Per Luigi .. se c'è

fillotto · 19 Giugno 2011

Nell'ultima risposta che hai fatto per Keper hai fatto questo esempio:
Problema : Verificare su una data ruota quante volte la somma del Primo e secondo Estratto col Fuori90
da esito di Estratto entro i primi 3 colpi successivi.

Volendo controllare tutte e 4 le somme (il 1°+il 2°,il 1°+il 3° ecc)
ho aggiunto come vedi la variabile "pos" e fatto un ciclo For cosi come vedi sotto.
Purtroppo l'output mi da tutti i casi positivi raggruppati così
Casi totali : 120 (30 x 4)
Casi positivi : 18 ( la somma di tutti i casi )
Lo scopo che voglio raggiungere è invece quello di sapere quale somma è + conveniente (l'esempio è fatto con BA x le ultime trenta
estazioni)

UN AIUTINO NON NECESSARIAMENTE DA LUIGI!!!

Option Explicit
Sub Main
Dim Inizio,Fine
Dim Ruota(1)
Dim k
Dim aNumeri(1)
Dim CasiPos
Dim CasiTot
Dim pos
Ruota(1) = ScegliRuota

Inizio = CInt(InputBox("Inizio analisi","Inizio",1))
Fine = CInt(InputBox("Fine analisi","Fine",EstrazioniArchivio))
For k = Inizio To Fine
For pos = 2 To 5
CasiTot = CasiTot + 1
aNumeri(1) = Fuori90(Estratto(k,Ruota(1),1) + Estratto(k,Ruota(1),pos))
If VerificaEsito(aNumeri,Ruota,k + 1,1,3) Then
CasiPos = CasiPos + 1
End If
Next
Next
Call Scrivi("Casi totali : " & CasiTot)

Call Scrivi("Casi positivi : " & CasiPos )

End Sub

claudio8 · 19 Giugno 2011

x Filotto, non è un rimprovero personale, però sarebbe meglio anche per chi vuole chiarimenti fare un piccolo sforzo.
Quando si posta uno script usiano il tasto Insert Code altrimenti occorre caricarlo su spaziometria e formattarlo per poterlo leggere, per cui se si ha voglia di prendersi la briga di fare questa 2 ulteriori operazioni si legge e si può rispondere, diversamente se non si ha tanta voglia, anche ad un semplice quesito non riceve risposta.
Ciao
ripeto che non è un rimprovro personale ma un atteggiamento generale che andrebbe modificato.

Lo spot che conosciamo dice "Ti Piace vincere facile ? " che tradotto in pratica significa "Ti Piace..rebbe vincere facile !!!"

claudio8 · 19 Giugno 2011

Relativamente al quesito:
vi sono 2 strade percorribili, una quella di ripeter lo script x le 4 somme modificando il for o escludendolo completamente, l'altra passa attraverso la creazione di una matrice-array che contenga per ogni "pos" del ciclo for gli esiti che ci sono.
Ciao

Lo spot che conosciamo dice "Ti Piace vincere facile ? " che tradotto in pratica significa "Ti Piace..rebbe vincere facile !!!"

claudio8 · 19 Giugno 2011

1° modo

Codice:

Option Explicit
Sub Main
	Dim Inizio,Fine
	Dim Ruota(1)
	Dim k
	Dim aNumeri(1)
	Dim CasiPos
	Dim CasiTot
	Dim pos
	Ruota(1) = ScegliRuota
	Inizio = CInt(InputBox("Inizio analisi","Inizio",1))
	Fine = CInt(InputBox("Fine analisi","Fine",EstrazioniArchivio))
	
	For k = Inizio To Fine
		For pos = 2 To 2
			CasiTot = CasiTot + 1
			aNumeri(1) = Fuori90(Estratto(k,Ruota(1),1) + Estratto(k,Ruota(1),pos))
			If VerificaEsito(aNumeri,Ruota,k + 1,1,3) Then
				CasiPos = CasiPos + 1
			End If
		Next
	Next
	Call Scrivi("Casi totali : " & CasiTot& " per somma 1 + " &pos)

	Call Scrivi("Casi positivi : " & CasiPos)
	CasiTot= 0
	CasiPos = 0
	For k = Inizio To Fine
		For pos = 3 To 3
			CasiTot = CasiTot + 1
			aNumeri(1) = Fuori90(Estratto(k,Ruota(1),1) + Estratto(k,Ruota(1),pos))
			If VerificaEsito(aNumeri,Ruota,k + 1,1,3) Then
				CasiPos = CasiPos + 1
			End If
		Next
	Next
	Call Scrivi("Casi totali : " & CasiTot& " per somma 1 + " &pos)

	Call Scrivi("Casi positivi : " & CasiPos)
	CasiTot= 0
	CasiPos = 0
	For k = Inizio To Fine
			For pos = 4 To 4
				CasiTot = CasiTot + 1
				aNumeri(1) = Fuori90(Estratto(k,Ruota(1),1) + Estratto(k,Ruota(1),pos))
				If VerificaEsito(aNumeri,Ruota,k + 1,1,3) Then
					CasiPos = CasiPos + 1
				End If
			Next
		Next
	Call Scrivi("Casi totali : " & CasiTot& " per somma 1 + " &pos)

	Call Scrivi("Casi positivi : " & CasiPos)
	CasiTot= 0
	CasiPos = 0
	For k = Inizio To Fine
			For pos =  5 To 5
				CasiTot = CasiTot + 1
				aNumeri(1) = Fuori90(Estratto(k,Ruota(1),1) + Estratto(k,Ruota(1),pos))
				If VerificaEsito(aNumeri,Ruota,k + 1,1,3) Then
					CasiPos = CasiPos + 1
				End If
			Next
		Next
	Call Scrivi("Casi totali : " & CasiTot & " per somma 1 + " &pos)
	Call Scrivi("Casi positivi : " & CasiPos)

End Sub

2° modo ..... lascio a te l'arduo compito
ciao

Lo spot che conosciamo dice "Ti Piace vincere facile ? " che tradotto in pratica significa "Ti Piace..rebbe vincere facile !!!"

fillotto · 19 Giugno 2011

grazie claudio , l'ho scritto che l'aiutino era rivolto a tutti, solo che dato che l'esempio veniva da Luigi.....
Ho fatto girare il tuo script non capisco l'output:
Casi totali : 30 per somma 1 + 3
Casi positivi : 6
Casi totali : 30 per somma 1 + 4
Casi positivi : 3
Casi totali : 30 per somma 1 + 5
Casi positivi : 5
Casi totali : 30 per somma 1 + 6 ??? perchè 1+6 ?
Casi positivi : 4

Son tornato adesso , ora provo qualche cosa Grazie comunque

LuigiB · 19 Giugno 2011

sempre per continuare sull'argomento una cosa che bisogna
evitare quando si scrive uno script è la ridondanza del codice.
Certe volte duplicare il codice appare la strada piu semplice
invece è meglio individuare il codice ridontante e racchiuderlo in una
unica funzione alla quale passerem opportuni parametri.

il pezzetto di codice ridondante è questo compare 4 volte

Codice:

For k = Inizio To Fine
		For pos = 2 To 2
			CasiTot = CasiTot + 1
			aNumeri(1) = Fuori90(Estratto(k,Ruota(1),1) + Estratto(k,Ruota(1),pos))
			If VerificaEsito(aNumeri,Ruota,k + 1,1,3) Then
				CasiPos = CasiPos + 1
			End If
		Next
	Next
	Call Scrivi("Casi totali : " & CasiTot & " per somma 1 + " & pos)
	Call Scrivi("Casi positivi : " & CasiPos)

è un codice che compare piu volte con l'unica variazione della variabile pos
allora potremmo scrivere una funzione

Codice:

Sub CalcolaCasiPos(pos,Inizio,fine,ruota)
	Dim k
	Dim aNumeri(1)
	Dim CasiPos
	Dim CasiTot
	For k = Inizio To fine
		CasiTot = CasiTot + 1
		aNumeri(1) = Fuori90(Estratto(k,ruota(1),1) + Estratto(k,ruota(1),pos))
		If VerificaEsito(aNumeri,ruota,k + 1,1,3) Then
			CasiPos = CasiPos + 1
		End If
	Next
	Call Scrivi("Casi totali : " & CasiTot & " per somma 1 + " & pos)
	Call Scrivi("Casi positivi : " & CasiPos)

End Sub

e lo script finale sarebbe questo

Codice:

Option Explicit
Sub Main
	Dim Inizio,Fine
	Dim Ruota(1)
	Dim aNumeri(1)
	Dim pos
	Ruota(1) = ScegliRuota
	Inizio = CInt(InputBox("Inizio analisi","Inizio",1))
	Fine = CInt(InputBox("Fine analisi","Fine",EstrazioniArchivio))
	For pos= 2 To 5
		Call CalcolaCasiPos(pos,Inizio,Fine,Ruota)
	Next
End Sub
Sub CalcolaCasiPos(pos,Inizio,fine,ruota)
	Dim k
	Dim aNumeri(1)
	Dim CasiPos
	Dim CasiTot
	For k = Inizio To fine
		CasiTot = CasiTot + 1
		aNumeri(1) = Fuori90(Estratto(k,ruota(1),1) + Estratto(k,ruota(1),pos))
		If VerificaEsito(aNumeri,ruota,k + 1,1,3) Then
			CasiPos = CasiPos + 1
		End If
	Next
	Call Scrivi("Casi totali : " & CasiTot & " per somma 1 + " & pos)
	Call Scrivi("Casi positivi : " & CasiPos)
End Sub

claudio8 · 19 Giugno 2011

Facendo girare questo script x capire come opera sembrerebbe che dopo aver effettuato il ciclo for pos = 2 to 2, valorizza pos = 3
cioè incrementa di 1 l'ultimo pos elaborato e poiché for pos = 2 to 2 da un fermo a 2, esso non elabora il 3 ma lo mantiene in memoria
Non so spiegarmi il perchè anche se questo uso del for è un tantino improprio per luso fattone.

Codice:

Option Explicit
Sub Main
	Dim Inizio,Fine
	Dim Ruota(1)
	Dim k
	Dim aNumeri(1)
	Dim CasiPos
	Dim CasiTot
	Dim pos
	Ruota(1) = ScegliRuota
	Inizio = CInt(InputBox("Inizio analisi","Inizio",8390))
	Fine = CInt(InputBox("Fine analisi","Fine",EstrazioneFin))
	CasiTot= 0
	CasiPos = 0
	For k = Inizio To Fine
		For pos = 2 To 2
			CasiTot = CasiTot + 1
			aNumeri(1) = Fuori90(Estratto(k,Ruota(1),1) + Estratto(k,Ruota(1),pos))
			If VerificaEsito(aNumeri,Ruota,k + 1,1,3) Then
				CasiPos = CasiPos + 1
			End If
			Scrivi pos & " valore pos dopo End If "
			Call Scrivi (Estratto(k,Ruota(1),1) &" a fine ciclo  for pos  " & Estratto(k,Ruota(1),pos))
		Next
		Scrivi pos & " valore pos dopo 1° next"
	Next
	Scrivi pos &" valore pos dopo 2° next "
	Scrivi "-----------------------"
	
	Call Scrivi (Estratto(k,Ruota(1),1) &" a fine ciclo  for K " & Estratto(k,Ruota(1),pos))
	Call Scrivi("Casi totali : " & CasiTot& " per somma 1 e " & pos)
	Call Scrivi("Casi positivi : " & CasiPos) 

End Sub

Lo spot che conosciamo dice "Ti Piace vincere facile ? " che tradotto in pratica significa "Ti Piace..rebbe vincere facile !!!"

LuigiB · 19 Giugno 2011

non ho capito che dici pero sappi che ogni istruzione next
incrementa di uno la variabile di controllo del ciclo.
Quindi tut fai un ciclo
for k = 2 to 2
next

e alla fine del ciclo ovviamente k è uguale a 3
p un comportamento normalissimo dei cicli for

claudio8 · 19 Giugno 2011

quote:Originally posted by LuigiB

non ho capito che dici pero sappi che ogni istruzione next
incrementa di uno la variabile di controllo del ciclo.
Quindi tut fai un ciclo
for k = 2 to 2
next

e alla fine del ciclo ovviamente k è uguale a 3
p un comportamento normalissimo dei cicli for

é la stessa cosa che cercavo di spiegare anche io, il famoso step = 1 che si omette nei cicli for
grazie Luigi

Lo spot che conosciamo dice "Ti Piace vincere facile ? " che tradotto in pratica significa "Ti Piace..rebbe vincere facile !!!"

LuigiB · 19 Giugno 2011

un evoluzione dello script precedente che risolve questo problema :

Problema :
Creare una classifica ordinata per indice di convenienza considerando
di giocare entro X colpi i numeri che si possono formare sommando
due a due col fuori90 quelli presi da tutte le posssibili 10
combinazioni di classe 2 di ciascuna estrazione per le 10 ruote (es. 1-2,1-3,1-4,1-5,2-3...).

In questo script tra l'altro si fa uso delle classi e delle collection
due armi molto potenti !

Codice:

Option Explicit
Sub Main
	Dim Coll
	Dim ClsI
	Dim idEs
	Dim Colpi
	Dim i
	Dim nEstrTot
	Dim NumDaGioc
	nEstrTot =(EstrazioneFin + 1) - EstrazioneIni
	Colpi = Int(InputBox("Entro quanti colpi verificare l'esito ?","Colpi di verifica",3))
	If Colpi <= 0 Then Exit Sub
	Call AlimentaCollItem(Coll)
	For Each ClsI In Coll
		For idEs = EstrazioneIni To EstrazioneFin
			Call CalcoloStat(ClsI,idEs,Colpi)
		Next
		i = i + 1
		Call AvanzamentoElab(1,Coll.count,i)
		If ScriptInterrotto Then Exit Sub
	Next
	ReDim aTitoli(9)
	aTitoli(1) = "Ruota"
	aTitoli(2) = "P1"
	aTitoli(3) = "P2"
	aTitoli(4) = "Ritardo"
	aTitoli(5) = "RitMax"
	aTitoli(6) = "Freq"
	aTitoli(7) = "I.C."
	aTitoli(8) = "Pronostico"
	aTitoli(9) = "Esito Colpi"
	Call InitTabella(aTitoli)
	For Each ClsI In Coll
		ReDim aV(9)
		aV(1) = NomeRuota(ClsI.ruota)
		aV(2) = ClsI.P1
		aV(3) = ClsI.P2
		aV(4) = ClsI.Rit
		aV(5) = ClsI.RitMax
		aV(6) = ClsI.Frq
		aV(7) = round(Dividi(ClsI.rit,Dividi(nEstrTot,ClsI.frq)),4)
		aV(9) = GetColpiEsito(ClsI,NumDaGioc)
		aV(8) = NumDaGioc
		Call AddRigaTabella(aV)
	Next
	Call Scrivi("Classifica dei numeri ottenuti sommando col fuori90 " & vbCrLf & "i numeri di 2 singole posizioni per ciascuna estrazione sulle 10 ruote esclusa la nazionale")
	Call Scrivi
	Call Scrivi("Analisi da           : " & GetInfoEstrazione(EstrazioneIni) & " a " & GetInfoEstrazione(EstrazioneFin))
	Call Scrivi("Estrazioni esaminate :" & nEstrTot)
	Call Scrivi
	Call CreaTabella(7)
End Sub
Function GetColpiEsito(ClsI,RetNum)
	Dim idEs
	ReDim aN(1)
	ReDim aR(1)
	Dim nRetColpi
	idEs = EstrazioneFin
	aN(1) = Fuori90(Estratto(idEs,ClsI.ruota,ClsI.p1) + Estratto(idEs,ClsI.ruota,ClsI.p2))
	aR(1) = ClsI.ruota
	
	If VerificaEsito(aN,aR,idEs + 1,1,,,,nRetColpi) Then
		GetColpiEsito = nRetColpi
	End If
	
	RetNum = aN(1)
	
End Function

Function Dividi(a,b)
	If b > 0 Then
		Dividi = a / b
	End If
End Function
Sub CalcoloStat(ClsI,idEs,Colpi)
	ReDim aN(1)
	ReDim aR(1)
	aN(1) = Fuori90(Estratto(idEs,ClsI.ruota,ClsI.p1) + Estratto(idEs,ClsI.ruota,ClsI.p2))
	aR(1) = ClsI.ruota
	If VerificaEsito(aN,aR,idEs + 1,1,Colpi) Then
		ClsI.frq = ClsI.frq + 1
		ClsI.rit = 0
	Else
		ClsI.rit = ClsI.rit + 1
		If ClsI.rit > ClsI.ritmax Then
			ClsI.ritmax = ClsI.rit
		End If
	End If
End Sub
Sub AlimentaCollItem(coll)
	Dim clsI
	Dim k,kk,r
	Set coll = GetNewCollection
	For r = 1 To 10
		If r <> 11 Then
			For k = 1 To 4
				For kk = k + 1 To 5
					Set clsI = New clsItem
					clsI.p1 = k
					clsI.p2 = kk
					clsI.ruota = r
					coll.Add clsI
				Next
			Next
		End If
	Next
End Sub
Class clsItem
	Public p1,p2,ruota,Rit,RitMax,Frq
End Class

Roby · 19 Giugno 2011

SEMPRE GRANDE LUIGGIONE !!!! CIAOOOOOOOOOO !!!!!!!!!!! e GRRAZZZIEEEE !

SUERTE !!!!

Magic Pluto · 20 Giugno 2011

Un po' vi invidio.....
Con tutte le tecniche che mi ritrovo avere un programma di verifica mi farebbe comodo....
ma ce ne vorrebbe uno per ogni tecnica....
Quindi.......... m'accontentero' delle veriche semi-manuali (excell)

Pero' resta il fatto che v'invidio ...

Ps.
Ho provato il programma spaziometria....
Per quel che ho potuto provare mi sembra fatto molto bene...
Meglio di molti altri programmi..... a pagamento (anche se non li uso)

Congratualazioni...
Ciao

fillotto · 20 Giugno 2011

ho fatto girare l'ultimo script di Luigi (vedi su)
con 330 estrazioni questo è parte dell'output:
Classifica dei numeri ottenuti sommando col fuori90
i numeri di 2 singole posizioni per ciascuna estrazione sulle 10 ruote esclusa la nazionale

Analisi da : [00001] [ 1 ] 07.01.1871 a [08393] [ 73] 18.06.2011
Estrazioni esaminate :330

Ruota P1 P2 Ritardo RitMax Freq I.C. Pronostico EsitoColpi
Napoli 1 2 23 23 50 3,4848 70
Cambiando questa istruzione da:
aN(1) = Fuori90(Estratto(idEs,ClsI.ruota,ClsI.p1) + Estratto(idEs,ClsI.ruota,ClsI.p2))
a:
aN(1) = Fuori90(Estratto(idEs,ClsI.ruota,ClsI.p1) - Estratto(idEs,ClsI.ruota,ClsI.p2)) con meno al posto di più
ho questo output :
Ruota P1 P2 Ritardo RitMax Freq I.C. Pronostico EsitoColpi
Napoli 1 2 23 23 50 3,4848 90
ora , vorrei sapere, mentre "70" è la somma (giustamente infatti 21+49) del primo +il secondo di napoli
che operazione ha fatto l'istruzione quando ho messo - invece di +
"90" infatti non è la differenza del 1° - il 2° di NA (21-49=62) , tutti gli altri parametri sono uguali il n° del pronostico cambia ma in maiera che non capisco con una grande quantità del "90" .
Tutto questo per capire meglio.

LuigiB · 20 Giugno 2011

Ciao Fil se tu metti meno al posto del piu capitano senz'altro casi dove il risultato sia negativo , un risultato negativo ovvero <0 la funzione fuori90 lo fara diventare automaticamente 90 ecco il perche della presenza promiscua di tutti quei 90

Se vuoi usare - inveche che + devi levare il fuori90 e invece di
fare la sottrazione con il - devi usare la funzione Distanza che appunto calcola la distanza ciclometrica tra 2 numeri.

fillotto · 21 Giugno 2011

quote:Originally posted by LuigiB

Ciao Fil se tu metti meno al posto del piu capitano senz'altro casi dove il risultato sia negativo , un risultato negativo ovvero <0 la funzione fuori90 lo fara diventare automaticamente 90 ecco il perche della presenza promiscua di tutti quei 90
Se vuoi usare - inveche che + devi levare il fuori90 e invece di
fare la sottrazione con il - devi usare la funzione Distanza che appunto calcola la distanza ciclometrica tra 2 numeri.

Grazie Luigi, in effetti pensavo a una cosa del genere ma non l'avevo afferrata in pieno!!
Sto pensando , e se io metto preventivamente al 1° dato un +90 e successivamente il "-" , dovrebbe funzionare

.... mo provo

fillotto · 21 Giugno 2011

quote:Originally posted by fillotto

quote:Originally posted by LuigiB

Ciao Fil se tu metti meno al posto del piu capitano senz'altro casi dove il risultato sia negativo , un risultato negativo ovvero <0 la funzione fuori90 lo fara diventare automaticamente 90 ecco il perche della presenza promiscua di tutti quei 90
Se vuoi usare - inveche che + devi levare il fuori90 e invece di
fare la sottrazione con il - devi usare la funzione Distanza che appunto calcola la distanza ciclometrica tra 2 numeri.

Clicca per espandere...

Grazie Luigi, in effetti pensavo a una cosa del genere ma non l'avevo afferrata in pieno!!
Sto pensando , e se io metto preventivamente al 1° dato un +90 e successivamente il "-" , dovrebbe funzionare .... mo provo

Funziona!!! infatti mettendo:
aN(1) = Fuori90(Estratto(idEs,ClsI.ruota,ClsI.p1) + 90 - Estratto(idEs,ClsI.ruota,ClsI.p2)) il risultato mi da 62.
MA QUI VIENE IL BELLO!!! COME MAI L'OUTPUT E' IL MEDESIMO COME SE FACESSI LA SOMMA TUTTI I PARAMETRI UGUALI AD ECCEZIONE DEL NUMERO
PREVISIONE [?][?][?][?] 62 (COL -) 70 (COL +)
SECONDO VOI PERCHE' SUCCEDE QUESTO?

fillotto · 21 Giugno 2011

SCUSA LUIGI RISOLTO L'ARCANO è CHE NON CAMBIAVO ALLO STESSO MODO ANCHE IL SUCCESSIVO RIGO DELLO SCRIPT DELLA SUB CalcoloStat;
Comunque in questo modo mettendo a confronto i 2 output si possono fare delle considerazioni ... stimolanti tipo i sincroni può capitare (esempio) che nella ruota di CA che con la somma di P1 e P2
abbia un ritardo significativo diciamo 23 (parliamo sempre su 330 es)
e con la differenza di P2 e p5 sempre sulla ruota di CA un ritardo di 23 ...... he he è da approfondire...Fill
Attenzione facendo altri controlli non mi trovo più con l'output se metto il segno meno

vedrò più tardi!!!

fillotto · 23 Giugno 2011

MANNAGGIA CHE FRUSTRAZIONE, MA è POSSIBILE CHE NON RIESCA A FARE UNA COSA SIMILE ?!?!!
Luigi mi dice "devi usare la funzione Distanza che appunto calcola la distanza ciclometrica tra 2 numeri" ma la distanza implica sempre 2 soluzioni!!! io invece vorrei un numero solo :
10 - 80 per come la vedo io è = a 20
60 - 80 " " " " = a 70 mentre la distanza è = a 20
il vantaggio è quello di avere un solo numero x ogni operazione cosi come succede con la somma !!!
Mettendo PREVENTIVAMENTE sempre 90 in questo rigo di codice:
aN(1) = Fuori90(Estratto(idEs,ClsI.ruota,ClsI.p1) + 90 - Estratto(idEs,ClsI.ruota,ClsI.p2))
sembrerebbe che va bene ma il riscontro con l'output non è esattamente quello che succede nella realtà.
Eppure questo accorgimento con excel è semplicissimo chi mi può aiutare???
Chiedo scusa ,mi sto "ATTORCIGLIANDO" su questo concetto da ulteriori
controlli sembra vada bene in effetti in teoria dovrebbe andare bene se il pericolo è quello che il primo num è inferiore al 2° e quindi mi da come risultato 90, se metto preventivamente+90 ad ogni operazione che faccio evito il problema giacchè se anche fosse il 1° num magg del 2° il fuori 90 lo annullerebbe .... o.... no????

imported_n/a · 23 Giugno 2011

Ciao Fill, per la differenza di 2 numeri puoi anche usare la funzione ABS che calcola la differenza tra 2 numeri.

vedi se può servirti allo scopo.

Sub Main

a = 10
b = 80
c = Abs(a-b) ' differenza
d = Distanza(a,b)' distanza

Scrivi"Differenza.... = " & c
Scrivi"Distanza...... = " & d

End Sub

Mike58

LuigiB · 23 Giugno 2011

ragazzi abs da il valore assoluto di un numero non la differenza
tra due numeri ! Abs togli il segno al numero.
Ora File nel programma ci sono 2 funzioni , vedi tu quale delle 2 vuoi adoperare , io ti riporto cosa dice l'help... ciao !

funzione Differenza

Codice:

Differenza(n1, n2) As Integer




Note:




Esegue la sottrazione algebrica tra due numeri ma se il sottraendo è inferiore del minuendo  scambia i due numeri in modo da impedire un risultato negativo

               

Valore di ritorno:




Torna la differenza algebrica tra due numeri ma se il sottraendo è inferiore del minuendo  scambia i due numeri prima dell'operazione in modo da impedire un risultato negativo




Parametri:




n1
 Primo numero
 
n2
 Secondo numero

funzione Distanza

Codice:

Distanza(a, b) As Integer




Note:




Calcola la distanza ciclometrica tra 2 numeri

               

Valore di ritorno:




Torna il valore dato dalal distanza ciclometrica tra i due numeri specificati







Parametri:




a
 primo numero

       
 
b
 secondo numero

Per Luigi .. se c'è

Advanced Member >PLATINUM<

Premium Member

Premium Member

Premium Member

Advanced Member >PLATINUM<

LuigiB

Guest

Premium Member

LuigiB

Guest

Premium Member

LuigiB

Guest

Roby

Guest

Premium Member

Advanced Member >PLATINUM<

LuigiB

Guest

Advanced Member >PLATINUM<

Advanced Member >PLATINUM<

Advanced Member >PLATINUM<

Advanced Member >PLATINUM<

Advanced Premium Member

LuigiB

Guest