Richiesta script per ambate

[farfalla2]

Ciao a TUTTI...per cortesia avrei una richiesta da fare per uno script di un metodo di un noto lottologo da calcolare su tutte le estrazioni. Il metodo è questo: mettere i numeri in figura e trovare in ogni ruota quelle figure che danno la somma 10. Sommare i numeri e togliere il fisso 89. Questa è la prima ambata. La seconda ambata è data dal diametrale della prima.Nel caso in cui la somma dei numeri è inferiore al fisso 89 aggiungere il 90 e poi togliere il fisso 89 .Esempio: in data 12/12/2015 a Bari avevamo il numero 52 e 48 di figura 7 e 3, e cioè di somma 10.Sommare i numeri 52 e 48 = 100 togliere il fisso 89 = 11 prima ambata e aggiungere 45 per la seconda ambata e cioè 11+45=56. Le ambate sono 11 e 56 e spesso possono uscire nelle posizioni di ricavo in questo caso in seconda e quarta posizione. Sempre in questa estrazione a Milano abbiamo 36 e 19 di figura 9 e 1. Quindi sommare i numeri 36+19=55 in questo caso aggiungere il 90 e togliere il fisso 89. 55+90-89=56 56-45=11. Ambate 56/11......A colpo 56 a Milano!!!!!!!!! Ringrazio di cuore per il vostro aiuto.

 

[claudio8]

Per farfalla2
Spero di non avere fatto errori di calcolo delle ambate. lo provi e mi faccia sapere.

 'Il metodo è questo: mettere i numeri In Figura e trovare In ogni ruota 'quelle figure che danno la somma 10.
'Sommare i numeri e togliere il fisso 89. Questa è la prima ambata.+ 2a ambata  Diametrale della prima.
'Nel caso In cui la somma dei numeri è inferiore al fisso 89 aggiungere il 90 e poi togliere il fisso 89
'Esempio: In data 12/12/2015 a Bari avevamo il numero 52 e 48
'di Figura 7 e 3, e cioè di somma 10.Sommare i numeri 52 e 48 = 100 togliere il fisso 89 = 11 prima ambata e
'aggiungere 45 per la seconda ambata e cioè 11+45=56. Le ambate sono 11 e 56 e spesso possono uscire nelle
'posizioni di ricavo In questo caso In seconda e quarta posizione. Sempre In questa estrazione a Milano
'abbiamo 36 e 19 di Figura 9 e 1. Quindi sommare i numeri 36+19=55 In questo caso aggiungere il 90 e togliere
'il fisso 89. 55+90-89=56 56-45=11. Ambate 56/11......A colpo 56 a Milano!
Sub Main()
    Dim es,r,p1,p2,clp,fa,fb,Qes,rini,rfin
    Dim n(2),ruo(1),posta(10)
  
    Qes = CInt(InputBox("Quante estrazioni controlliamo ?","ESTRAZIONI DI ANALISI",10))
    clp = CInt(InputBox("Quanti colpi di gioco?","COLPI DI GIOCO",10))
    ''sezione di scelta ruota: se si sceglie una singola ruota, ad esntrambe le seguenti domande inserire lo stesso n° riferito alla ruota scelta.
    rini = CInt(InputBox("Da quale ruota inizio il controllo?","Ruota di inizio controllo",1))
    rfin = CInt(InputBox("Sino a quale ruota faccio il controllo?","Ruota di fine controllo",1))
    Scrivi " Metodo delle figure con doppia ambata semplice o determinata di .... x Farfalla2 ",1
    posta(1) = 1
    caso = 0
    ini = EstrazioneFin - Qes
    fin = EstrazioneFin
    For es = ini To fin
        Messaggio(es)
        AvanzamentoElab ini,fin,es
        For r = rini To rfin
            If r = 11 Then r = 12
            For p1 = 1 To 4
                For p2 = p1 + 1 To 5
                    a = Estratto(es,r,p1)
                    b = Estratto(es,r,p2)
                    fa = Figura(a)
                    fb = Figura(b)
                    If fa + fb = 10 Then
                        caso = caso + 1
                        Scrivi "Caso n° " & Format2(caso) & " " & String(65,"-") & " trovato sulla ruota di " & NomeRuota(r),1,,,1
                        Scrivi GetInfoEstrazione(es) & " " & SiglaRuota(r) & " " & StringaEstratti(es,r) & " - " & Format2(a) & " in " & p1 & "ª pos e " & Format2(b) & " in " & p2 & "ª pos"
                        Scrivi "Estratti i numeri |" & Format2(a) & "| figura " & Format2(fa) & " e |" & Format2(b) & "| figura " & Format2(fb) & " -> somma figura = " & fa + fb
                        If(a + b) > 89 Then ' caso in cui la somma dei numeri è maggiore al fisso 89 ( non può esistere la somma = a 89 )
                            n(1) = FuoriX((a + b),89)
                            n(2) = Diametrale(n(1))
                            'ColoreTesto 2
                            Scrivi "Somma numeri maggiore di  89: --> " & Format2(a) & " + " & Format2(b) & " = " & Format2(a + b) & " ambate : " & Format2(n(1)) & " e " & Format2(n(2)),1,,3
                        Else
                            ' altro caso possibile,... la somma dei numeri è inferiore al fisso 89
                            n(1) = FuoriX((a + b) + 90,89)
                            n(2) = Diametrale(n(1))
                            Scrivi "Somma numeri  minore  di  89: --> " & Format2(a) & " + " & Format2(b) & " = " & Format2(a + b) & " ambate : " & Format2(n(1)) & " e " & Format2(n(2)),1,,4
                        End If
                        Scrivi
                        ruo(1) = r
                        ImpostaGiocata 1,n,ruo,posta,clp,1       '  l' "1" interrompe la giocata al 1° esito
                        Gioca es,True,,True
                    End If
                Next
            Next
        Next
    Next
    ScriviResoconto
End Sub

Un saluto

 

[farfalla2]

Ciao CLAUDIO.....lo script è perfetto ed io ti ringrazio vivamente.....ti seguo e sei bravissimo......ciao e ancora grazieeeeeee......

 

[claudio8]

Ciao CLAUDIO.....lo script è perfetto ed io ti ringrazio vivamente.....ti seguo e sei bravissimo......ciao e ancora grazieeeeeee......

Grazie di nulla, se hai qualche idea di quale possa essere la migliore delle ruote, facci sapere.

 

[claudio8]

Ho rivisto lo script aggiungendo la giocata di Estratto determinato così come specifichi inizialmente.
Puoi cambiare anche la figura da valutare,

 Sub Main()
    Dim es,r,p1,p2,clp,fa,fb,Qes,rini,rfin,sommafig,somfig
    Dim n(2),ruo(1),posta(10)
    ReDim fig10(4005,8)
    ReDim poste(10)
    somfig = CInt(InputBox("Quale figura controlliamo ?","FIGURA DA ANALIZZARE",10))
    Qes = CInt(InputBox("Quante estrazioni controlliamo ?","ESTRAZIONI DI ANALISI",10)) '  fig 2 = 2 11 20 29 38 47 56 65 74 83
    clp = CInt(InputBox("Quanti colpi di gioco?","COLPI DI GIOCO",20))
    'sezione di scelta ruota: se si sceglie una singola ruota, ad entrambe le seguenti domande inserire lo stesso n° riferito alla ruota scelta.
    rini = CInt(InputBox("Da quale ruota inizio il controllo?","Ruota di inizio controllo",6))
    rfin = CInt(InputBox("Sino a quale ruota faccio il controllo?","Ruota di fine controllo",6))
    Scrivi " Metodo delle figure con doppia ambata semplice o determinata di M.... x Farfalla2 ",1
    Scrivi Now
    posta(1) = 1
    Scrivi "' CONTROLLARE LA POSSIBLITA' DI ACCOPPIARE LE AMBATE. ",1,,- 1,3
      For sommafig = somfig To somfig ' Valore Minimo di sommafigure = 2  e max = 18
        Giocata = 0
        caso = 0
        ini = EstrazioneFin - Qes
        fin = EstrazioneFin
        For r = rini To rfin
            If r = 11 Then r = 12
            For es = ini To fin
                caso = 0
                Messaggio(SiglaRuota(r) & " " & es)
                AvanzamentoElab ini,fin,es
                'For r = rini To rfin
                'If r = 11 Then r = 12
                For p1 = 1 To 4
                    For p2 = p1 + 1 To 5
                        a = Estratto(es,r,p1)
                        b = Estratto(es,r,p2)
                        fa = Figura(a)
                        fb = Figura(b)
                        'casi = 0
                        If fa + fb = sommafig Then
                            caso = caso + 1
                            Giocata = Giocata + 1
                            Scrivi
                            Scrivi Format2(Giocata) & " Caso n° " & Format2(caso) & " " & String(60,"-") & " trovato sulla ruota di " & NomeRuota(r),1,,,1
                            Scrivi GetInfoEstrazione(es) & " " & SiglaRuota(r) & " " & StringaEstratti(es,r) & " - " & Format2(a) & " in " & p1 & "ª pos e " & Format2(b) & " in " & p2 & "ª"
                            Scrivi "Estratti i numeri |" & Format2(a) & "| figura " & Format2(fa) & " e |" & Format2(b) & "| figura " & Format2(fb) & " -> somma figura = " & fa + fb
                            ' caso in cui la somma dei numeri è maggiore al fisso 89-90 ( non può esistere la somma = a 89 )
                            If(a + b) > 90 Then
                                n(1) = FuoriX(a + b,89)
                                n(2) = Diametrale(n(1))
                                'ColoreTesto 2
                                Scrivi "Somma numeri maggiore di  90: --> " & Format2(a) & " + " & Format2(b) & " = " & Format2(a + b) & " ambate : " & Format2(n(1)) & " e " & Format2(n(2)),1,,3
                            Else
                                ' altro caso possibile,... la somma dei numeri è inferiore al fisso 89
                                n(1) = FuoriX(a + b + 90,89)
                                n(2) = Diametrale(n(1))
                                Scrivi "Somma numeri  minore  di  90: --> " & Format2(a) & " + " & Format2(b) & " = " & Format2(a + b) & " ambate : " & Format2(n(1)) & " e " & Format2(n(2)),1,,4
                            End If
                            Scrivi
                            ruo(1) = r
                            ReDim poste(10)
                            poste(5 + p1) = 1
                            poste(5 + p2) = 1

                            ' x controllo delle singole giocate, mettere l'apice d'avanti alla riga specifica
                            ImpostaGiocata 1,n,ruo,poste,clp,0 ' l' "1" interrompe la giocata al 1° esito - giocata x estratto determinato.
                            ImpostaGiocata 2,n,ruo,posta,clp,0 ' l' "1" interrompe la giocata al 1° esito - giocata x estratto semplice.
                            Gioca es,True,,True
                            
                        End If
                    Next
                Next
            Next
        Next
      
        Scrivi "n° di giocate " & Giocata & " x controllo:  " & GetQuantitaGiocateEffettuate
        ScriviResoconto False
     
    Next
End Sub

 

[farfalla2]

BELLO!!!!!!!!!!!!!!! VERAMENTE BELLO..... Ciaooo CLAUDIO ...Ho visto che la figura 6 da delle buone ambate....Io ti ringrazio....Ti auguro di passare una bella Vigilia di Natale a base di pesce...Io cucino x 24 persone ...tutto a base di pesce e tutto con amici e familiari.......Se potessi ti inviterei...Il NATALE è così...con amore di chi c'è e con il ricordo nel cuore di chi non c'è più...

 

[claudio8]

Grazie per il pensiero Farfalla, fai anche tu un buon Natale e auguri ai tuoi amici e familiari.
Ps: grazie x la fig.6