Richiesta listato frequenza ambo in decina

[solare]

chiedo se è possibile un listato che faccia un controllo
relativo alle decine 1....10------11...20 ecc
in pratica dovrebbe indicare la frequenza degli ambi in decina in cicli da 18
per un totale di 10 cicli cioè 180 estrazioni.
es:
Risultato della ricerca:
Ruota Periodo dal al decina Frequenza ambi

Bari 3/1/2012 11/2/2012 1....10 2
14/2/2012 24/3/2012 1....10 4

Totale ambi......................................................6


Naturalmente il controllo va fatto per 10 cicli da 18 estrazioni

analizzando tutte le decine così da avere un resoconto totale su quella ruota.
Grazie

 

[Joe91]

Ciao Solare,

Vorrei fornirti lo script che hai richiesto ... costruendolo passo-passo,

per chi volesse capire ... poi ... come funziona e per chi fosse interessato,

ad apprendere come traformare l' enunciato ... negli algoritmi, capaci calcolare quanto hai richiesto.

La "struttura portante" è un Loop (Ciclo/Anello) che (si) ripete per 180 volte.

Un Ciclo-For-Next per gestire i blocchi di Estrazioni ("Es") che vogliamo controllare.

All'interno di esso, dunque TRA il "For" e il "Next", ho inserito un contatore ... "K"

che si incrementa di una "Unità" ovvero il "+1" ad ogni successivo passaggio.

Ed ancora ... una linea, di controllo / debug:

"Scrivi K" per verificare se tutto funziona a dovere

e ... "il ciclo" viene eseguito le 180 volte previste.

[SIZE=2][COLOR=#000080][SIZE=2][COLOR=#000080]Sub main()

For Es = EstrazioneFin-179 To EstrazioneFin 
K=K+1
Scrivi K
Next

End Sub
[/COLOR][/SIZE][/COLOR][/SIZE]

Tutto funziona al meglio ... e lo script "Scrive" : 1.2.3.4....180 linee di testo.

Prossima tappa: dividere queste 180 Estrazioni "Es", in 18 decine.

Buona Giornata a a tutti.

 

[Joe91]

Come fare ?

Semplice:

Quando k di passaggio in passaggio è cresciuto fino a 10 ... lo si azzera.

Le istruzioni semplicissime sono: If K=10 Then k=0 : Scrivi

Aggiungo questa linea al programma precedente ... Che diventa:

[SIZE=2][COLOR=#000080][SIZE=2][COLOR=#000080]Sub main()

For Es = EstrazioneFin-179 To EstrazioneFin 
K=K+1
Scrivi K 
If K= 10 Then K=0 : Scrivi 
Next

End Sub

Ho inserito anche: "Scrivi" -senza argomenti-
[/COLOR][/SIZE][/COLOR][/SIZE]
ed effettivamente inserisce una linea vuota ...

che è utile per separare i blocchi di decine di estrazioni.

 

[Joe91]

Riassumo dicendo che abbiamo costruito l'anello principale ...

For-Next utilizzando la Variabile "Es" acronimo di Estrazione

Quindi visualizziamo anche questa "Es" nel seguente modo :

dove già si inrementa K ...

K=k+1 : Scrivi K & "° " & Es

":" ci permette di scrive più istuzioni sulla stessa linea.

"&" concatena i vari argomenti dell' istruzione "Scrivi"

"° " separa e "trasforma" il Numero Cardinale in Ordinale (1.2.3 ... diventa primo ... secondo ... terzo ... alla nosta lettura)

"Es" è la variabile di controllo ed è il numero idetificativo dell' Estrazione (8 mila e rotti attualmente)

che si sta "facendo ciclare" ovvero considerando al momento in cui "Scrivi" la palesa.

L' "Output" dello script:

1° 8357
2° 8358
3° 8359
4° 8360
5° 8361
6° 8362
7° 8363
8° 8364
9° 8365
10° 8366

.... omesso ...

1° 8527
2° 8528
3° 8529
4° 8530
5° 8531
6° 8532
7° 8533
8° 8534
9° 8535
10° 8536

 

[Joe91]

Ora, non ... rimane che andare a raccogliere ...

le "Es" ovvero ... il numero di riferimento di ogni estrazione

che è l'inizio ("Ini") e la fine ("Fin") di ogni periodo.

Abbiamo già velocemente visto dove, quando e come utilizzare "If"

per azzerare "K" è ovvio che in questo "punto" finisce il periodo


Quindi in sintesi l'istruzione completa sono:

If K=1 Then Ini = Es

e ...

"If K=10 Then Fin = Es "

che ho aggiunto ove indicato nello script.

Dopo aver raccolto il valore "Ini" e "Fin"

con cui iniziano e finiscono i cicli di 10 estrazioni

per controllo con la solita "Scrivi" li porto all'evidenza.

Il codice ... fino a qui.

[SIZE=2][COLOR=#000080][SIZE=2][COLOR=#000080]Sub main()
For R = 1 To 1
For Es = EstrazioneFin-179 To EstrazioneFin 
K=k+1 : Scrivi K  & "° " & Es 
If K=1 Then Ini=Es
If k = 10 Then Fin = ES : K = 0 : Scrivi : Scrivi (Ini) & "-" & (Fin) : Scrivi 
Next
Next
End Sub

[/COLOR][/SIZE][/COLOR][/SIZE]

 

[solare]

Grazie joe91
gentilissimo

 

[Roby]

Ottimo lavoro ci ho capito perfino io che non mastico di scritp
grazie per il tuo contributo.. Avevo a chiederti poi un quesito la stringa di compatibilita' affinche l'elaborato possa anche esser letto da altri noti programmi sai indicarmi come si imposta e se in questo e' presente? Sarebbe poi cosa interessante immetterla sempre in modo da catturare l'attenzione anche di chi usa programmi diversi dai noti pubblicizzati come trovo ottima e senza alcuna sviolinata la tua iniziativa cui sarebbe cosa GRADITA SE CONTINUASSE per il futuro e sempre tempi a te permettenti ancora grazie per il tuo contributo

un saluto e buon lavoro
ib63

 

[Joe91]

Ringrazio Solare ed IB63,

Si, confermo che appena mi sarà possibile ... passeremo a sviluppare "le decine" ...

e cercherò di farlo anche in questo caso im modo ... molto semplice.

Non ho capito invece, a quale, stringa si faccia riferimento.

Lo script finora proposto... dovrebbe "girare" sia con Spaziometria, sia con L8 che con LD.

Eventuali piccole correzioni per renderlo compatibile tra un ambiente e l'altro potrebbero essere necessarie,

se ... nel prosieguo ... si evidenziasse la necessità ... dopo averne preso conoscenza si potrà appunto,

adottare le strategie necessarie.

Quindi avendo per ora inquadrato il discorso periodi/cicli ... ora si tratta di redigere gli algoritmi per le decine.

Ovvero: "Un listato che faccia un controllo relativo alle decine 1....10------11...20 ecc"

Da cui risulta evidente quale tipo di decine si dovranno considerare.

Qui utilizzeremo due cicli For-Next ... nidificati (ovvero ... uno dentro l'altro)

Uno per le "Decine" (intese matematicamente da ZERO A OTTANTA con il passo 10)

ed il secondo più interno ... per le "Unità" (intese matematicamente da UNO a DIECI).

Ho predisposto una memoria per i Numeri (Nu) capace di contenerne 10 in questo modo: Dim Nu(10)

Come precedentemente fatto, al termine ho predisposto una istruzione per il controllo: Scrivi stringanumeri

Ecco dunque (il secondo) programma come l'ho descritto:

Sub Main
 Dim Nu(10)
 For D = 0 To 80 Step 10
  For U = 1 To 10
   Nu(U) =  D + U
  Next
  Scrivi StringaNumeri(Nu)
 Next
End Sub

Buona serata a tutti.

 

[Antonin]

Grande joe91 ti seguo...

 

[Joe91]

Ciao Antonio. Grazie anche a te.

Buona Sera a tutti ...

prima di continuare (domani spero) una piccola osservazione.

Qualcuno più attento potrà obiettare che come con lo script al messaggio #8

si sono gestite le Decine di 90 numeri ... si sarebbe potuto gestire, ALLO STESSO MODO ...

le Decine di 180 Estrazioni. Con pochissime righe di programma. Vero. Verissimo.

Quindi dimostrato che possono esistere più soluzioni (o script diversi) capaci ... delle stesse cose.

Qui dunque ... inizia l'ottimizzazione ... tra le tante soluzioni bisognerebbe anche individuare ... la migliore.

Non è questo il caso ... e ritengo valide le due proposte soprattutto perchè, nella loro diversità ...

forniscono ognuna a modo suo un "output" di facilissima consultazione e/o debug.

Ovverro sono ben orientate ... al loro scopo. (Compreso quello didattico).

Ora si potrebbe nuovamente scegliere ... tra il "fai da te" ... utilizzando pochissime

istruzioni dedicate ... oppure affidarsi alle istruzioni preposte ... al conteggio della frequenza.

Nel primo caso bisognerebbe generare i 45 ambi per ogni decina e poi conteggiarli uno ad uno.

Ho preferito e svilupperò invece utilizzando l' "istruzione regina": SerieFrequenza.

Essa richiede parametri ... ovvero:

Quante estrazioni deve controllare ... (Da "Ini" a Fin")

Quali Numeri ("Nu")

In quali Ruote ("Ru")

Per Quale Sorte ("2") ricordando che 1 = Estratto / 2 = Ambo / 3 = Terno ecc..

Quindi SF = Seriefreq(Ini,Fin,Nu,Ru,2) dove rimane, ancora da definire, il vettore Ruote.

Vedremo come ...

Buona Serata tutti.

 

[solare]

Ciao joe91 io tra i tanti listati ho trovato questo fatto dal grande LuigiB,fa le stesse cose che vorrei facessi per la ricerca degli ambi però si limita a fare statistica per l'intera decina
se ti può aiutare eccolo:

Option Explicit
Sub Main
Dim Ruota
Dim nCicli
Dim Inizio,Fine
Dim idEstr
Dim idDecina
Dim sErr
Dim nTotale
ReDim aNum(10)
ReDim aRuote(1)
Ruota = ScegliRuota
nCicli = Int(InputBox("Inserire il numero dei cicli da 18",,18))
Inizio =(EstrazioneFin -(nCicli * 18)) + 1
Fine = EstrazioneFin - 17
If nCicli > 0 And Inizio > 0 And Ruota > 0 Then
aRuote(1) = Ruota
For idDecina = 1 To 9
nTotale = 0
Call AlimentaNumeri(idDecina,aNum)
ReDim aTitoli(2)
aTitoli(1) = " Range "
aTitoli(2) = " Frequenza "
Call InitTabella(aTitoli)
For idEstr = Inizio To Fine Step 18
ReDim aValori(2)
aValori(1) = CStr(idEstr) & " - " & CStr(idEstr + 17)
aValori(2) = SerieFreq(idEstr,idEstr + 17,aNum,aRuote,1)
nTotale = nTotale + CLng(aValori(2))
Call AddRigaTabella(aValori)
Next
ReDim aValori(2)
aValori(1) = "Totale"
aValori(2) = nTotale
Call AddRigaTabella(aValori,vbYellow)
Call Scrivi(" meglio elaborare dal 01 1945 in cicli da 18 estrazioni tot. 249 cicli meglio un totale altissimo...purchè abbia freq alta ultimi 2 cicli ")
Call Scrivi("Ruota in gioco " & NomeRuota(Ruota))
Call Scrivi("Decina analizzata " & StringaNumeri(aNum))
Call Scrivi
Call CreaTabella
Next
Else
If nCicli <= 0 Then
sErr = "Numero di cicli non valido"
End If
If Inizio <= 0 Then
sErr = "Troppi cicli rispetto alle estrazioni del range"
End If
If idDecina <= 0 Then
sErr = "Nessuna decina selezionata"
End If
If Ruota <= 0 Then
sErr = "Nessuna ruota selezionata"
End If
MsgBox sErr,vbCritical
End If
End Sub
Function ScegliDecina()
ReDim aVoci(8)
Dim k,i
For k = 1 To 81 Step 10
aVoci(i) = "Decina " & k & " - " & k + 9
i = i + 1
Next
ScegliDecina = ScegliOpzioneMenu(aVoci,0,"Selezione decina") + 1
End Function
Sub AlimentaNumeri(idDecina,aNum)
Dim i,k,y
i =((idDecina - 1) * 10) + 1
For k = i To(i - 1) + 10
y = y + 1
aNum(y) = k
Next
End Sub
　

 

[Joe91]

Ciao solare,

Ti ringrazio.

Ho letto lo script ... che andrebbe corretto, tutto, prima di poter funzionare ... sul mio PC.

Questo perchè cosi' come è stato impaginato dall'editor .... purtroppo non gira.

Comunque sia, si, è un bello script e dimostra che esistono anche altre soluzioni ... simili.

In particolare, come vedi :


SubAlimentaNumeri(idDecina,aNum)
Dimi,k,y
i=((idDecina- 1) * 10) + 1
Fork=iTo(i- 1) + 10
y=y+ 1
aNum(y) =k
Next
EndSub

E' molto simile, a quanto avevo scritto io.

Zero è uguale a "1-1" & "* 10" ... è equivalente a "Step 10" (Sono "gestioni differenti" della medesima contabilità)

Ho fatto scelte differenti. Anzicchè lasciare una "Sub" (alimentanumeri) da richiamare (Enne volte)

io, l'ho portata, all'interno della "Main" ... ed anche peggio.

Voglio infatti provare ... estrazione per estrazione ... quanti "Ambi in Decina" ci sono.

La prima linea dell script diventa:

Dim NU(10), RU(1) : RU(1)=BA_

Creando il vettore per contenere "la Ruota" e questa è esplecitamente posta "UGUALE" a Bari.

La "fusione" dei miei 2 script precedenti diventa così:

Sub Main()
 
Dim Nu(10), Ru(1) : Ru(1)=BA_
For Es = EstrazioneFin-179 To EstrazioneFin 
K=k+1 : Scrivi K  & "° " & Es 
If K=1 Then Ini=Es
'REM Qui inizia ... il secondo script .....
 For D = 0 To 80 Step 10
  For U = 1 To 10
   Nu(U) =  D + U
  Next
  Scrivi StringaNumeri(Nu)
 Next : Scrivi 
'REM  ... finisce qui ...
If k = 10 Then Fin = ES : K = 0 : Scrivi : Scrivi (Ini) & "-" & (Fin) : Scrivi 
Next

End Sub

 

[Joe91]

Lo script, presente al messaggio 12, gestisce ora la ruota, le decine, ed i gruppi di estrazioni.

Si tratta di convertire il tutto ... nelle frequenze con l'istuzione dedicata ... già descritta:

Quindi al posto di Scrivi StringaNumeri ... scriveremo "SF" ovvero la frequenza ... in quel "gruppo di numeri".

In modo difforme, dalla richiesta ... è, per singola estrazione, singola decina, singola Ruota...

Rimane, ultima cosa da realizzare i totali per il gruppo. Prima di questo ...

Ho tolto ... "Scrivi K " per ogni successiva estrazione del gruppo ...

e, ho convertito (Es) nella "data di estrazione" corrispondente.

Questo perchè a noi comuni mortali, è più intuitiva ... di "8 Mila X Y Z".

Per fare questo ho utilizzzando l'istruzione ... Scrivi DataEstrazione (Es).

Ho inserito, anche, una formattazione per ogni "SF" così da poter aver un incolonnamento leggibile

Per questo ho usato "FormatSpace" ed i suoi parametri: ",4" spazi , ",1" ... incolonnato a destra.

Ho ritenuto opportuno anche scrivere gli Estratti (di Bari) in quella data ... prima di "scomporli"

e conteggiarne la frequenza ... per Ambo in Decina, per debug e per evitare di doverli cercare ... altrove.

Quindi il nuovo output è:

... omesso ...

28.04.2012  27.55.51.44.46   0   0   0   0   1   1   0   0   0
02.05.2012  87.18.02.81.78   0   0   0   0   0   0   0   0   1
03.05.2012  34.13.60.33.46   0   0   0   1   0   0   0   0   0
05.05.2012  39.52.60.75.37   0   0   0   1   0   1   0   0   0
08.05.2012  08.24.64.25.89   0   0   1   0   0   0   0   0   0
10.05.2012  56.81.28.74.83   0   0   0   0   0   0   0   0   1
12.05.2012  77.11.23.03.29   0   0   1   0   0   0   0   0   0
15.05.2012  18.03.80.01.20   1   1   0   0   0   0   0   0   0
17.05.2012  65.19.36.87.58   0   0   0   0   0   0   0   0   0
19.05.2012  57.67.56.10.08   1   0   0   0   0   1   0   0   0

8528-8537

La frequenza "1" nella Prima & Quinta colonna" del 19.05.2012

Riferiscono della caduta dell'Ambo 08.10 e dell'Ambo 56.57 nelle rispettive decine.

 

[Joe91]

Lo script ... aggiornato al messagigo precedente:

Sub Main()

Dim Nu(10),Ru(1) : Ru(1) = BA_
For Es = EstrazioneFin - 179 To EstrazioneFin
K = k + 1 : Scrivi DataEstrazione(Es) & "  " & StringaEstratti(Es,Ru(1)),1,0
If K = 1 Then Ini = Es
'REM Qui inizia ... il secondo script .....
For D = 0 To 80 Step 10
For U = 1 To 10
Nu(U) = D + U
Next
SF = SerieFreq(Es,Es,Nu,Ru,2)
Scrivi FormatSpace(SF,4,1),0,0 
Next : Scrivi
'REM ... finisce qui ...
If k = 10 Then Fin = ES : K = 0 : Scrivi : Scrivi(Ini) & "-" &(Fin) : Scrivi
Next

End Sub

"Leggendo" lo script ... che ben conosciamo,

si nota che a causa "dell'errore volutamente commesso"

come potrebbe essere/accadere ... per fretta ... inesperienza ecc,

Ovvero quello di aver generato "i numeri" (di cui si compongono le decine),

dentro il ciclo principale "Main" e non in una SUB ESTERNA ...

fa si che, quando sarebbe il momento di calcolare e stampare i totali per ogni decina di estrazioni ...

Cioè quando si hanno, effettivamente, a disposizione i valiori "INI" & "FIN"

"Le decine" ... "I numeri" ... "Nu" ... hanno -finito- i loro cicli e ... sono "già passati". TUTTI.

Quindi ... è, come aver perso il treno.

Due sono le soluzioni ... La prima, è quella adottata da Luigi.

Ovvero riportare lo script "al come" l'avevo costruito,

con una MAIN ... ed una SUB per generare/alimentare/ ... "i numeri"

MA ... avendolo già fatto Luigi, basta imparare come ... dal suo script.

Oppure, cercare di recuperare la situazione, andando a "raccogliere" le frequenze,

con cautela, come fossero "castagne al fuoco",

prelevandole "una ad una", colonna per colonna,

per poterne calcolare, i (9) totali.

E' quello ... che si farà.

 

[Joe91]

Intanto ... ho reso funzionante ... lo script di Luigi:

Option Explicit
Sub Main
 Dim Ruota
 Dim nCicli
 Dim Inizio,Fine
 Dim idEstr
 Dim idDecina
 Dim sErr
 Dim nTotale
 ReDim aNum(10)
 ReDim aRuote(1)
 Ruota = ScegliRuota
 nCicli = Int(InputBox("Inserire il numero dei cicli da 18",,18))
 Inizio =(EstrazioneFin -(nCicli* 18)) + 1
 Fine = EstrazioneFin - 17
 If nCicli > 0 And Inizio > 0 And Ruota > 0 Then
  aRuote(1) = Ruota
  For idDecina = 1 To 9
   nTotale = 0
   Call AlimentaNumeri(idDecina,aNum)
   ReDim aTitoli(2)
   aTitoli(1) = " Range "
   aTitoli(2) = " Frequenza "
   Call InitTabella(aTitoli)
   For idEstr = Inizio To Fine Step 18
    ReDim aValori(2)
    aValori(1) = CStr(idEstr) & " - " & CStr(idEstr + 17)
    aValori(2) = SerieFreq(idEstr,idEstr + 17,aNum,aRuote,1)
    nTotale = nTotale + CLng(aValori(2))
    Call AddRigaTabella(aValori)
   Next
   ReDim aValori(2)
   aValori(1) = "Totale"
   aValori(2) = nTotale
   Call AddRigaTabella(aValori,vbYellow)
   Call Scrivi(" meglio elaborare dal 01 1945 in cicli da 18 estrazioni tot. 249 cicli meglio un totale altissimo...purchè abbia freq alta ultimi 2 cicli ")
   Call Scrivi("Ruota in gioco " & NomeRuota(Ruota))
   Call Scrivi("Decina analizzata " & StringaNumeri(aNum))
   Call Scrivi
   Call CreaTabella
  Next
 Else
  If nCicli <= 0 Then
   sErr = "Numero di cicli non valido"
  End If
  If Inizio <= 0 Then
   sErr = "Troppi cicli rispetto alle estrazioni del range"
  End If
  If idDecina <= 0 Then
   sErr = "Nessuna decina selezionata"
  End If
  If Ruota <= 0 Then
   sErr = "Nessuna ruota selezionata"
  End If
  MsgBox sErr,vbCritical
 End If
End Sub
Function ScegliDecina()
 ReDim aVoci(8)
 Dim k,i
 For k = 1 To 81 Step 10
  aVoci(i) = "Decina " & k & " - " & k + 9
  i = i + 1
 Next
 ScegliDecina = ScegliOpzioneMenu(aVoci,0,"Selezione decina") + 1
End Function
Sub AlimentaNumeri(idDecina,aNum)
 Dim i,k,y
 i =((idDecina - 1) * 10) + 1
 For k = i To(i - 1) + 10
  y = y + 1
  aNum(y) = k
 Next
End Sub

Spero sia giusto dopo le molte necessarie correzioni.

 

[Joe91]

Eccomi ... con gli aggiornamenti.

Al messaggio #14 ... ho scritto che si devono intercettare e raccogliere le 9 Frequenze.

Quindi all' inizio dello script ho dimensionato "T" perchè possa contenere 9 Totali.

Dim T(9).

Utilizzo un nuovo contatore "KK" per indicizzarli (o ... più semplicemetecontare le colonne).

Per ogni nuova estrazione ... azzero questo contatore/indice "KK"

"For Es =EstrazioneFin- 179 ToEstrazioneFin : KK = 0"

E ... dopo che ogni frequenza (quella di ogni decina) viene scritta ...

Questa viene aggiunta al Totale(KK) (ovvero a quello della colonna in oggetto)

Scrivi FormatSpace(SF,4,1),0,0 : KK = KK + 1 : T(KK) =T(KK) + SF

Per cui ogni Kolonnina "KK" delle frequenze ... ha un suo totale..

Infine ho aggiunto ... Un ciclo For-Next (da 1 a 9) per formattare e scrivere questi "Totali"

For Tot = 1 To 9 : ScriviFormatSpace(T(Tot),4,1),1,0 : Next : Scrivi

E con questo ... dovremmo essere in dirittura d'arrivo.

Buona Serata a Tutti.

Lo script ... per le prove:

Sub Main()

Dim Nu(10),Ru(1) : Ru(1) = BA_
ReDim T(9)
For Es = EstrazioneFin - 179 To EstrazioneFin : KK = 0
K = k + 1 : Scrivi DataEstrazione(Es) & "  " & StringaEstratti(Es,Ru(1)),1,0
If K = 1 Then Ini = Es
'REM Qui inizia ... il secondo script .....
For D = 0 To 80 Step 10
For U = 1 To 10
Nu(U) = D + U
Next
SF = SerieFreq(Es,Es,Nu,Ru,2)
Scrivi FormatSpace(SF,4,1),0,0 : KK = KK + 1 : T(KK) = T(KK) + SF
Next : Scrivi
'REM ... finisce qui ...
If K = 10 Then
Fin = ES : K = 0 : Scrivi : Scrivi(Ini) & "-" &(Fin),0,0
Scrivi " ... Totali ...  ",1,0
For Tot = 1 To 9 : Scrivi FormatSpace(T(Tot),4,1),1,0 : Next : Scrivi
Scrivi
End If
Next

End Sub

 

[Antonin]

Continuo...

 

[solare]

Ottimo Grazie joe91
Gentilissimo
Ti chiedo un'ultima cosa
si può inserire la possibilità che lo script all'avvio chieda la ruota da analizzare ?

 

[Joe91]

Ciao Solare ...

Si certo, inserirò "scegliruota"

Volevo chiederti: Vanno bene i totali ... ad incremento ...

o ... li volevi che iniziassero da zero ... ad ogni ciclo di 10 estrazioni?

Pensavo anche di completare lo script inserirendo titoli

e ... il conteggio del Ritardo (attuale) per ogni Decina.

Buona giornata.

 

[solare]

Ciao Joe91, vista la tua disponibilità e di questo ti ringrazio, ti chiedo:
il totale sarebbe meglio facesse riferimento ad ogni ciclo e poi alla fine dei cicli riportare anche il totale. es: se nel 1 ciclo abbiamo la 1...10 con la presenza di 2 ambi, nel 2 ciclo la presenza di 1 solo ambo sempre della 1....10
il risultato sarà tot. presenza ambi 1 ciclo 2,secondo ciclo 1 ed infine il totale degli ambi nei cicli esaminati relativo alla 1....10 è 3.---

Per quanto riguarda l'inserimento del conteggio del ritardo attuale per ogni decina trovo sia un'ottima idea.

Ciao e buona giornata