Elenco script x filtrare una lunghetta dinamica doc x teorico ambo in pochi colpi

[lotto_tom75]

Vorrei provare a testare diversi script con questo unico target "filtro di lunghette medio-grandi dinamiche doc anche di classe 30 x teorico ambo a colpo o in pochi colpi su ruota unica" e provare a scegliere il migliore o migliori. Grazie anticipate se mi indichi con l'url relativo in questo post quello che conosci tu magari aggiungendo, se la sai, anche la breve teoria riduzionale che vi sta alla base. Inoltre questo thread se popolato da interessanti script di questo genere potrebbe essere molto utile anche x tutti/e coloro che avessero in corso varie altre ricerche analoghe e similari. Buona giornata a tutti/e

 

[lotto_tom75]

Intanto tra gli script di "default" del programma ho trovato questo...

RitardiAmboSuUltimeRighe

Option Explicit

Class clsCoppia
   Public Pos(2)
   Dim Ritardo
   Dim Frequenza
   Dim RitardoMax
   Public Sub GetRigaColonna(i,nRiga,nColonna)
      Dim n

      n = Pos(i)
      If n > 5 Then
         If n Mod 5 = 0 Then
            nRiga =(n /5)
            nColonna = 5
         Else
            nRiga =((n -(n Mod 5)) /5) + 1
            nColonna = n Mod 5
         End If
      Else
         nRiga = 1
         nColonna = n
      End If
   End Sub
   Public Sub CalcolaValoriStat(idEstr,Ruota)

      ReDim aN(2)
      ReDim aRuote(1)
      Dim k
      Dim nRiga,nPos

      aRuote(1) = Ruota

      For k = 1 To 2
         Call GetRigaColonna(k,nRiga,nPos)
         aN(k) = Estratto(idEstr - nRiga,Ruota,nPos)
      Next

      If SerieFreq(idEstr,idEstr,aN,aRuote,2) = 1 Then
         Ritardo = 0
         Frequenza = Frequenza + 1
      Else
         Ritardo = Ritardo + 1
         If Ritardo > RitardoMax Then
            RitardoMax = Ritardo
         End If
      End If
   End Sub
End Class
Sub Main
   Dim idEstr,Ruota
   Dim Inizio,Fine
   Dim collCoppie


   Inizio = EstrazioneIni
   Fine = EstrazioneFin
   Ruota = ScegliRuota
   If Ruota > 0 Then

      Call AlimentaCollCoppie(collCoppie,15)
      For idEstr = Inizio To Fine

         ' inserire qui il codice che analizza l'estrazione corrente
         Call AnalisiRitardi(collCoppie,idEstr,Ruota)


         Call AvanzamentoElab(Inizio,Fine,idEstr)
         If ScriptInterrotto Then Exit For
      Next

      Call OrdinaItemCollection(collCoppie,"Ritardo")
      Call CreaOutput(collCoppie,Ruota)

      MsgBox "fine"
   End If
End Sub
Sub AlimentaCollCoppie(coll,nValMax)

   Dim k,kk
   Dim clsCoppia

   Set coll = GetNewCollection

   For k = 1 To nValMax - 1
      For kk = k + 1 To nValMax
         Set clsCoppia = New clsCoppia
         clsCoppia.pos(1) = k
         clsCoppia.pos(2) = kk

         coll.Add clsCoppia

      Next
   Next

End Sub
Sub AnalisiRitardi(coll,idEstr,Ruota)
   Dim clsCoppia

   For Each clsCoppia In coll
      Call clsCoppia.CalcolaValoriStat(idEstr,Ruota)
   Next
End Sub

Sub CreaOutput(coll,Ruota)

   Dim clsCoppia

   ReDim aV(4)
   aV(1) = "Coppia"
   aV(2) = "Ritardo"
   aV(3) = "RitMax"
   aV(4) = "Frequenza"

   Call Scrivi(NomeRuota(Ruota))

   Call InitTabella(aV)

   For Each clsCoppia In coll
      ReDim aV(4)
      aV(1) = clsCoppia.Pos(1) & "-" & clsCoppia.Pos(2)
      aV(2) = clsCoppia.Ritardo
      aV(3) = clsCoppia.RitardoMax
      aV(4) = clsCoppia.Frequenza

      Call AddRigaTabella(aV)

   Next

   Call CreaTabella

End Sub

Ma confrontando il report (di cui riporto solo una parte per l'eccessiva lunghezza dello stesso) di questo con i ritardi x A analizzati con la sezione statistica formazioni veloce non corrispondono...

Ad esempio prendendo in esame l'ambo 3-13 su TO dal 1871 qui risulterebbe RA 1745 e RS 1745 e in formazioni statistica veloce RA 564 RS 1862.

Ora questa discrepanza apparente è solo dovuta al diverso tipo di analisi ovviamente ma chiedo a chi ne è a conoscenza di quale ritardo si parli nel caso sottostante... ovvero cosa sia il Ritardo su Ambo Su Ultime Righe che devo dire.. potrebbe essere molto interessante adottarlo come filtro forse... proprio appunto per la sua "incongruenza" con i valori standard... dei ritardi "classici"

Torino - RitardiAmboSuUltimeRighe [TABLE="border: 1, cellpadding: 0, cellspacing: 0"]
[TR]
[TD="bgcolor: #ffffff, align: center"]Coppia [/TD]
[TD="bgcolor: #ffffff, align: center"]Ritardo [/TD]
[TD="bgcolor: #ffffff, align: center"]RitMax [/TD]
[TD="bgcolor: #ffffff, align: center"]Frequenza [/TD]
[/TR]
[TR]
[TD="bgcolor: #ffffff, align: center"]3-13 [/TD]
[TD="bgcolor: #ffffff, align: center"]1745 [/TD]
[TD="bgcolor: #ffffff, align: center"]1745 [/TD]
[TD="bgcolor: #ffffff, align: center"]22 [/TD]
[/TR]
[TR]
[TD="bgcolor: #ffffff, align: center"]ecc...[/TD]
[TD="bgcolor: #ffffff, align: center"] [/TD]
[TD="bgcolor: #ffffff, align: center"] [/TD]
[TD="bgcolor: #ffffff, align: center"] [/TD]
[/TR]
[TR]
[TD="bgcolor: #ffffff, align: center"] [/TD]
[TD="bgcolor: #ffffff, align: center"] [/TD]
[TD="bgcolor: #ffffff, align: center"] [/TD]
[TD="bgcolor: #ffffff, align: center"] [/TD]
[/TR]
[/TABLE]
A cosa ci si riferisce con "Ritardo su Ambo Su Ultime Righe" ? Grazie