script

[lottofortune]

ciao a tutti volevo sapere se esiste uno script che fa la somma delle decine più le unità e mi dai la somma...es bari 22 somma 2+2=4
ho provato a cercare ma non c e niente

 

[claudio8]

E' così vago il tuo chiedere che forse non ti risponderemo in tanti.

dai maggiori dettagli:
per ogni estrazioni pper una specifica?, per una singolaruota o per tutte?, per singolo estratto o per tutti e 5?
che fine faranno queste somme?

spero che qualcuno ti dia una mano.....

un saluto

 

[lottofortune]

Si solo alla prima...e per ogni ruota... facciamo l esempio per una sola ruota es bari 22-68-20-42-77 fare la somma 2+2+6+8+2+0+7+7=40 solo questo

 

[*blacklotto*]

Ciao, vedi se ti potrebbe interessare modificandolo come vuoi, di Mike58.

Sub Main
Dim nu(5),dc(5),cd(5),np(10)
Ini = EstrazioneFin - 10
fin = EstrazioneFin
For es = Ini To fin
For r = 1 To 10
For p = 1 To 5
nu(p) = Estratto(es,r,p)
dc(p) = Decina(nu(p))
cd(p) = Cadenza(nu(p))
Next
np(1) = dc(1)
np(2) = dc(2)
np(3) = dc(3)
np(4) = dc(4)
np(5) = dc(5)
'
np(6) = cd(1)
np(7) = cd(2)
np(8) = cd(3)
np(9) = cd(4)
np(10) = cd(5)
For x = 1 To 10
If pari(np(x)) Then kp = kp + 1
If dispari(np(x)) Then kd = kd + 1
Next
If kp = 5 And kd = 5 Then
If Decina(nu(1)) > 0 And Decina(nu(2)) > 0 And Decina(nu(3)) > 0 And Decina(nu(4)) > 0 And Decina(nu(5)) > 0 Then
If Cadenza(nu(1)) > 0 And Cadenza(nu(2)) > 0 And Cadenza(nu(3)) > 0 And Cadenza(nu(4)) > 0 And Cadenza(nu(5)) > 0 Then
k = k + 1
Scrivi "Caso n. " & FormatSpace(k,3) & " " & GetInfoEstrazione(es) & " " & SiglaRuota(r) & " " & StringaEstratti(es,r),0,0
Scrivi " " & StringaNumeri(dc) & " - " & StringaNumeri(cd) & " " & " Pari = " & kp & " Dispari = " & kd
End If
End If
End If
kp = 0
kd = 0
Next
Next
End Sub

RESOCONTO
Caso n. 1 [09485] [ 70] 12.06.2018 FI 24.32.73.25.74 2.3.7.2.7 - 4.2.3.5.4 Pari = 5 Dispari = 5 Caso n. 2 [09486] [ 71] 14.06.2018 CA 43.27.88.73.89 4.2.8.7.8 - 3.7.8.3.9 Pari = 5 Dispari = 5 Caso n. 3 [09486] [ 71] 14.06.2018 MI 51.43.26.69.87 5.4.2.6.8 - 1.3.6.9.7 Pari = 5 Dispari = 5 Caso n. 4 [09486] [ 71] 14.06.2018 VE 47.55.26.52.32 4.5.2.5.3 - 7.5.6.2.2 Pari = 5 Dispari = 5 Caso n. 5 [09488] [ 73] 19.06.2018 FI 22.58.28.79.59 2.5.2.7.5 - 2.8.8.9.9 Pari = 5 Dispari = 5 Caso n. 6 [09491] [ 76] 26.06.2018 FI 28.66.12.37.33 2.6.1.3.3 - 8.6.2.7.3 Pari = 5 Dispari = 5 Caso n. 7 [09491] [ 76] 26.06.2018 PA 15.25.78.68.49 1.2.7.6.4 - 5.5.8.8.9 Pari = 5 Dispari = 5 Caso n. 8 [09492] [ 77] 28.06.2018 CA 51.84.46.32.17 5.8.4.3.1 - 1.4.6.2.7 Pari = 5 Dispari = 5 Caso n. 9 [09493] [ 78] 30.06.2018 GE 84.46.81.39.59 8.4.8.3.5 - 4.6.1.9.9 Pari = 5 Dispari = 5 Caso n. 10 [09493] [ 78] 30.06.2018 MI 19.36.66.79.46 1.3.6.7.4 - 9.6.6.9.6 Pari = 5 Dispari = 5 Caso n. 11 [09495] [ 80] 05.07.2018 FI 28.42.19.38.53 2.4.1.3.5 - 8.2.9.8.3 Pari = 5 Dispari = 5

 

[salvo50]

ciao a tutti volevo sapere se esiste uno script che fa la somma delle decine più le unità e mi dai la somma...es bari 22 somma 2+2=4
ho provato a cercare ma non c e niente

Ciao, come ha scritto Claudio, devi dare più dettagli per quello che vuoi fare una volta ottenuta questa somma, al fatto che non hai trovato script che fanno questa somma, probabilmente è perchè hai pochi script ne tuo pc, quasi tutti gli script che fanno i calcoli delle piramidi,e non usano la funzione PIRAMIDE, fanno questa somma col fuori 9, tempo fa avevo fatto degli script sul QUADRATO INTELLETTUALE di Pico Della Mirandola e all'inizio avevo fatto lo script tutto sommando decine con unità, poi qualcuno mi aiuto dicendomi che esisteva la funzione PIRAMIDE e alla fine feci un misto tra con la funzione e senza, ti posto lo script, nel calcolo delle piramidi 4 e 5, faccio decine + cadenze col fuori 9

Option Explicit
Sub Main
    Dim g1p1,g1p4,g1p5,g2p2,g3p3,g2p6,g2p7,g3p8,g3p9,fig(12),decnum(3),cadnum(3)
    Dim ap1(20),ap2(20),ap3(20),bp1,cp1,dp1,ep1,fp1,gp1,a,fisso1,fisso2
    Dim ag2num,bg2num,aag2num,bbg2num,ag3num,bg3num,aag3num,bbg3num
    Dim g1p10,g1p11,g2p12,g2p13,g3p14,g3p15,g1p16,g2p17,g3p18,g1p19,g2p20,g3p21
    ReDim g1Num(3),g1Num2(3),g1Num3(5)
    ReDim g2Num(3),g2Num2(3),g2Num3(5)
    ReDim g3num(3),g3num2(3),g3num3(5)
    Scrivi
    g1Num(1) = 24
    g1Num(3) = 32
    fig(1) = FuoriX(((g1Num(1) + g1Num(3)) + 9),9)
    If fig(1) = 1 Then g1Num(2) = 35
    If fig(1) = 2 Then g1Num(2) = 57
    If fig(1) = 3 Then g1Num(2) = 79
    If fig(1) = 4 Then g1Num(2) = 92
    If fig(1) = 5 Then g1Num(2) = 24
    If fig(1) = 6 Then g1Num(2) = 46
    If fig(1) = 7 Then g1Num(2) = 68
    If fig(1) = 8 Then g1Num(2) = 81
    If fig(1) = 9 Then g1Num(2) = 13
    g1p1 = StringaNumeri(g1Num,"",True)
    ap1(1) = Piramide(g1p1,1)
    ap1(2) = Piramide(g1p1,2)
    ap1(3) = Piramide(g1p1,3)
    ap1(4) = Piramide(g1p1,4)
    'calcoli gruppo 2 seconda piramide
    fisso1 = 33
    ag2num = FuoriX(Decina(g1Num(1)) + Decina(fisso1),9)
    bg2num = FuoriX(Cadenza(g1Num(1)) + Cadenza(fisso1),9)
    g2Num(1) = ag2num & bg2num
    aag2num = FuoriX(Decina(g1Num(3)) + Decina(fisso1),9)
    bbg2num = FuoriX(Cadenza(g1Num(3)) + Cadenza(fisso1),9)
    g2Num(3) = aag2num & bbg2num
    fig(2) = FuoriX(((g2Num(1) + g2Num(3)) + 9),9)
    If fig(2) = 1 Then g2Num(2) = 35
    If fig(2) = 2 Then g2Num(2) = 57
    If fig(2) = 3 Then g2Num(2) = 79
    If fig(2) = 4 Then g2Num(2) = 92
    If fig(2) = 5 Then g2Num(2) = 24
    If fig(2) = 6 Then g2Num(2) = 46
    If fig(2) = 7 Then g2Num(2) = 68
    If fig(2) = 8 Then g2Num(2) = 81
    If fig(2) = 9 Then g2Num(2) = 13
    g2p2 = StringaNumeri(g2Num,"",True)
    ap2(1) = Piramide(g2p2,1)
    ap2(2) = Piramide(g2p2,2)
    ap2(3) = Piramide(g2p2,3)
    ap2(4) = Piramide(g2p2,4)
    'calcoli gruppo 3 terza piramide
    ag3num = FuoriX(Decina(g2Num(1)) + Decina(fisso1),9)
    bg3num = FuoriX(Cadenza(g2Num(1)) + Cadenza(fisso1),9)
    g3num(1) = ag3num & bg3num
    aag3num = FuoriX(Decina(g2Num(3)) + Decina(fisso1),9)
    bbg3num = FuoriX(Cadenza(g2Num(3)) + Cadenza(fisso1),9)
    g3num(3) = aag3num & bbg3num
    fig(3) = FuoriX(((g3num(1) + g3num(3)) + 9),9)
    If fig(3) = 1 Then g3num(2) = 35
    If fig(3) = 2 Then g3num(2) = 57
    If fig(3) = 3 Then g3num(2) = 79
    If fig(3) = 4 Then g3num(2) = 92
    If fig(3) = 5 Then g3num(2) = 24
    If fig(3) = 6 Then g3num(2) = 46
    If fig(3) = 7 Then g3num(2) = 68
    If fig(3) = 8 Then g3num(2) = 81
    If fig(3) = 9 Then g3num(2) = 13
    g3p3 = StringaNumeri(g3num,"",True)
    ap3(1) = Piramide(g3p3,1)
    ap3(2) = Piramide(g3p3,2)
    ap3(3) = Piramide(g3p3,3)
    ap3(4) = Piramide(g3p3,4)
    ' visualizzazione piramidi 1-2-3
    ColoreTesto 1
    Scrivi "     Gruppo:1                   Gruppo:2                  Gruppo:3  ",1
    Scrivi "    Piramide:1                 Piramide:2                Piramide:3 ",1
    ColoreTesto 0
    Scrivi
    Scrivi "     " & g1p1 & "                     " & g2p2 & "                     " & g3p3,1
    Scrivi "     " & ap1(1) & "                      " & ap2(1) & "                      " & ap3(1),1
    Scrivi "     " & ap1(2) & "                       " & ap2(2) & "                       " & ap3(2),1
    Scrivi "     " & ap1(3) & "                        " & ap2(3) & "                        " & ap3(3),1
    Scrivi "     " & ap1(4) & "                         " & ap2(4) & "                         " & ap3(4),1
    'calcoli piramidi 4 e 5
    fig(4) = FuoriX(Decina(ap1(4)) + Cadenza(ap1(4)),9)
    g1p4 = fig(4)*100 + g1Num(1)
    bp1 = Piramide(g1p4,1)
    g1p5 = fig(4)*100 + g1Num(3)
    cp1 = Piramide(g1p5,1)
    'calcoli piramidi 6 e 7
    fig(5) = FuoriX(Decina(ap2(4)) + Cadenza(ap2(4)),9)
    g2p6 = fig(5)*100 + g1Num(1)
    dp1 = Piramide(g2p6,1)
    g2p7 = fig(5)*100 + g1Num(3)
    ep1 = Piramide(g2p7,1)
    'calcoli piramidi 8 e 9
    fig(6) = FuoriX(Decina(ap3(4)) + Cadenza(ap3(4)),9)
    g3p8 = fig(6)*100 + g1Num(1)
    fp1 = Piramide(g3p8,1)
    g3p9 = fig(6)*100 + g1Num(3)
    gp1 = Piramide(g3p9,1)
    'visualizzazione piramidi 4-5-6-7-8-9
    Scrivi
    ColoreTesto 2
    Scrivi "Pir:4   Pir:5            Pir:6      Pir:7            Pir:8      Pir:9 "
    ColoreTesto 0
    Scrivi "" & g1p4 & "     " & g1p5 & "              " & g2p6 & "        " & g2p7 & "              " & g3p8 & "        " & g3p9,1
    Scrivi "" & bp1 & "      " & cp1 & "               " & dp1 & "         " & ep1 & "               " & fp1 & "         " & gp1,1
    ' calcoli piramidi 10 e 11
    g1p10 = ap1(4)*100 + bp1
    ap1(5) = Piramide(g1p10,1)
    ap1(6) = Piramide(g1p10,2)
    g1p11 = ap1(4)*100 + cp1
    ap1(7) = Piramide(g1p11,1)
    ap1(8) = Piramide(g1p11,2)
    ' calcoli piramidi 12 e 13
    g2p12 = ap2(4)*100 + dp1
    ap2(5) = Piramide(g2p12,1)
    ap2(6) = Piramide(g2p12,2)
    g2p13 = ap2(4)*100 + ep1
    ap2(7) = Piramide(g2p13,1)
    ap2(8) = Piramide(g2p13,2)
    ' calcoli piramidi 14 e 15
    g3p14 = ap3(4)*100 + fp1
    ap3(5) = Piramide(g3p14,1)
    ap3(6) = Piramide(g3p14,2)
    g3p15 = ap3(4)*100 + gp1
    ap3(7) = Piramide(g3p15,1)
    ap3(8) = Piramide(g3p15,2)
    Scrivi
    'visualizzazione piramidi 10-11-12-13-14-15
    ColoreTesto 1
    Scrivi "Pir:10  Pir:11           Pir:12     Pir:13           Pir:14     Pir:15 "
    ColoreTesto 0
    Scrivi "" & g1p10 & "    " & g1p11 & "             " & g2p12 & "       " & g2p13 & "             " & g3p14 & "       " & g3p15,1
    Scrivi "" & ap1(5) & "     " & ap1(7) & "              " & ap2(5) & "        " & ap2(7) & "              " & ap3(5) & "        " & ap3(7),1
    Scrivi "" & ap1(6) & "      " & ap1(8) & "               " & ap2(6) & "         " & ap2(8) & "               " & ap3(6) & "         " & ap3(8),1
    'calcoli piramide 16
    g1Num2(1) = ap1(6)
    g1Num2(3) = ap1(8)
    fig(7) = FuoriX(((g1Num2(1) + g1Num2(3)) + 9),9)
    If fig(7) = 1 Then g1Num2(2) = 35
    If fig(7) = 2 Then g1Num2(2) = 57
    If fig(7) = 3 Then g1Num2(2) = 79
    If fig(7) = 4 Then g1Num2(2) = 92
    If fig(7) = 5 Then g1Num2(2) = 24
    If fig(7) = 6 Then g1Num2(2) = 46
    If fig(7) = 7 Then g1Num2(2) = 68
    If fig(7) = 8 Then g1Num2(2) = 81
    If fig(7) = 9 Then g1Num2(2) = 13
    g1p16 = StringaNumeri(g1Num2,"",True)
    ap1(9) = Piramide(g1p16,1)
    ap1(10) = Piramide(g1p16,2)
    ap1(11) = Piramide(g1p16,3)
    ap1(12) = Piramide(g1p16,4)
    ' calcoli piramide 17
    g2Num2(1) = ap2(6)
    g2Num2(3) = ap2(8)
    fig(8) = FuoriX(((g2Num2(1) + g2Num2(3)) + 9),9)
    If fig(8) = 1 Then g2Num2(2) = 35
    If fig(8) = 2 Then g2Num2(2) = 57
    If fig(8) = 3 Then g2Num2(2) = 79
    If fig(8) = 4 Then g2Num2(2) = 92
    If fig(8) = 5 Then g2Num2(2) = 24
    If fig(8) = 6 Then g2Num2(2) = 46
    If fig(8) = 7 Then g2Num2(2) = 68
    If fig(8) = 8 Then g2Num2(2) = 81
    If fig(8) = 9 Then g2Num2(2) = 13
    g2p17 = StringaNumeri(g2Num2,"",True)
    ap2(9) = Piramide(g2p17,1)
    ap2(10) = Piramide(g2p17,2)
    ap2(11) = Piramide(g2p17,3)
    ap2(12) = Piramide(g2p17,4)
    ' calcoli piramide 18
    g3num2(1) = ap3(6)
    g3num2(3) = ap3(8)
    fig(9) = FuoriX(((g3num2(1) + g3num2(3)) + 9),9)
    If fig(9) = 1 Then g3num2(2) = 35
    If fig(9) = 2 Then g3num2(2) = 57
    If fig(9) = 3 Then g3num2(2) = 79
    If fig(9) = 4 Then g3num2(2) = 92
    If fig(9) = 5 Then g3num2(2) = 24
    If fig(9) = 6 Then g3num2(2) = 46
    If fig(9) = 7 Then g3num2(2) = 68
    If fig(9) = 8 Then g3num2(2) = 81
    If fig(9) = 9 Then g3num2(2) = 13
    g3p18 = StringaNumeri(g3num2,"",True)
    ap3(9) = Piramide(g3p18,1)
    ap3(10) = Piramide(g3p18,2)
    ap3(11) = Piramide(g3p18,3)
    ap3(12) = Piramide(g3p18,4)
    Scrivi
    ColoreTesto 2
    Scrivi "    Pir:16                    Pir:17                     Pir:18"
    ColoreTesto 0
    Scrivi "    " & g1p16 & "                    " & g2p17 & "                     " & g3p18,1
    Scrivi "    " & ap1(9) & "                     " & ap2(9) & "                      " & ap3(9),1
    Scrivi "    " & ap1(10) & "                      " & ap2(10) & "                       " & ap3(10),1
    Scrivi "    " & ap1(11) & "                       " & ap2(11) & "                        " & ap3(11),1
    Scrivi "    " & ap1(12) & "                        " & ap2(12) & "                         " & ap3(12),1
    'calcoli piramide 19
    g1Num3(1) = ap1(12)
    g1Num3(2) = ap1(4)
    g1Num3(3) = ap2(12)
    g1Num3(4) = ap1(4)
    g1Num3(5) = ap3(12)
    g1p19 = StringaNumeri(g1Num3,"",True)
    ap1(13) = Piramide(g1p19,1)
    ap1(14) = Piramide(g1p19,2)
    ap1(15) = Piramide(g1p19,3)
    ap1(16) = Piramide(g1p19,4)
    ap1(17) = Piramide(g1p19,5)
    ap1(18) = Piramide(g1p19,6)
    ap1(19) = Piramide(g1p19,7)
    ap1(20) = Piramide(g1p19,8)
    'calcoli piramide 20
    g2Num3(1) = ap1(12)
    g2Num3(2) = ap2(4)
    g2Num3(3) = ap2(12)
    g2Num3(4) = ap2(4)
    g2Num3(5) = ap3(12)
    g2p20 = StringaNumeri(g2Num3,"",True)
    ap2(13) = Piramide(g2p20,1)
    ap2(14) = Piramide(g2p20,2)
    ap2(15) = Piramide(g2p20,3)
    ap2(16) = Piramide(g2p20,4)
    ap2(17) = Piramide(g2p20,5)
    ap2(18) = Piramide(g2p20,6)
    ap2(19) = Piramide(g2p20,7)
    ap2(20) = Piramide(g2p20,8)
    'calcoli piramide 21
    g3num3(1) = ap1(12)
    g3num3(2) = ap3(4)
    g3num3(3) = ap2(12)
    g3num3(4) = ap3(4)
    g3num3(5) = ap3(12)
    g3p21 = StringaNumeri(g3num3,"",True)
    ap3(13) = Piramide(g3p21,1)
    ap3(14) = Piramide(g3p21,2)
    ap3(15) = Piramide(g3p21,3)
    ap3(16) = Piramide(g3p21,4)
    ap3(17) = Piramide(g3p21,5)
    ap3(18) = Piramide(g3p21,6)
    ap3(19) = Piramide(g3p21,7)
    ap3(20) = Piramide(g3p21,8)
    Scrivi
    ColoreTesto 1
    Scrivi "    Pir:19                    Pir:20                     Pir:21"
    ColoreTesto 0
    Scrivi "  " & g1p19 & Space(16) & g2p20 & Space(17) & g3p21,1
    Scrivi "  " & ap1(13) & Space(17) & ap2(13) & Space(18) & ap3(13),1
    Scrivi "  " & ap1(14) & Space(18) & ap2(14) & Space(19) & ap3(14),1
    Scrivi "  " & ap1(15) & Space(19) & ap2(15) & Space(20) & ap3(15),1
    Scrivi "  " & ap1(16) & Space(20) & ap2(16) & Space(21) & ap3(16),1
    Scrivi "  " & ap1(17) & Space(21) & ap2(17) & Space(22) & ap3(17),1
    Scrivi "  " & ap1(18) & Space(22) & ap2(18) & Space(23) & ap3(18),1
    Scrivi "  " & ap1(19) & Space(23) & ap2(19) & Space(24) & ap3(19),1
    Scrivi "  " & ap1(20) & Space(24) & ap2(20) & Space(25) & ap3(20),1
    Scrivi
    Scrivi
End Sub

Scusami, non avevo visto la tua risposta e quella di Blacklotto

 

[lottofortune]

Ciao a tutti grazie di cuore ma quello che cerco io è la somma di tutte le decine e unità dei numeri usciti vome nell'esempio sopra... il numero uscito si usa come ambata..

 

[joe]

Ciao,

Option Explicit
Sub Main
'SommaCifre By Joe.
  Dim R,E,S,P
  R = BA_
  Call GetArrayNumeriRuota(DataEstrToIdEstr(28,06,2018),R,E)
  For P = 1 To 5
    S = S + Int(E(P)/10) + Cadenza(E(P))
  Next
  Call Scrivi(SiglaRuota(R) & Space(1) & StringaNumeri(E,"+",True) & " = " & S)
End Sub

 

[Roby]

oppure prova questo se ti è piu congeniale

Option Explicit
Sub Main
   Dim es,Ini,Fin,r0,nRic,Clp
   Dim ruota(12)
   Dim posta(10)
   Dim am(1)
   Dim a,b,c,d,e,f,g,h,i,l,m,n,o,p,q,t,co
   posta(1) = 1
   r0 = CInt(InputBox(" Scegli la ruota Base ",,"1"))
   nRic = CInt(InputBox(" Quante estrazioni vuoi controllare ? ",,"100"))
   Clp = CInt(InputBox(" Per quanti colpi vuoi giocare ? ",,"18"))
   Ini = EstrazioneFin - nRic
   Fin = EstrazioneFin
   co = 0
   For es = Ini To Fin
 If IndiceMensile(Es) = 1 Then  
      Messaggio "elab. estr. [" &(es) & "] di " & DataEstrazione(es,1)      
      Call AvanzamentoElab(Ini,Fin,es)
      ruota(1) = r0
      a = Estratto(es,r0,1)
      b = Estratto(es,r0,2)
      c = Estratto(es,r0,3)
      d = Estratto(es,r0,4)
      e = Estratto(es,r0,5)
      '--------------------
      f = Decina(a)
      g = Cadenza(a)
      h = Decina(b)
      i = Cadenza(b)
      l = Decina(c)
      m = Cadenza(c)
      n = Decina(d)
      o = Cadenza(d)
      p = Decina(e)
      q = Cadenza(e)
      '--------------------
      t = f + g + h + i + l + m + n + o + p + q
      am(1) = t
      co = co + 1
      Scrivi String(70,"-")
      Scrivi DataEstrazione(es) & " [ " & SiglaRuota(r0) & " " & StringaEstratti(es,r0) & " ] " & " Ambata " & t,1,,,1
      ImpostaGiocata 1,am,ruota,posta,Clp
      Gioca es,True,,1
      If ScriptInterrotto Then Exit For
   Next
   Scrivi
   Scrivi String(100,"*")
   ColoreTesto 2
   Scrivi" casi trovati : " & co,1
   ColoreTesto 0
   Scrivi String(100," * ")
   ScriviResoconto,False
End Sub

 

[joe]

Si solo alla prima...e per ogni ruota... facciamo l esempio per una sola ruota es bari 22-68-20-42-77 fare la somma 2+2+6+8+2+0+7+7=40 solo questo

Option Explicit
Sub Main
  Dim Ini,Fin,Es
  Dim R,E,S,P
  Scrivi "SommaCifre By Joe",True
  Ini = EstrazioneFin - 156 : Fin = EstrazioneFin
  For Es = Ini To Fin
    If IndiceMensile(Es) = 1 Then
      Scrivi DataEstrazione(Es),True
      For R = 1 To 12 : If R = 11 Then R = 12
        Call GetArrayNumeriRuota(Es,R,E)
        S = 0
        For P = 1 To 5
          S = S + Int(E(P)/10) + Cadenza(E(P))
        Next
        Call Scrivi(SiglaRuota(R) & Space(1) & StringaNumeri(E," + ",True) & " = " & S)
      Next
      Scrivi String(30,"-")
    End If
  Next
End Sub

Nel seguente script ho modificato l'output per renderlo più simile a quello proposto:

Option Explicit
Sub Main
  Dim Ini,Fin,Es
  Dim R,E,S,P,O
  Call Scrivi (Space(25) & "SommaCifre By Joe",True)
  Ini = EstrazioneFin - 156 : Fin = EstrazioneFin
  For Es = Ini To Fin
    If IndiceMensile(Es) = 1 Then
      Call Scrivi (Space(6) & DataEstrazione(Es),True)
      For R = 1 To 12 : If R = 11 Then R = 12
        Call (GetArrayNumeriRuota(Es,R,E))
        S = 0 : O = ""
        For P = 1 To 5
          S = S + Int(E(P)/10) + Cadenza (E(P))
          O = O & " + " & Int(E(P)/10) : O = O & " + " & Cadenza(E(P))
        Next
        Call Scrivi(SiglaRuota(R) & Space(2),True,False)
        Call Scrivi(StringaNumeri(E,,True) & Space(2),False,False)
        Call Scrivi(Right(O,Len(O) - 3),False,False)
        Call Scrivi(" = " & S,True)
      Next
      Call Scrivi (String(62,"-"))
    End If
  Next
End Sub

 

[salvo50]

Vedi se può andare

 'Chiesto da Lottofortune, sommare di una estrazione alla prima del
'mese le decine e le unità 'il totale risultante giocarlo come ambata
'SCRIPT BY SALVO50
Option Explicit
Sub Main
   Dim FIn,Es,Ini,Clp
   Dim Posta(2),Ruote(1),Ambata(1)
   Dim Caso,Casi,A1,A2,A3,A4,A5,R1,B1,B2,B3,B4,B5
   Dim DeA1,DeA2,DeA3,DeA4,DeA5,CaA1,CaA2,CaA3,CaA4,CaA5
   FIn = EstrazioneFin
   Call ScegliRange(Ini,FIn,9400,FIn)
   Clp = InputBox("Per quanti colpi vuoi giocare le ambate?",,13)
   Posta(1) = 1
   For Es = Ini To FIn
      If IndiceMensile(Es) = 1 Then
         Messaggio Es
         AvanzamentoElab Ini,FIn,Es
         For R1 = 1 To 12
            If R1 = 11 Then R1 = 12
            A1 = Estratto(Es,R1,1) : If A1 > 0 Then
            A2 = Estratto(Es,R1,2)
            A3 = Estratto(Es,R1,3)
            A4 = Estratto(Es,R1,4)
            A5 = Estratto(Es,R1,5)
            DeA1 = Decina(A1) : CaA1 = Cadenza(A1)
            DeA2 = Decina(A2) : CaA2 = Cadenza(A2)
            DeA3 = Decina(A3) : CaA3 = Cadenza(A3)
            DeA4 = Decina(A4) : CaA4 = Cadenza(A4)
            DeA5 = Decina(A5) : CaA5 = Cadenza(A5)
            Ambata(1) = DeA1 + CaA1 + DeA2 + CaA2 + DeA3 + CaA3 + DeA4 + CaA4 + DeA5 + CaA5
            Casi = Casi + 1
            ColoreTesto 1
            Scrivi String(95,"o") & " Caso  " & FormattaStringa(Casi,"0000")
            ColoreTesto 0
            Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
            Scrivi "  " & SiglaRuota(R1) & " " & StringaEstratti(Es,R1),1
            Scrivi
            Ruote(1) = R1
            ImpostaGiocata 1,Ambata,Ruote,Posta,Clp
            Gioca Es
         End If
         If ScriptInterrotto Then Exit Sub
      Next
   End If
Next
ScriviResoconto
End Sub

sono esclusi le ambate inferiori a 15 e presumo superiori a 75

 

[salvo50]

Caspita in 2 mi avete preceduto

Quello di Joe è una lezione in più, almeno per me


Per Cesare, ho lanciato il tuo, va in errore perchè manca un END-IF sopra il NEXT

 

[Roby]

Si ho fatto un casino, quando mi sono accorto che era solo per la prima del mese, e modificando devo aver cancellato qualcosa,
perchè lo script che avevo io girava bene.

Comunque questo script gli fa vedere questo forse gli serve.
io sono un principiante ma se sono di aiuto ben venga, e poi cazzeggio...

----------------------------------------------------------------------
04.06.2018 [ BA 68.03.70.14.06 ]
6 + 8 + 0 + 3 + 7 + 0 + 1 + 4 + 0 + 6 = 35 Ambata

Estrazione generatrice del pronostico 09481 [ 66 - 04/06/2018]
G 0001 Numeri in gioco : 35 su BA per Estratto
V N. [35 ] [BA] [.. .. 35 .. ..] C. 4 Estratto 09485 [ 70 - 12/06/2018] [07.43.35.02.62]
Interrotta per esito verificato

----------------------------------------------------------------------
03.07.2018 [ BA 78.84.85.57.44 ]
7 + 8 + 8 + 4 + 8 + 5 + 5 + 7 + 4 + 4 =  60  Ambata

Estrazione generatrice del pronostico 09494 [ 79 - 03/07/2018]
G 0001 Numeri in gioco : 60 su BA per Estratto
In corso per altre 9 estrazioni

Lo script se non è la prima del mese avvisa che non lo è.

Option Explicit
Sub Main
   Dim es,Ini,Fin,r0,nRic,Clp,iMese
   Dim ruota(12)
   Dim posta(10)
   Dim am(1)
   Dim a,b,c,d,e,f,g,h,i,l,m,n,o,p,q,t,co
   posta(1) = 1
   iMese = CInt(InputBox("L'indice mese rilevato alla attuale data di FineRange è (vedi sotto)" & Chr(13) & Chr(13) & "Verificare che coincida con l'Indice di interesse e cliccare [ OK ] "," CONFERMA INDICE MESE (Prima del mese)",IndiceMensile(EstrazioneFin)))
   If iMese <> 1 Then
      Scrivi: Scrivi : Scrivi
      Scrivi " Attenzione indice Mese non consentito, modificare il FineRange ,,............. !!! ",1,,4
      Scrivi
      Scrivi " Posizionare il FineRange di Spaziometria sull'estrazione di Inizio Mese !!! ",1,,4
      Scrivi
      Exit Sub
   End If
   r0 = CInt(InputBox(" Scegli la ruota Base ",,"1"))
   nRic = CInt(InputBox(" Quante estrazioni vuoi controllare ? ",,"500"))
   Clp = CInt(InputBox(" Per quanti colpi vuoi giocare ? ",,"10"))
   Ini = EstrazioneFin - nRic
   Fin = EstrazioneFin
   co = 0
   For es = Ini To Fin
      If IndiceMensile(es) = 1 Then
         Messaggio "elab. estr. [" &(es) & "] di " & DataEstrazione(es,1)
         Call AvanzamentoElab(Ini,Fin,es)
         ruota(1) = r0
         a = Estratto(es,r0,1)
         b = Estratto(es,r0,2)
         c = Estratto(es,r0,3)
         d = Estratto(es,r0,4)
         e = Estratto(es,r0,5)
         '--------------------
         f = Decina(a)
         g = Cadenza(a)
         h = Decina(b)
         i = Cadenza(b)
         l = Decina(c)
         m = Cadenza(c)
         n = Decina(d)
         o = Cadenza(d)
         p = Decina(e)
         q = Cadenza(e)
         '--------------------
         t = f + g + h + i + l + m + n + o + p + q
         am(1) = t
         co = co + 1
         Scrivi String(70,"-")
         Scrivi DataEstrazione(es) & " [ " & SiglaRuota(r0) & " " & StringaEstratti(es,r0) & " ] ",1,,,1
         Scrivi "" & f & " + " & g & " + " & h & " + " & i & " + " & l & " + " & m & " + " & n & " + " & o & " + " & p & " + " & q & " =  " & t & "  Ambata",1,,,1
         Scrivi
         ImpostaGiocata 1,am,ruota,posta,Clp,1
         Gioca es,True,,1
         If ScriptInterrotto Then Exit For
      End If
   Next
   Scrivi
   Scrivi String(100,"*")
   ColoreTesto 2
   Scrivi" casi trovati : " & co,1
   ColoreTesto 0
   Scrivi String(100," * ")
   ScriviResoconto,False
End Sub

 

[salvo50]

Ciao a Tutti.

Grazie Cesare, io neanche me ne ero accorto che era solo per la prima del mese, quindi l'ho corretto.

 

[lottofortune]

Perfetto era ciò che cercavo, grazie a tutti di cuore per la vostra disponibilità.. buona giornata..