Novità

Per Salvo 50

R

Raimbow58

Junior Member
Quadrato somma 91
Prima di tutto, un grazie per gli script. Se ti è possibile avrei bisogno di questo script perchè fare una ricerca visiva è molto complicato. Bisogna rintracciare su due ruote in maniera isotopa due numeri di somma 91. Trovata la condizione la previsione consiste nella differenza dei due numeri e facendo il complemento a 91.
RO 21 90 28 66 36
NZ 70 82 12 25 47
21-70 somma 91 e 66-25 somma 91, differenza 21-66=45 complemento a 91=46 primo ambo. Secondo ambo vertibile del 45=54 complemento a 91=37
Previsione: 45-46 e 54-37.
Spero che la spiegazione fatta vada bene. Ho provato a modificare lo script quadrato somma 90 che avevi fatto tempo fa, ma non ci sono riuscito.
Grazie in anticipo
Allego lo script

Option Explicit
Sub Main
Dim FIn,Ini,A,B,C,D,Clp,Salvo50,Es,OK,Tutte
Dim R1,R2,P1,P2,P5,P6,E1,E2,Caso,Casi
Dim AB90,CD90,AB05,CD05,AC90,BD90
Dim AC05,BD05,AD90,BC90,AD05,BC05
Dim Num(3),Ruo(2),Ruote(1),Posta(3)
FIn = EstrazioneFin
Ini = CInt(InputBox("Inserisci l'estrazione che vuoi iniziare",Salvo50,9400))
Clp = CInt(InputBox(" Per quanti colpi vuoi giocare?",Salvo50,15))
Tutte = CInt(InputBox(" SE VUOI FARE LA RICERCA ANCHE PER TUTTE LE RUOTE METTI 1 ALTRIMENTI UN ALTRO NUMERO",Salvo50,0))
Call ScegliRange(Ini,FIn,Ini,FIn)
Scrivi Space(12) & "Per Raimbow58 - Quadrato somma 90 (ISOTOPO) - script Salvo50",1,,4,,3,,1
Posta(2) = 1
'Posta(3) = 1
For Es = Ini To FIn
Messaggio Es
AvanzamentoElab Ini,FIn,Es
Caso = 0
For R1 = 1 To 10
For R2 = R1 + 1 To 12
If R2 = 11 Then R2 = 12
For P1 = 1 To 4
For P2 = P1 + 1 To 5
A = Estratto(Es,R1,P1)
B = Estratto(Es,R1,P2)
C = Estratto(Es,R2,P1)
D = Estratto(Es,R2,P2)
If A > 0 And C > 0 Then
'A---B
'| |
'C---D
If A <> C And A <> D And B <> C And B <> D Then
AB90 = Fuori90(A + B) : CD90 = Fuori90(C + D) : AC90 = Fuori90(A + C)
BD90 = Fuori90(B + D) : AD90 = Fuori90(A + D) : BC90 = Fuori90(B + C)
AB05 = Distanza(A,B) : CD05 = Distanza(C,D) : AC05 = Distanza(A,C)
BD05 = Distanza(B,D) : AD05 = Distanza(A,D) : BC05 = Distanza(B,C)
If((AB90 = 90 And CD90 = 90) And((AC05 = 05 And BD05 = 05)Or((AD05 = 05 And BC05 = 05))))_
Xor((AC90 = 90 And BD90 = 90) And((AB05 = 05 And CD05 = 05)Or((AD05 = 05 And BC05 = 05))))_
Xor((AD90 = 90 And BC90 = 90) And((AB05 = 05 And CD05 = 05)Or((AC05 = 05 And BD05 = 05))))Then
OK = 0
If(AB90 = 90 And CD90 = 90) And(AC05 = 05 And BD05 = 05) Then Num(1) = Fuori90(A + C): OK = 1
If(AB90 = 90 And CD90 = 90) And(AD05 = 05 And BC05 = 05) Then Num(1) = Fuori90(A + D): OK = 1
If(AC90 = 90 And BD90 = 90) And(AB05 = 05 And CD05 = 05) Then Num(1) = Fuori90(A + B): OK = 1
If(AC90 = 90 And BD90 = 90) And(AD05 = 05 And BC05 = 05) Then Num(1) = Fuori90(A + D): OK = 1
If(AD90 = 90 And BC90 = 90) And(AB05 = 05 And CD05 = 05) Then Num(1) = Fuori90(A + B): OK = 1
If(AD90 = 90 And BC90 = 90) And(AC05 = 05 And BD05 = 05) Then Num(1) = Fuori90(A + C): OK = 1
If Num(1) <> 90 And OK = 1 Then
Num(2) = ComplAdX(Num(1)) : Num(3) = 90
Caso = Caso + 1
Casi = Casi + 1
Scrivi String(89,"*") & " Casi Totali " & FormattaStringa(Casi,"0000"),1,,,2
Scrivi String(80,"*") & " Estrazione " &(Es) & " caso " & FormattaStringa(Caso,"0000"),1,,,1
Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
Scrivi " " & SiglaRuota(R1) & " ",1,0
For P5 = 1 To 5
E1 = Estratto(Es,R1,P5)
If E1 = A Or E1 = B Then
ColoreTesto 2
Else
ColoreTesto 0
End If
Scrivi Format2(E1) & " ",1,0
ColoreTesto 0
Next
Scrivi
Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
Scrivi " " & SiglaRuota(R2) & " ",1,0
For P6 = 1 To 5
E2 = Estratto(Es,R2,P6)
If E2 = C Or E2 = D Then
ColoreTesto 2
Else
ColoreTesto 0
End If
Scrivi Format2(E2) & " ",1,0
ColoreTesto 0
Next
Scrivi
Scrivi
Scrivi Space(15) & "Solo un gruppo con somme uguali a 90",1,0,,2
Scrivi Space(9) & "Solo un gruppo con Distanze = a 5",1,,,2
Scrivi Space(19) & "Somme " & Space(6) & " Somme" & Space(6) & " Somme",1,0
Scrivi Space(11) & "Distanze " & Space(3) & " Distanze ",1,0
Scrivi Space(2) & " Distanze",1
Scrivi Space(5) & "Estratti " & Space(2) & "Orizzontali" & " - ",1,0
Scrivi "Verticali - Diagonali Orizzontali - Verticali - Diagonali",1
Scrivi Space(6) & Format2(A) & " " & Format2(B) & Space(9) & Format2(AB90),1,0
Scrivi Space(11) & Format2(AC90) & Space(10) & Format2(AD90),1,0
Scrivi Space(16) & Format2(AB05) & Space(11) & Format2(AC05) & Space(10) & Format2(AD05),1
Scrivi Space(6) & Format2(C) & " " & Format2(D) & Space(9) & Format2(CD90),1,0
Scrivi Space(11) & Format2(BD90) & Space(10) & Format2(BC90),1,0
Scrivi Space(16) & Format2(CD05) & Space(11) & Format2(BD05) & Space(10) & Format2(BC05),1
Scrivi
Ruo(1) = R1 : Ruo(2) = R2 : Ruote(1) = TU_
EliminaRipetuti Num
ImpostaGiocata 1,Num,Ruo,Posta,Clp
If Tutte = 1 Then ImpostaGiocata 2,Num,Ruote,Posta,Clp
Gioca Es
End If
End If
End If
End If
Next
Next
Next
Next
If ScriptInterrotto Then Exit Sub
Next
ScriviResoconto
End Sub





Replica (Quote)

Report Modifica
 
Ciao a Tutti.

Ciao Raimbow58

Codice: 
Option Explicit
Sub Main
   Dim FIn,Ini,A,B,C,D,Clp,Salvo50,Es
   Dim R1,R2,P1,P2,P5,P6,E1,E2,Caso,Casi
   Dim Sac,Sbd,Di1,Di2,Di3,Ver1
   Dim Ambo1(2),Ambo2(2),Ruote(2),Posta(2)
   FIn = EstrazioneFin
   Ini = CInt(InputBox("Inserisci l'estrazione che vuoi iniziare",Salvo50,9575))
   Clp = CInt(InputBox(" Per quanti colpi vuoi giocare?",Salvo50,15))
   Call ScegliRange(Ini,FIn,Ini,FIn)
   Scrivi Space(12) & "Per Raimbow58 - Quadrato somma 91 in Verticale (ISOTOPO) - script Salvo50",1,,4,,3,,1
   Posta(2) = 1
   For Es = Ini To FIn
      Messaggio Es
      AvanzamentoElab Ini,FIn,Es
      Caso = 0
      For R1 = 1 To 10
         For R2 = R1 + 1 To 12
            If R2 = 11 Then R2 = 12
            For P1 = 1 To 4
               For P2 = P1 + 1 To 5
                  A = Estratto(Es,R1,P1)
                  B = Estratto(Es,R1,P2)
                  C = Estratto(Es,R2,P1)
                  D = Estratto(Es,R2,P2)
                  If A > 0 And C > 0 Then
                     'A---B
                     '|   |
                     'C---D
                     If A <> C And A <> D And B <> C And B <> D Then
                        If A + C = 91 And B + D = 91 Then
                           Sac = A + C : Sbd = B + D
                           Di1 = Differenza(A,B): Di2 = 91 - Di1
                           Ver1 = Vert(Di1): Di3 = 91 - Ver1
                           Ambo1(1) = Di1 : Ambo1(2) = Di2
                           Ambo2(1) = Ver1 : Ambo2(2) = Di3
                           Caso = Caso + 1
                           Casi = Casi + 1
                           Scrivi String(89,"*") & " Casi Totali " & FormattaStringa(Casi,"0000"),1,,,2
                           Scrivi String(80,"*") & " Estrazione " &(Es) & " caso " & FormattaStringa(Caso,"0000"),1,,,1
                           Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
                           Scrivi " " & SiglaRuota(R1) & " ",1,0
                           For P5 = 1 To 5
                              E1 = Estratto(Es,R1,P5)
                              If E1 = A Or E1 = B Then
                                 ColoreTesto 2
                              Else
                                 ColoreTesto 0
                              End If
                              Scrivi Format2(E1) & " ",1,0
                              ColoreTesto 0
                           Next
                           Scrivi
                           Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
                           Scrivi " " & SiglaRuota(R2) & " ",1,0
                           For P6 = 1 To 5
                              E2 = Estratto(Es,R2,P6)
                              If E2 = C Or E2 = D Then
                                 ColoreTesto 2
                              Else
                                 ColoreTesto 0
                              End If
                              Scrivi Format2(E2) & " ",1,0
                              ColoreTesto 0
                           Next
                           Scrivi
                           Scrivi Space(25) & Format2(A) & " + " & Format2(C) & " = " & Format2(Sac),1
                           Scrivi Space(25) & Format2(B) & " + " & Format2(D) & " = " & Format2(Sbd),1
                           Scrivi
                           Scrivi Space(9) & " Differenza tra " & Format2(A) & " e " & Format2(B) & " = " & Format2(Di1),1
                           Scrivi Space(25) & Format2(Sac) & " - " & Format2(Di1) & " = " & Format2(Di2),1
                           Scrivi Space(9) & " Vertibile di " & Space(7) & Format2(Di1) & " = " & Format2(Ver1),1
                           Scrivi Space(25) & Format2(Sac) & " - " & Format2(Ver1) & " = " & Format2(Di3),1
                           Ruote(1) = R1 : Ruote(2) = R2
                           ImpostaGiocata 1,Ambo1,Ruote,Posta,Clp
                           ImpostaGiocata 2,Ambo2,Ruote,Posta,Clp
                           Gioca Es
                        End If
                     End If
                  End If
               Next
            Next
         Next
      Next
      If ScriptInterrotto Then Exit Sub
   Next
   ScriviResoconto
End Sub
 
Devi accedere o registrarti per poter rispondere.

Ultima estrazione Lotto

  • Estrazione del lotto
    martedì 24 marzo 2026
    Bari
    51
    62
    27
    44
    28
    Cagliari
    73
    24
    23
    48
    43
    Firenze
    46
    15
    72
    52
    31
    Genova
    17
    09
    29
    19
    27
    Milano
    06
    70
    05
    76
    79
    Napoli
    51
    16
    26
    11
    48
    Palermo
    88
    57
    76
    84
    09
    Roma
    90
    38
    32
    69
    53
    Torino
    85
    84
    58
    60
    87
    Venezia
    14
    41
    26
    90
    52
    Nazionale
    40
    24
    59
    01
    46
    Estrazione Simbolotto
    Firenze
    07
    08
    19
    35
    04
    Archivio estrazioni lotto Ritardi top 15 Frequenze top 15

Ultimi Messaggi

Indietro
Alto