Modifica Listato

[Xeroxs]

Buongiorno a Tutti,
Volevo chiedere a Joe se è possibile (o Fattibile) modificare questo Tuo listato utilizzando dei numeri scelti dall'utente.
Mi hanno passato questo tuo ottimo lavoro e piace molto come vengono evidenziati i numeri, ma io non riesco a capire dove devo intervenire, o meglio è possibile capire forse dove ma non riesco ad ottenere il risultato voluto.
Mi basta al massimo una lunghetta di 5 numeri per Testare le loro scelte, nel breve periodo.
Spero si possa fare.

Grazie come sempre.

Questo è il listato

Option Explicit
Sub Main
Dim P,I,F 'Primario / Inizio / Fine
Dim N ' Ciclo - Enne - Estrazioni
Dim S 'Secondario
Dim E 'Estrazione
Dim Numeri(10)
Dim Ruota
Dim L
Dim Pos
Dim Q
Dim Bold
Dim CP,CC
Ruota = BA_
ColoreTesto 2
Scrivi NomeRuota(Ruota) & " ",True,False
For N = 1 To 10 : Numeri(N) = N : Next
Scrivi StringaNumeri(Numeri,,True),True
ColoreTesto 0
Scrivi
'DATI :
I = 9729 'Inizio Principale
F = EstrazioneFin 'Fine Principale
N = 9 'Numero di estrazioni per ciclo
For P = I To F Step 9 'Ciclo principaleI=z
CC = CC + 1 'Contatore Cicli Aumenta di 1 ad ogni passaggio
CP = 0 'CP = Contatore Presenze = 0
For S = 0 To N - 1 'Ciclo Secondario
E = P + S 'Estrazione nel ciclo
Scrivi E & " " & DataEstrazione(E) & " ",0,0
For Pos = 1 To 5 'leggo gli estratti uno ad uno
L = Estratto(E,Ruota,Pos) ''
For Q = 1 To 10
If Numeri(Q) = L Then
CP = CP + 1
ColoreTesto 2
Bold = True
End If
Next
Scrivi Format2(L),Bold,0 ''' Li Scrivo singolarmente
ColoreTesto 0 : Bold = False
If Pos < 5 Then Scrivi ".",False,False
Next
Scrivi
Next
ColoreTesto 1 : Scrivi "Ciclo N° " & FormatSpace(CC,4,True),True,False
Scrivi Space(7),False,False
ColoreTesto 2 : Scrivi "Presenze " & CP,True : ColoreTesto 0
REM If CP >= 7 Then CC = 0 'AZZERA IL CONTATORE NEI "CICLI POSITIVI"
If E = 4311 Then Exit For
Scrivi String(32,"-")
Next
End Sub

 

[joe]

Ciao ...

è probabile che qualcuno abbia modificato quello script (o nel tempo ... sia cambiato qualcosa),

perché eseguendolo finisce fuori range ed io non lo avrei reso pubblico con un problema così.

Adesso ... andare a cercare e correggere gli errori che si sono introdotti è difficile.

Dovresti chiedere a chi te lo ha dato se ne ha una versione funzionante,

perché lavorare su una cosa "guasta in partenza" è sconveniente per tutti.

 

[Xeroxs]

ok provvedo, grazie

 

[Xeroxs]

Ciao,
Rintracciato.
il link della discussione tratta da questo Forum è questo

Joe91 come faccio

Ciao Eugenio. Si ho riutilizzato la varabile "N". Come vedi nella prima parte dello script essa termina di essere utile. Pertanto l'ho resa disponibile per altri scopi. Ripropongo lo script con le aggiunte già descritte assieme ad alcune piccole modifiche nel suo output. Ho lasciato...

forum.lottoced.com

post 41 da dove ha prelevato il listato anche se ho notato il listato successivo sembra più completo, ma per correttezza riporto quello già copiato in precedenza, mi ha detto che aveva solo cambiato qualcosa sulla data, ma nel link trovi il tuo file originale

Spero sia sufficiente per capire se la mia richiesta è fattibile.

Grazie come sempre

 

[joe]

Ciao Xeroxs,

Ricordavo ed ero certo che fosse un qualcosa fatto per Eugenio,

però per un contesto specifico e molto diverso.

Ho preferito lavorare allo script che hai proposto modificandolo profondamente.

Primo perché non esistono le decine (intese come 10 numeri consecutivi)

se non come cabala nella testa di qualcuno.

Secondo perché esse esistono ancora meno in presenza di un archivio ordinario.

Tralasciando queste poche considerazioni e premesse ...

Dovendo sganciare lo script da un intervallo fisso ho scelto che

i cicli siano quelli previsti e questi siano completi.

Dunque lo script esamina, una finestra, di estrazioni dell'archivio,

"fissa" come numero di estrazioni (numero di cicli per numero di estrazioni)

in un periodo "mobile".

Mobile perché esso va a coincidere con il termine dell'archivio stesso,

che si sposta di aggiornamento in aggiornamento.

Ho deciso anche di lasciare come input ruote e numeri,

mantenendo semi fissi ampiezza e numero di cicli

cioè l'ampiezza della finestra esaminata.

Questo perché con 4 parametri mobili sarebbero state troppe

le combinazioni di risultati prodotti, divenendo questi difficilmente analizzabili.

Nessuno vieta di inserire altri 2 inputbox.

O di reimpostare tutto al contrario.

Option Explicit
Sub Main
  Dim P,I,F 'Primario / Inizio / Fine
  Dim C 'Numero di cicli
  Dim N 'Estrazioni per ogni ciclo
  Dim S 'Secondario
  Dim E 'Estrazione
  Dim Numeri()
  Dim Ruota
  Dim L
  Dim Pos
  Dim Q
  Dim Bold
  Dim CP,CC
  Ruota = ScegliRuota
  Scrivi NomeRuota(Ruota) & " ",True,False
  ScegliNumeri(Numeri)
  ColoreTesto 2
  Scrivi StringaNumeri(Numeri,,True),True
  ColoreTesto 0
  Scrivi

'--------------------------------------
'DATI :
  C =  5 'Numero di cicli
  N = 18 'Numero di estrazioni per ciclo
'--------------------------------------

  F = EstrazioneFin 'Fine Principale
  I = EstrazioneFin - C*N + 1 'Inizio Principale
  For P = I To F Step N 'Ciclo principaleI=z
    CC = CC + 1 'Contatore Cicli Aumenta di 1 ad ogni passaggio
    CP = 0 'CP = Contatore Presenze = 0
    For S = 0 To N - 1 'Ciclo Secondario
      E = P + S 'Estrazione nel ciclo
      Scrivi E & " " & DataEstrazione(E) & " ",0,0
      For Pos = 1 To 5 'leggo gli estratti uno ad uno
        L = Estratto(E,Ruota,Pos) ''
        For Q = 1 To UBound(Numeri)
          If Numeri(Q) = L Then
            CP = CP + 1
            ColoreTesto 2
            Bold = True
          End If
        Next
        Scrivi Format2(L),Bold,0 ''' Li Scrivo singolarmente
        ColoreTesto 0 : Bold = False
        If Pos < 5 Then Scrivi ".",False,False
      Next
      Scrivi
    Next
    ColoreTesto 1 : Scrivi "Ciclo N° " & FormatSpace(CC,4,True),True,False
    Scrivi Space(7),False,False
    ColoreTesto 2 : Scrivi "Presenze " & CP,True : ColoreTesto 0
    REM If CP >= 7 Then CC = 0 'AZZERA IL CONTATORE NEI "CICLI POSITIVI"
    Scrivi String(32,"-")
  Next
End Sub

 

[Xeroxs]

Grazie Joe,
Ho potuto accedere al Forum solo adesso, o meglio ho visto ieri sera dal Tablet, ma non riuscivo a rispondere, misteri della rete, che posso dire un Grazie enorme per quanto fatto come sempre un ottimo lavoro.
Rileggo con attenzione molti dei tuoi commenti, come quelli di Mike, I-Legend, Salvo, Claudio e spero di non dimenticare nessuno per cercare di imparare a capire non solo la logica della programmazione ma anche per capire come fare "da solo" (al momento ancora un parolone) qualche script, a volte riesco a volte no, e capisco che apporre modifiche su uno script fatto per altre logiche non sempre si può fare. Credimi i vostri interventi mi sono stati utili per molti spunti, non per copiare ma per capire così per provare a migliorami, quindi se ancora mi permetto di chieder qualche intervento lo faccio perchè non ci riesco ad essere autonomo e avedere la crescita di alcuni non può che essere uno sprono vero per migliorarsi, e non pretendo mai un aiuto, ma non per questo mi arrendo, non è mio uso farlo....
Grazie Ancora Joe.