x salv50 ambo unito e non ma isotopo

kubes · 14 Maggio 2019

anche in 3 estrazioni precedenti,trovare due ambi che abbiano in comune la stessa distanza ed isotopi.(le coppie possono essere anche non unite ma isotope )

estrazione del 24/03/2011
NA 14 42 <dist. 28>
estrazione del 31/03/2011
TO 08-36 <dist 28>

pertanto averemo

14 (+28) 42 (+28) [ 70] (+28) 08 (+28) 36

Il 70 è il numero che mancava e sarà ambata
abbinamenti per ambo 14-36 NA-TO.
In questo caso il 70 si è incastrato perfettamente al centro, sono validi anche incastri che si inseriscano in altre posizioni.
********************************************************
ESTRAZIONE 20/04/2019
RO 65.13 <DIST.38>
NZ 89 37 <Dist. 38>
65 (+38) 13 [51] 89 (+38) 37

AMBATA =51
ABBINAMENTI PER AMBO=65.37 RO-NZ
*******************************************************
ESTRAZIONE DEL 27.04.2019
FI 19.08. Dist. 11
NZ 41.52 Dist. 11
08 (11) 19 (11) [30] (11) 41 (11) 52

AMBATA =30
ABBINAMENTI = 19.52 FI-NAZ

salvo50 · 15 Maggio 2019

Ciao a Tutti.

Avevo buttato la spugna, quando mi sono ricordato che alcuni mesi fa, uno script quasi uguale l'avevo fatto per Juri (con l'aiuto straordinario di DJNomade) .
E' lo stesso script gli ho solo aggiunto la ricerca dei 2 ambi e l'isotopia

Codice:

Option Explicit
Sub Main()
   Dim R1,R2,P1,P2,P3,P4,P5,P6,A,B,C,D
   Dim DZ12,DZ23,DZ34,DZ14,E1,E2,X,Clp,Salvo50
   Dim Es,Ini,Fin,Nu,D2,Caso,Casi
   Dim Am(1),Z(4),Ambo1(2),Ambo2(2)
   Dim Ruote(2),Posta(1),Poste(2)
   Posta(1) = 1
   Poste(2) = 1
   Fin = EstrazioneFin
   Ini = 9600
   Clp = CInt(InputBox(" Per quanti colpi vuoi giocare? ",Salvo50,7))
   Call ScegliRange(Ini,Fin,Ini,Fin)
   Scrivi Space(12) & "CHIESTO da KUBES AMBO ISOTOPO STESSA DISTANZA - SCRIPT Salvo50",1,,4,,3,,1
   For Es = Ini To Fin
      Caso = 0
      Messaggio "Estrazione esaminata: " & CStr(Es)
      AvanzamentoElab Ini,Fin,Es
      For R1 = 1 To 10
         For P1 = 1 To 4
            For P2 = P1 + 1 To 5
               A = Estratto(Es,R1,P1)
               B = Estratto(Es,R1,P2)
               For R2 = R1 + 1 To 12
                  If R2 = 11 Then R2 = 12
                  C = Estratto(Es,R2,P1)
                  D = Estratto(Es,R2,P2)
                  If A <> C And A <> D And B <> C And B <> D Then
                     Z(1) = A : Z(2) = B : Z(3) = C : Z(4) = D
                     Call OrdinaMatrice(Z,1)
                     DZ12 = Distanza(Z(1),Z(2))
                     DZ23 = Distanza(Z(2),Z(3))
                     DZ34 = Distanza(Z(3),Z(4))
                     DZ14 = Distanza(Z(1),Z(4))
                     For X = 1 To 45
                        If(DZ12 = X And DZ23 = X And DZ34 =(X * 2))_
                           Xor(DZ12 = X And DZ34 = X And DZ23 =(X * 2))_
                           Xor(DZ12 = X And DZ34 = X And DZ14 =(X * 2))_
                           Xor(DZ12 = X And DZ14 = X And DZ34 =(X * 2))_
                           Xor(DZ23 = X And DZ34 = X And DZ12 =(X * 2))_
                           Xor(DZ23 = X And DZ34 = X And DZ14 =(X * 2))_
                           Xor(DZ23 = X And DZ14 = X And DZ34 =(X * 2))_
                           Xor(DZ12 = X And DZ23 = X And DZ34 = X)_
                           Xor(DZ23 = X And DZ34 = X And DZ14 = X) Then
                           If DZ12 =(X * 2) Then Nu = Fuori90(Z(1) + X)
                           If DZ23 =(X * 2) Then Nu = Fuori90(Z(2) + X)
                           If DZ34 =(X * 2) Then Nu = Fuori90(Z(3) + X)
                           If DZ14 =(X * 2) Then Nu = Fuori90(Z(4) + X)
                           If(DZ12 = X And DZ23 = X And DZ34 = X) Then Nu = Fuori90(Z(4) + X)
                           If(DZ23 = X And DZ34 = X And DZ14 = X) Then Nu = Fuori90(Z(1) + X)
                           Caso = Caso + 1
                           Casi = Casi + 1
                           ColoreTesto 1
                           Scrivi String(89,"o") & " Casi Totali " & FormattaStringa(Casi,"0000")
                           ColoreTesto 2
                           Scrivi String(80,"o") & " Estrazione " &(Es) & " caso " & FormattaStringa(Caso,"0000")
                           ColoreTesto 0
                           Scrivi
                           Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
                           Scrivi "  " & SiglaRuota(R1) & " ",1,0
                           For P5 = 1 To 5
                              E1 = Estratto(Es,R1,P5)
                              If E1 = A Or E1 = B Then
                                 Call ColoreTesto(2)
                              Else
                                 Call ColoreTesto(0)
                              End If
                              Call Scrivi(Format2(E1) & " ",1,0)
                              Call ColoreTesto(0)
                           Next
                           Scrivi
                           Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
                           Scrivi "  " & SiglaRuota(R2) & " ",1,0
                           For P6 = 1 To 5
                              E2 = Estratto(Es,R2,P6)
                              If E2 = C Or E2 = D Then
                                 Call ColoreTesto(2)
                              Else
                                 Call ColoreTesto(0)
                              End If
                              Call Scrivi(Format2(E2) & " ",1,0)
                              Call ColoreTesto(0)
                           Next
                           Scrivi "  Distanza " & Format2(X) & "  Mancante ",1,0
                           Scrivi Format2(Nu),1,,,2
                           If(DZ12 = X And DZ23 = X And DZ34 =(X * 2)) Then Scrivi" Sequenza " & Z(1) & "-" & Z(2) & "-" & Z(3) & "-" & Nu & "-" & Z(4),1
                           If(DZ12 = X And DZ34 = X And DZ23 =(X * 2)) Then Scrivi" Sequenza " & Z(1) & "-" & Z(2) & "-" & Nu & "-" & Z(3) & "-" & Z(4),1
                           If(DZ12 = X And DZ34 = X And DZ14 =(X * 2)) Then Scrivi" Sequenza " & Z(1) & "-" & Z(2) & "-" & Z(3) & "-" & Z(4) & "-" & Nu,1
                           If(DZ12 = X And DZ14 = X And DZ34 =(X * 2)) Then Scrivi" Sequenza " & Z(3) & "-" & Nu & "-" & Z(4) & "-" & Z(1) & "-" & Z(2),1
                           If(DZ23 = X And DZ34 = X And DZ12 =(X * 2)) Then Scrivi" Sequenza " & Z(1) & "-" & Nu & "-" & Z(2) & "-" & Z(3) & "-" & Z(4),1
                           If(DZ23 = X And DZ34 = X And DZ14 =(X * 2)) Then Scrivi" Sequenza " & Z(2) & "-" & Z(3) & "-" & Z(4) & "-" & Nu & "-" & Z(1),1
                           If(DZ23 = X And DZ14 = X And DZ34 =(X * 2)) Then Scrivi" Sequenza " & Z(2) & "-" & Z(3) & "-" & Nu & "-" & Z(4) & "-" & Z(1),1
                           If(DZ12 = X And DZ23 = X And DZ34 = X) Then Scrivi" Sequenza " & Z(1) & "-" & Z(2) & "-" & Z(3) & "-" & Z(4) & "-" & Nu,1
                           If(DZ23 = X And DZ34 = X And DZ14 = X) Then Scrivi" Sequenza " & Z(2) & "-" & Z(3) & "-" & Z(4) & "-" & Z(1) & "-" & Nu,1
                           Ruote(1) = R1
                           Ruote(2) = R2
                           Am(1) = Nu
                           Scrivi
                           ImpostaGiocata 1,Am,Ruote,Posta,Clp,1
                           Ambo1(1) = Nu : Ambo1(2) = A
                           ImpostaGiocata 2,Ambo1,Ruote,Poste,Clp
                           Ambo2(1) = Nu : Ambo2(2) = D
                           ImpostaGiocata 3,Ambo2,Ruote,Poste,Clp
                           Gioca Es
                        End If
                        If ScriptInterrotto Then Exit Sub
                     Next
                  End If
               Next
            Next
         Next
      Next
      If ScriptInterrotto Then Exit Sub
   Next
   ScriviResoconto
End Sub

kubes · 15 Maggio 2019

GENTILISSIMO E SEMPRE ALLA GRANDE, GRAZIE

lla · 16 Maggio 2019

scusate se mi intrometto..
sarebbe possibile riadattarlo in questo modo

trovare due ambi nella stessa estrazione e in posizione isotopa che abbiano in comune la stessa distanza
e mettere in gioco il vertibile del numero + piccolo fra i 4 e i restanti 3

esempio ge 29 1 to 25 53
in gioco su ge to
10,29,25,83

ed eventualmente se non si disfa tutto lo script ..avere la possibilità di disabilitare quella parte di codice che verifica l'isotopia magari mettendo ' come fosse un commento, in modo da poter cogliere anche coppie con stessa distanza ma in posizioni differenti, ma se impiccia non importa

GioRyuKen72 · 16 Maggio 2019

Ciao Ila, dimmi come va questo..mi sono superato sul vertibile (stavo quasi rinunciando) ahahaha

Codice:

Sub Main
   ColoreTesto 0
   Scrivi " METODO Ambi Isotopi con egual Differenza  -------- LISTATO BY SALVO modificato da GIORYUKEN72",,1,3,,4
   Scrivi
   ColoreTesto 0
   Dim Fin,Ini,Es,R1,R2,Casi,P1,P2
   Dim Nn(4),quartina1(4)
   Dim ruota(2),posteQ(4)
   posteQ(2) = 1.1 'euro sulla sorte Ambo
   posteQ(3) = 0.3 'euro sulla sorte Terno
   posteQ(4) = 0.1 'euro sulla sorte Quaterna
   Fin = EstrazioneFin
   Ini = InputBox("Da quale estrazione vuoi inziare la ricerca?","INSERIRE IL NUMERO DELL'ESTRAZIONE",9617)
   Call ScegliRange(EstrazioneIni,Fin,Ini,EstrazioneFin)
   For Es = Ini To Fin
      AvanzamentoElab Ini,Fin,Es
      For R1 = 1 To 10
         For R2 = R1 + 1 To 12
            For P1 = 1 To 4
               For P2 = P1 + 1 To 5
                  Nn(1) = Estratto(Es,R1,P1)
                  Nn(2) = Estratto(Es,R1,P2)
                  Nn(3) = Estratto(Es,R2,P1)
                  Nn(4) = Estratto(Es,R2,P2)
                  ok = 0
                  If Differenza(Nn(1),Nn(2)) = Differenza(Nn(3),Nn(4)) Then :ok = 1
                  If ok = 1 Then
                     Casi = Casi + 1
                     ruota(1) = R1
                     ruota(2) = R2
                     Scrivi String(80,"*") & " Estrazione " &(Es) & " caso " & FormattaStringa(Casi,"0000"),1,,,1
                     Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
                     Scrivi "  " & SiglaRuota(R1) & " " & StringaEstratti(Es,R1),1
                     Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
                     Scrivi "  " & SiglaRuota(R2) & " " & StringaEstratti(Es,R2),1
                     Scrivi Space(40) & Format2(Nn(1)) & " >> " & Format2(Nn(2)) & " =  " & Differenza(Nn(1),Nn(2)),1,,,2
                     Scrivi Space(40) & Format2(Nn(3)) & " >> " & Format2(Nn(4)) & " =  " & Differenza(Nn(3),Nn(4)),1,,,2
                     ColoreTesto 0
                     Call OrdinaMatrice(Nn,1)
                     quartina1(1) = Vert(Nn(1))
                     quartina1(2) = Nn(2)
                     quartina1(3) = Nn(3)
                     quartina1(4) = Nn(4)
                     ImpostaGiocata 1,quartina1,ruota,posteQ,9,2
                     Gioca Es,,,1
                  End If
                 Next
            Next
         Next
      Next
   Next
   ColoreTesto 0
   Scrivi String(65,"•")
   TestoInBandaPassante " ***** LISTATO BY SALVO modificato da GIORYUKEN72 ***** ",1,3,0
   ScriviResoconto
End Sub

Ciao
Gio.

lla · 17 Maggio 2019

Grazie GioRyuKen72

molto gentile

volevo chiederti 2 cose sullo script

nasce per l'ambata ma vedo che nel resoconto conteggia i casi dall'ambo, per verificare quante ambate hanno dato esito dove modifico?
e poi...siccome non sono soddisfatta degli esiti

se volessi utilizzare la distanza che ha trovato mi basta inseire un valore x=distanza?
non è che devo rimettere questa parte?

For X = 1 To 45

If(DZ12 = X And DZ23 = X And DZ34 =(X * 2))_ Xor(DZ12 = X And DZ34 = X
And DZ23 =(X * 2))_ Xor(DZ12 = X And DZ34 = X And DZ14 =(X * 2))_ Xor(DZ12 = X
And DZ14 = X And DZ34 =(X * 2))_ Xor(DZ23 = X And DZ34 = X And DZ12 =(X * 2))_ Xor(DZ23 = X And DZ34 = X And DZ14 =(X * 2))_ Xor(DZ23 = X And DZ14 = X And DZ34 =(X * 2))_ Xor(DZ12 = X And DZ23 = X And DZ34 = X)_ Xor(DZ23 = X And DZ34 = X And DZ14 = X) Then If DZ12 =(X * 2) X)

è troppo per me ..ho capito che verifica le distanze fra le coppie di estratti ma niente più.. oppure mi basta mettere una voce tipo x= distanza(n1,n2) per esempio?

grazie! quando puoi/vuoi ovviamente...

salvo50 · 17 Maggio 2019

Ciao a Tutti.

Lia quello che hai chiesto nel post 4 in comune col mio script ha poco e niente, infatti GioRyuKen72 l'ha completamente saltata la parte di -For X = 1 To 45 - io l'avevo fatto in quel modo, perchè mi si chiedeva tutti e 4 le distanze uguali che ci sono in 4 numeri qualsiasi ed in più trovarne un altro che si incastri in qualsiasi parte rispettando sempre la stessa distanza, magari si può fare in qualche modo completamente diverso e molto più semplice, non lo so.

In questo script alla terza domanda puoi decidere la distanza

Codice:

Option Explicit
Sub Main
   Dim FIn,Ini,A,B,C,D,Clp,Es
   Dim R1,R2,P1,P2,P3,P4,P5,P6,E1,E2
   Dim DAB,DCD,Sp,Dist
   Dim Salvo50,Caso,Casi
   Dim Ruo(2),Po1(5),M(4),Num(4)
   Sp = " "
   FIn = EstrazioneFin
   Ini = CInt(InputBox("Inserisci l'estrazione che vuoi iniziare",Salvo50,9600))
   Clp = CInt(InputBox(" Per quanti colpi vuoi giocare?",Salvo50,9))
   Dist = CInt(InputBox(" Quale distanza cercare?",Salvo50,9))
   Call ScegliRange(Ini,FIn,Ini,FIn)
   Scrivi Space(12) & " AMBI STESSA DISTANZA - CHIESTO DA LIA - SCRIPT SALVO50",1,,4,,3,,1
   Po1(2) = 1
   Po1(3) = 1
   For Es = Ini To FIn
      Messaggio Es
      AvanzamentoElab Ini,FIn,Es
      Caso = 0
      For R1 = 1 To 10
         For P1 = 1 To 4
            For P2 = P1 + 1 To 5
               A = Estratto(Es,R1,P1)
               B = Estratto(Es,R1,P2)
               For R2 = R1 + 1 To 12
                  If R2 = 11 Then R2 = 12
                  For P3 = 1 To 4
                     For P4 = P3 + 1 To 5
                        C = Estratto(Es,R2,P3)
                        D = Estratto(Es,R2,P4)
                        'A---B
                        '|   |
                        'C---D
                        If A <> C And A <> D And B <> C And B <> D Then
                           DAB = Distanza(A,B) : DCD = Distanza(C,D)
                           If DAB = DCD And DAB = Dist Then
                              M(1) = A : M(2) = B : M(3) = C : M(4) = D
                              OrdinaMatrice M,1
                              Num(1) = Vert(M(1)) : Num(2) = M(2) : Num(3) = M(3) : Num(4) = M(4)
                              Caso = Caso + 1
                              Casi = Casi + 1
                              Scrivi String(89,"*") & " Casi Totali " & FormattaStringa(Casi,"0000"),1,,,2
                              Scrivi String(80,"*") & " Estrazione " &(Es) & " caso " & FormattaStringa(Caso,"0000"),1,,,1
                              Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
                              Scrivi "  " & SiglaRuota(R1) & " ",1,0
                              For P5 = 1 To 5
                                 E1 = Estratto(Es,R1,P5)
                                 If E1 = A Or E1 = B Then
                                    ColoreTesto 2
                                 Else
                                    ColoreTesto 0
                                 End If
                                 Scrivi Format2(E1) & " ",1,0
                                 ColoreTesto 0
                              Next
                              Scrivi
                              Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
                              Scrivi "  " & SiglaRuota(R2) & " ",1,0
                              For P6 = 1 To 5
                                 E2 = Estratto(Es,R2,P6)
                                 If E2 = C Or E2 = D Then
                                    ColoreTesto 2
                                 Else
                                    ColoreTesto 0
                                 End If
                                 Scrivi Format2(E2) & " ",1,0
                                 ColoreTesto 0
                              Next
                              Scrivi
                              Scrivi
                              Scrivi Space(7) & "Estratti " & Space(4) & "Dist. Orizz. " & Space(5) & "Estr. in Ordine Crescente",1
                              Scrivi Space(8) & Format2(A) & " " & Format2(B) & Space(11) & Format2(DAB),1,0
                              Scrivi Space(19) & Format2(M(1)) & Sp & Format2(M(2)) & Sp & Format2(M(3)) & Sp & Format2(M(4)),1,,,2
                              Scrivi Space(8) & Format2(C) & " " & Format2(D) & Space(11) & Format2(DCD),1
                              Ruo(1) = R1
                              Ruo(2) = R2
                              EliminaRipetuti Num
                              ImpostaGiocata 1,Num,Ruo,Po1,Clp
                              Gioca Es
                           End If
                        End If
                     Next
                  Next
               Next
            Next
         Next
      Next
      If ScriptInterrotto Then Exit Sub
   Next
   ScriviResoconto
End Sub

lla · 17 Maggio 2019

buongiorno a tutti

grazie Salvo50 per questa ulteriore variante

chiedevo in sostanza la possibilità di vedere su un unico script le uscite dei numeri nel caso di coppie isotope e non, era per verifica/controllo, ma mi arrangio ragazzi ..ci mancherebbe

.

ti posso chiedere la gentilezza di spiegarmi qui :
If DAB = DCD And DAB = Dist Then M(1) = A : M(2) = B : M(3) = C : M(4) = D OrdinaMatrice M,1 Num(1) = Vert(M(1)) : Num(2) = M(2) : Num(3) = M(3) : Num(4) = M(4) cos'è m?

salvo50 · 17 Maggio 2019

Codice:

'A e B ________sono gli estratti della prima ruota
'C e D ________sono gli estratti della seconda ruota


'DAB = Distanza(A,B) : DCD = Distanza(C,D) sono le distanze ciclometriche
'tra A e B  e  tra C e D
'

'quindi con

'If DAB = DCD And DAB = Dist Then ' controllo le distanze tra gli estratti
'della prima ruota e della seconda ruota siano uguali e contemporaneamente
'con DAB = Dist, controllo

'che la distanza trovata sia uguale alla distanza impostata tramite InputBox, se ci
'sono queste condizioni lo script prosegue con la riga di programma successiva
'altrimenti salta tutte le righe che ci sono fino al suo END IF


'Quindi se ci sono le condizioni prosegue con la riga successiva,



'M(1) = A : M(2) = B : M(3) = C : M(4) = D ________ metto i 4 estratti in una variabile
'con indice (credo si chiami così,forse)
' riga successiva

OrdinaMatrice M,1 'Questa funzione mette in ordine i numeri dentro la variabile M
' in ordine crescente se dopo la M metti 1 ed in ordine decrescente se metti -1
'quindi dopo questa operazione sò che M(1) è l'estratto più piccolo e quindi come avevi
'chiesto nei numeri da cercare ho messo il vertibile, più gli altri estratti


'Num(1) = Vert(M(1)) : Num(2) = M(2) : Num(3) = M(3) : Num(4) = M(4)

GioRyuKen72 · 17 Maggio 2019

Ciao Ila, se vuoi vedere solo le ambate nello script di Salvo50, aggiungi questa riga sopra po1(2):
po1(1) = 2

e aggiungi il numero 1 preceduto dalla virgola alla fine di questa:
ImpostaGiocata 1,Num,Ruo,Po1,Clp,1

Ciao
Gio.

lla · 17 Maggio 2019

grazie immensamente ragazzi ora ci butto un occhio

nel frattempo ho provato per conto mio a fare una piccola modifica per mettere in gioco anche la distanza che trova..e mi è riuscito
lo so è è una cosa banale ma x me ..che parto da 0..

grazie ancora

GioRyuKen72 · 17 Maggio 2019

lla;n2171798 ha scritto:
grazie immensamente ragazzi ora ci butto un occhio

nel frattempo ho provato per conto mio a fare una piccola modifica per mettere in gioco anche la distanza che trova..e mi è riuscito
lo so è è una cosa banale ma x me ..che parto da 0..

grazie ancora

..ti capisco benissimo, anche io sono felicissimo quando mi riescono le modifiche che faccio..

lla · 19 Giugno 2019

ciao a tutti

vorrei chiedervi come fare per mettere nello stesso pronostico 2 numeri calcolati da due estrazioni differenti ?..esempio:

dim a, b, c, num(10)
posta (1)=1
r = CInt(InputBox("su che rutoa?",,7))
ee = CInt(InputBox("Quante estrazioni?",,10))
clp = CInt(InputBox("Quanti colpi?",,12))

fin = EstrazioneFin
ini = EstrazioneFin - ee

For es = ini To fin
a = Estratto(es,pa_,1)
b = Estratto(es,pa_,2)
c=fuori90(a+b)

num(1)=c ( il mio calcolo cioè la somma dei primi due estratti )

ecco...diciamo che il mio calcolo è questo ma io voglio che mi dia la somma dei primi 2 estratti dell'estrazione ..che ne so..18.6.2019 e poi voglio la somma sempre dei primi 2 estratti ma dell'estrazione precedente cioè quella del 15 giugno, oppure di 2 estrazioni precedenti.. a mia scelta se possibile ..altrimenti va bene anche di 2 estrazioni consecutive.

e che quindi mi metta questi due calcoli uguali nel procedimento nello stesso pronostico

poi vorrei chiedervi..ma se io voglio posso fare una previsione di più di 10 numeri posso farla? mi si impalla il programma quando ci provo
num(10) è il massimo che mi prende

poi alla fine per quel che riguarda il resoconto..è possibile avere una statistica di uscita dei numeri? al momento mi guardo un numero per volta e disattivo tutti gl ialtri mettendo il segno ' ..come fosse un commento

grazie a tutti

salvo50 · 19 Giugno 2019

Ciao a Tutti

lla;n2176720 ha scritto:
ciao a tutti

vorrei chiedervi come fare per mettere nello stesso pronostico 2 numeri calcolati da due estrazioni differenti ?..esempio:

dim a, b, c, num(10)
posta (1)=1
r = CInt(InputBox("su che rutoa?",,7))
ee = CInt(InputBox("Quante estrazioni?",,10))
clp = CInt(InputBox("Quanti colpi?",,12))

fin = EstrazioneFin
ini = EstrazioneFin - ee

For es = ini To fin
a = Estratto(es,pa_,1)
b = Estratto(es,pa_,2)
c=fuori90(a+b)

num(1)=c ( il mio calcolo cioè la somma dei primi due estratti )

ecco...diciamo che il mio calcolo è questo ma io voglio che mi dia la somma dei primi 2 estratti dell'estrazione ..che ne so..18.6.2019 e poi voglio la somma sempre dei primi 2 estratti ma dell'estrazione precedente cioè quella del 15 giugno, oppure di 2 estrazioni precedenti.. a mia scelta se possibile ..altrimenti va bene anche di 2 estrazioni consecutive.

e che quindi mi metta questi due calcoli uguali nel procedimento nello stesso pronostico

Se vuoi prendere una estrazione indietro oppure avanti di quella impostata date qui
ee = CInt(InputBox("Quante estrazioni?",,10))
metti - 1 oppure + 1 se sono di più metti un numero più alto, e come dicono i maestri
ci sono molti modi per arrivare alla meta, questo è uno dei tanti.

Codice:

'Option Explicit
Sub Main
   Dim a,b,c,a1,b1,c1,a2,b2,c2
   Dim num(10),posta(5)
   posta(1) = 1
   r = CInt(InputBox("su che rutoa?",,7))
   ee = CInt(InputBox("Quante estrazioni?",,10))
   clp = CInt(InputBox("Quanti colpi?",,12))
   fin = EstrazioneFin
   ini = EstrazioneFin - ee
   For es = ini To fin
      a1 = Estratto(es - 1,PA_,1)
      b1 = Estratto(es - 1,PA_,2)
      c1 = Fuori90(a1 + b1)
      '----------------------------
      a = Estratto(es,PA_,1)
      b = Estratto(es,PA_,2)
      c = Fuori90(a + b)
      '--------------------------
      a2 = Estratto(es + 1,PA_,1)
      b2 = Estratto(es + 1,PA_,2)
      c2 = Fuori90(a2 + b2)
      Scrivi(" Estrazione n." & Format2(Es - 1) & " del " & DataEstrazione(Es - 1)),1,0
      Scrivi "  " & SiglaRuota(PA_) & " " & StringaEstratti(Es - 1,PA_),1,0
      Scrivi "  Somma 1° e 2° estratto = " & Format2(c1)
      Scrivi(" Estrazione n." & Format2(Es) & " del " & DataEstrazione(Es)),1,0
      Scrivi "  " & SiglaRuota(PA_) & " " & StringaEstratti(Es,PA_),1,0
      Scrivi "  Somma 1° e 2° estratto = " & Format2(c)
      Scrivi(" Estrazione n." & Format2(Es + 1) & " del " & DataEstrazione(Es + 1)),1,0
      Scrivi "  " & SiglaRuota(PA_) & " " & StringaEstratti(Es + 1,PA_),1,0
      Scrivi "  Somma 1° e 2° estratto = " & Format2(c2)
      Scrivi String(52,"*")
   Next
End Sub

poi vorrei chiedervi..ma se io voglio posso fare una previsione di più di 10 numeri posso farla? mi si impalla il programma quando ci provo
num(10) è il massimo che mi prende

Con ImpostaGiocata, il massimo sono 10 numeri, il MITICO LUIGIB, l'ha fatto così perche al massimo in una bolletta puoi inserire 10 numeri, per cercare più di 10 numeri puoi usare VERIFICAESITO

poi alla fine per quel che riguarda il resoconto..è possibile avere una statistica di uscita dei numeri? al momento mi guardo un numero per volta e disattivo tutti gl ialtri mettendo il segno ' ..come fosse un commento

grazie a tutti

questa non l'ho capita

lla · 19 Giugno 2019

ciao Salvo

grazie stai sempre sul pezzo, ho già fatto qualche piccola prova con quello che mi hai scritto

per il discorso della statistica intendevo dire..nel caso in cui io faccio un pronostico di 5 numeri ( num1,num2,num3 ecc)con il resoconto alla fine posso vedere quei 5 numeri quante volte mi hanno dato (tutti insieme) almeno un'ambata o ambo .
io poi a mano mi controllo ogni numero singolo quante volte è uscito e più o meno dopo quanti colpi

invece io vorrei proprio una statistica di uscita ovvero il num 1 su 10 estrazioni quante volte è uscito? per es. 8 su 10 e con un'attesa media di 4 colpi.
poi mi piacerebbe anche sapere sempre(per es.) quante volte il num1 è uscito in coppia con un num3

ho dato un'occhiata a quanto disponibile nella guida del programma ma non mi è riuscito di metterlo in pratica

p.s.
sempre sia lodato Luigi B che non conosco direttamente ma ho imparato ad apprezzare la sua fama girando qui sul forum

salvo50 · 19 Giugno 2019

lla;n2176752 ha scritto:
ciao Salvo

grazie stai sempre sul pezzo, ho già fatto qualche piccola prova con quello che mi hai scritto

per il discorso della statistica intendevo dire..nel caso in cui io faccio un pronostico di 5 numeri ( num1,num2,num3 ecc)con il resoconto alla fine posso vedere quei 5 numeri quante volte mi hanno dato (tutti insieme) almeno un'ambata o ambo .
io poi a mano mi controllo ogni numero singolo quante volte è uscito e più o meno dopo quanti colpi

invece io vorrei proprio una statistica di uscita ovvero il num 1 su 10 estrazioni quante volte è uscito? per es. 8 su 10 e con un'attesa media di 4 colpi.
poi mi piacerebbe anche sapere sempre(per es.) quante volte il num1 è uscito in coppia con un num3

ho dato un'occhiata a quanto disponibile nella guida del programma ma non mi è riuscito di metterlo in pratica

p.s.
sempre sia lodato Luigi B che non conosco direttamente ma ho imparato ad apprezzare la sua fama girando qui sul forum

Prova ad inserire queste 2 righe alla fine dello script, prima di ScriviResoconto
-----------------------------------------------------------

ScriviDistribuzioneEsiti(True)

ScriviDistribuzioneCasiInCorso(True)

------------------------------------------------------------
questa è una delle ultime modifiche di LuigiB al programma Spaziometria, quindi per non andare in errore la versione deve essere la 1.6.30 o superiore

lla · 20 Giugno 2019

mette 2 tabelline colorate
la prima con il numero di colpi in cui la previsione si è verificata sul totale dei casi vincenti

cioè quante volte per esempio l'ambo o l'ambata son usciti al 3 colpo però non fornisce dettagli sui numeri vincenti, dentro le parentesi posso mettere anche altri dati che voglio sapere? tipo se è uscito il num1 o il num2 o il 3..ecc?

salvo50 · 20 Giugno 2019

lla;n2176883 ha scritto:
dentro le parentesi posso mettere anche altri dati che voglio sapere? tipo se è uscito il num1 o il num2 o il 3..ecc?

Non credo, però io non sono esperto.

lla · 25 Giugno 2019

cmq sempre grazie

x salv50 ambo unito e non ma isotopo

Senior Member

Advanced Member >PLATINUM PLUS<

Senior Member

Premium Member

Advanced Member >PLATINUM PLUS<

Premium Member

Advanced Member >PLATINUM PLUS<

Premium Member

Advanced Member >PLATINUM PLUS<

Advanced Member >PLATINUM PLUS<

Premium Member

Advanced Member >PLATINUM PLUS<

Premium Member

Advanced Member >PLATINUM PLUS<

Premium Member

Advanced Member >PLATINUM PLUS<

Premium Member

Advanced Member >PLATINUM PLUS<

Premium Member