IL NUMERO RIPETUTO (per salvo 50)

[vinci]

Ciao a tutti quanti.
Se salvo50 ha un attimo di tempo e se vuole, propongo un metodo da fare lo script.
Per questo lo ringrazio anticipatamente



IL NUMERO RIPETUTO

La previsione è su singola ruota e ricava una sola quartina.

Bisogna attendere che in due estrazioni consecutive sulla medesima ruota esca lo stesso numero in posizione isotopa.
Condizione che accade spesso, quindi onde evitare troppe previsioni in contemporanea, occorre anche che in almeno
una estrazione delle due consecutive, ci sia il diametrale in decina del numero doppio.
Verificatosi questa condizione si opera come segue:

N = n° doppio
A = N + N
B = 91 - N
C = 91 - A
D = diametrale N

Come esempio vediamo una condizione che si è verificata recentemente sulla ruota di BARI

in data 28/11/2020 uscivano i seguenti numeri a BARI 61-80-40-26-16
in data 01/12/2020 uscivano i seguenti numeri a BARI 65-80- 01-13-85

Come possiamo notare sulla stessa ruota e in due estrazioni consecutive, usciva il numero 80
in posizione isotopa e in una delle due estrazioni consecutive è presente il diametrale in decina 85

Verificato questo si può procedere al calcolo della previsione.

N = n° doppio = (80)
A = N + N = (80+80 = 160) = 70
B = 91 - N = (91-80) = 11
C = 91 - A = (91-70) = 21
D = diametrale N (80+45) = 35

A questo punto la previsione da mettere in gioco è la seguente :
BARI 11-21-35-70
da giocare per 10 colpi per ambo,terno e pochi centesimi per quaterna
sospendere il gioco al primo esito positivo

 

[vinci]

Come seconda ipotesi potremmo eliminare il vincolo del diametrale in decina
e vedere come si comporta il metodo .
Ancora grazie a chi dedicherà il suo tempo per questa idea di metodo che mi è venuta in mente
senza sapere della sua validità nel tempo.

 

[salvo50]

Ciao vinci, l'ho fatto senza il diametrale in decina, è più semplice, comunque anche così non sono molti i casi in 851 estrazioni ne son venuti 489 quindi in media meno di uno a estrazione

Option Explicit
Sub Main
   Dim FIn,Ini,A,B,C,D,E,F,Clp,Es,Salvo50
   Dim R1,R2,P1,P2,P3,E1,E2,Caso,Casi
   Dim Qua(4),Ruo(1),Posta(4)
   FIn = EstrazioneFin
   Ini = CInt(InputBox("Inserisci l'estrazione che vuoi iniziare",Salvo50,9000))
   Clp = CInt(InputBox(" Per quanti colpi vuoi giocare?",Salvo50,13))
   Call ScegliRange(Ini,FIn,Ini,FIn)
   Scrivi Space(15) & "NUMERO DOPPIO di VINCI - SCRIPT SALVO50" & Space(25),1,,4,,3,,1
   Posta(2) = 1.5
   Posta(3) = 0.4
   Posta(4) = 0.1
   For Es = Ini To FIn
      Messaggio Es
      AvanzamentoElab Ini,FIn,Es
      Caso = 0
      For R1 = 1 To 10
         For P1 = 1 To 5
            A = Estratto(Es,R1,P1)
            B = Estratto(Es + 1,R1,P1)
            If A > 0 And B > 0 Then
               If A = B Then
                  C = Fuori90(A + B)
                  D = 91 - A
                  E = 91 - C
                  F = Diametrale(A)
                  Qua(1) = C : Qua(2) = D : Qua(3) = E : Qua(4) = F
                  '
                  Caso = Caso + 1
                  Casi = Casi + 1
                  Scrivi String(89,"*") & " Casi Totali " & FormattaStringa(Casi,"0000"),1,,,2
                  Scrivi String(80,"*") & " Estrazione " &(Es) & " caso " & FormattaStringa(Caso,"0000"),1,,,1
                  Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
                  Scrivi "  " & SiglaRuota(R1) & " ",1,0
                  For P2 = 1 To 5
                     E1 = Estratto(Es,R1,P2)
                     If E1 = A Then
                        ColoreTesto 2
                     Else
                        ColoreTesto 0
                     End If
                     Scrivi Format2(E1) & " ",1,0
                     ColoreTesto 0
                  Next
                  Scrivi
                  Scrivi(" Estrazione n." & Format2(Es + 1) & " del " & DataEstrazione(Es + 1)),1,0
                  Scrivi "  " & SiglaRuota(R1) & " ",1,0
                  For P3 = 1 To 5
                     E2 = Estratto(Es + 1,R1,P3)
                     If E2 = B Then
                        ColoreTesto 2
                     Else
                        ColoreTesto 0
                     End If
                     Scrivi Format2(E2) & " ",1,0
                     ColoreTesto 0
                  Next
                  Scrivi
                  Scrivi
                  Scrivi Space(10) & " Pronostico 1    " & Format2(C) & " = " & Format2(A) & " + " & Format2(B),1
                  Scrivi Space(10) & " Pronostico 2    " & Format2(D) & " = 91 - " & Format2(A),1
                  Scrivi Space(10) & " Pronostico 3    " & Format2(E) & " = 91 - " & Format2(C),1
                  Scrivi Space(10) & " Pronostico 4    " & Format2(F) & " = DIAMETRALE " & Format2(A),1
                  Scrivi
                  Ruo(1) = R1
                  ImpostaGiocata 1,Qua,Ruo,Posta,Clp
                  Gioca Es
               End If
            End If
         Next
      Next
      If ScriptInterrotto Then Exit Sub
   Next
   ScriviResoconto
End Sub

 

[vinci]

Grazie salvo50 ottimo lavoro come sempre lo script è perfetto mentre il metodo lascia molto a desiderare.....
vediamo se riesco ad aggiustare un po il tiro provando a fare delle migliorie.....
ancora grazie mille