script x salvo50 o altro scripter ambata +2ambi secchi+ terno

[kubes]

Bisogna ora trovare nella stessa estrazioneil + 1 o il -1 di un numero,isotopi .

esempio estrazione 30/04/2019
BARI 1°ESTRATTO = 78 .
Troviamo il 77 a NAZIONALE in prima posizione come da regola, quindi si procede alla previsione:
disponiamoli
78-------77
il diametrale di 78 è 33
il diametrale di 77 è 32
li mettiamo cosi invertendoli:
78---77
32---33
ora sommiamo 78+32=110-90=20
e sommiamo 77+33= 110-90=20
20 è ambata.
per i 2 ambi faremo :
78+77= 65
32+33=65
al 65 aggiungiamo -1 (cambia in base alla condizione trovata : in questo caso è -1. Dovuto al fatto che 77 su naz è piu piccolo di 78)
e avremo 64
QUINDI :
20 AMBATA
20/65 1° AMBO
20/64 2° AMBO
20-64-65 TERNO .

IN QUESTA ESTRAZIONE CI SONO ANCHE ALTRE CONDIZIONI
4° PALERMO=12
4° ROMA = 11 .QUI Cè IL -1

5° MILANO= 56
5°NAPOLI =55 .QUI Cè IL -1

3°CAGLIARI=66
3°PALERMO =65

5°GENOVA =20
5°ROMA = 19

 

[salvo50]

Ciao Kubes, controlla se ci sono errori, la distanza non l'ho fatta fissa, ma variabile tramite InputBox

Option Explicit
Sub Main
   Dim Fin,Es,Ini,Clp,Caso,Casi
   Dim R1,R2,P1,P2,P3,A,B,Salvo50
   Dim E1,E2,Diam_A,Diam_B,S1,S2,S3
   Dim S4,S5,Dist,Sp
   Dim Amba(1),Ambo1(2),Ambo2(2),Terno(3)
   Dim Posta(1),Poste(3),Ruo(2)
   Posta(1) = 1
   Poste(2) = 1
   'Poste(3) = 1
   Sp = " "
   Fin = EstrazioneFin
   Ini = InputBox("Inserisci l'estrazione che vuoi iniziare",Salvo50,9550)
   Dist = CInt(InputBox("Inserisci la distanza Isotopa da trovare",Salvo50,1))
   Clp = InputBox("Per quanti colpi vuoi giocare?",,5)
   Call ScegliRange(Ini,Fin,Ini,Fin)
   Scrivi "METODO CHIESTO DA KUBES - ISOTOPO (+" & Dist & ") OPPURE (-" & Dist & ") - Script Salvo50",1,,4,,3,,1
   Posta(1) = 1
   Poste(2) = 1
   Poste(3) = 1
   For Es = Ini To Fin
      Messaggio Es
      AvanzamentoElab Ini,Fin,Es
      Caso = 0
      For R1 = 1 To 10
         For R2 = R1 + 1 To 12
            If R2 = 11 Then R2 = 12
            For P1 = 1 To 5
               A = Estratto(Es,R1,P1)
               B = Estratto(Es,R2,P1)
               If(B > A And B - A = Dist) Or(B < A And A - B = Dist) Then
                  Diam_A = Diametrale(A) : Diam_B = Diametrale(B)
                  S1 = Fuori90(A + Diam_B)
                  S2 = Fuori90(B + Diam_A)
                  S3 = Fuori90(A + B)
                  S4 = Fuori90(Diam_A + Diam_B)
                  If A > B Then
                     S5 = Fuori90(90 +(S3 - Dist))
                  Else
                     S5 = Fuori90(S3 + Dist)
                  End If
                  Amba(1) = S1
                  Ambo1(1) = S1
                  Ambo1(2) = S3
                  Ambo2(1) = S1
                  Ambo2(2) = S5
                  Terno(1) = S1
                  Terno(2) = S3
                  Terno(3) = S5
                  Ruo(1) = R1 : Ruo(2) = R2
                  Caso = Caso + 1
                  Casi = Casi + 1
                  Scrivi String(89,"o") & " Casi Totali " & FormattaStringa(Casi,"0000"),1,,,1
                  Scrivi String(80,"o") & " Estrazione " &(Es) & " caso " & FormattaStringa(Caso,"0000"),1,,,2
                  Scrivi " Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es),1,0
                  Scrivi "  " & SiglaRuota(R1) & " ",1,0
                  For P2 = 1 To 5
                     E1 = Estratto(Es,R1,P2)
                     If E1 = A Then
                        ColoreTesto 2
                     Else
                        ColoreTesto 0
                     End If
                     Scrivi Format2(E1) & " ",1,0
                     ColoreTesto 0
                  Next
                  Scrivi "  " & Format2(Diam_A) & " = Diametrale " & Format2(A),1,,,1
                  Scrivi " Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es),1,0
                  Scrivi "  " & SiglaRuota(R2) & " ",1,0
                  For P3 = 1 To 5
                     E2 = Estratto(Es,R2,P3)
                     If E2 = B Then
                        ColoreTesto 2
                     Else
                        ColoreTesto 0
                     End If
                     Scrivi Format2(E2) & " ",1,0
                     ColoreTesto 0
                  Next
                  Scrivi "  " & Format2(Diam_B) & " = Diametrale " & Format2(B),1,,,1
                  Scrivi
                  Scrivi Space(15) & Format2(A) & " + " & Format2(Diam_B) & " = " & Format2(S1),1,0,,1
                  Scrivi Space(10) & Format2(A) & " + " & Format2(B) & " = " & Format2(S3),1,,,1
                  Scrivi Space(15) & Format2(B) & " + " & Format2(Diam_A) & " = " & Format2(S2),1,0,,1
                  Scrivi Space(10) & Format2(Diam_A) & " + " & Format2(Diam_B) & " = " & Format2(S4),1,0,,1
                  If A > B Then
                     Scrivi Space(10) & Format2(S3) & " - " & Format2(Dist) & " = " & Format2(S5),1,,,2
                  Else
                     Scrivi Space(10) & Format2(S3) & " + " & Format2(Dist) & " = " & Format2(S5),1,,,2
                  End If
                  Scrivi
                  Scrivi Space(37) & "PRONOSTICO"
                  Scrivi Space(22) & "Ambata" & Space(5) & "Ambo 1" & Space(5) & "Ambo 2" & Space(5) & "Terno",1
                  Scrivi Space(24) & Format2(S1) & Space(7) & Format2(S1) & Sp & Format2(S3),1,0
                  Scrivi Space(6) & Format2(S1) & Sp & Format2(S5) & Space(5),1,0
                  Scrivi Format2(S1) & Sp & Format2(S3) & Sp & Format2(S5),1
                  Scrivi
                  ImpostaGiocata 1,Amba,Ruo,Posta,Clp
                  ImpostaGiocata 2,Ambo1,Ruo,Poste,Clp
                  ImpostaGiocata 3,Ambo2,Ruo,Poste,Clp
                  ImpostaGiocata 4,Terno,Ruo,Poste,Clp
                  Gioca Es
               End If
            Next
         Next
      Next
      If ScriptInterrotto Then Exit Sub
   Next
   ScriviResoconto
End Sub

 

[kubes]

salvo50 va benissimo... grazie !!!! top scripter !!!