Terzine di somma 90

[Xeroxs]

Buonasera a tutti,
Volevo chiedere per favore uno script se possibile che elencasse le terzine di somma scelta con input
ed il numero di estrazioni a scelta
La ricerca va fatta su ogni ruota
ad esempio se cerco la somma 90
22 68 90 questa è una terzina di somma 90

l ideale sarebbe avere l elenco con data estrazione e numero estrazione, tutti i numeri estratti evidenziando la terzina

e la ruota dove rintraccia la somma

Grazie

 

[Master]

Buonasera provi questo

Sub Main()
   Dim INI,FINE,ES,R1,A1,A2,A3,P1,P2,P3
   Dim RS,SA,E1,S1,OK
   RS = InputBox("Quante estrazioni vuoi controllare?","ESTRAZIONI",100)
   SA = CInt(InputBox("Quale somma?","SOMMA",90))
   Scrivi String(2," ") & "********* TERZINE DI SOMMA " & SA & " ********",1
   Scrivi
   INI = EstrazioneFin - RS : FINE = EstrazioneFin
   For ES = INI To FINE : : AvanzamentoElab INI,FINE,ES : OK = 0
      For R1 = 1 To 11
         If R1 = 11 Then R1 = 12
         For P1 = 1 To 3 : A1 = Estratto(ES,R1,P1)
            For P2 = P1 + 1 To 4 : A2 = Estratto(ES,R1,P2)
               For P3 = P2 + 1 To 5 : A3 = Estratto(ES,R1,P3)
                  If Fuori90(A1 + A2 + A3) = SA Then
                     OK = 1
                     Scrivi("[" & Format2(ES) & "] - " & DataEstrazione(ES)),1,0
                     Scrivi " - " & SiglaRuota(R1) & " - ",1,0
                     For S1 = 1 To 5 : E1 = Estratto(ES,R1,S1)
                        If E1 = A1 Or E1 = A2 Or E1 = A3 Then
                           ColoreTesto 2
                        Else
                           ColoreTesto 0
                        End If
                        Scrivi Format2(E1) & " ",1,0
                        ColoreTesto 0
                     Next
                     Scrivi
                  End If
               Next
            Next
         Next
      Next
      If OK > 0 Then Scrivi String(41,"-")
   Next
   Scrivi"list by Master"
End Sub

 

[Xeroxs]

Grazie, per il listato.
Si avvicina molto a ciò che volevo e direi che mi soddisfa.
Ti darei del Tu, se non offendo.
Secondo Te riesco facilmente a modificarlo volendo cercare la terzina della somma cercata composta solo dalla somma e dei due numeri che la compongono ad esempio restando sul 90

90 38 52
90 59 31
27 90 63

Grazie Ancora per la risposta.

 

[Master]

Ciao
Prova questa soluzione..da controllare

Sub Main()
   Dim INI,FINE,ES,R1,A1,A2,A3,P1,P2,P3
   Dim RS,SA,E1,S1,OK
   RS = InputBox("Quante estrazioni vuoi controllare?","ESTRAZIONI",100)
   SA = CInt(InputBox("Quale somma?","SOMMA",90))
   Scrivi String(2," ") & "********* TERZINE DI SOMMA " & SA & " ********",1
   Scrivi
   INI = EstrazioneFin - RS : FINE = EstrazioneFin
   For ES = INI To FINE : : AvanzamentoElab INI,FINE,ES : OK = 0
      For R1 = 1 To 11
         If R1 = 11 Then R1 = 12
         For P1 = 1 To 4 : A1 = Estratto(ES,R1,P1)
            For P2 = P1 + 1 To 5 : A2 = Estratto(ES,R1,P2)
               A3 = Fuori90(A1 + A2)
               If A1 <> A3 And A2 <> A3 Then
                  If Posizione(ES,R1,A3) > 0 And A3 = SA Then
                     OK = 1
                     Scrivi("[" & Format2(ES) & "] - " & DataEstrazione(ES)),1,0
                     Scrivi " - " & SiglaRuota(R1) & " - ",1,0
                     For S1 = 1 To 5 : E1 = Estratto(ES,R1,S1)
                        If E1 = A1 Or E1 = A2 Then
                           ColoreTesto 2
                        Else
                           If E1 = A3 Then
                              ColoreTesto 1
                           Else
                              ColoreTesto 0
                           End If
                        End If
                        Scrivi Format2(E1) & " ",1,0
                        ColoreTesto 0
                     Next
                     Scrivi
                  End If
               End If
            Next
         Next
      Next
      If OK > 0 Then Scrivi String(41,"-")
   Next
   Scrivi"list by Master"
End Sub

 

[Xeroxs]

Grazie, Direi Perfetto, Cosi Ho due soluzioni per cercare delle Soluzioni Di calcolo