Proviamo a Testare le funzioni script di spazio Light e chiedere delucidazioni sulle difficoltà riscontrate

[Mike58]

Ok, io impiego 4 min e 19 sec con il tuo script (sarà il mio processore).

usi la seerieStat o la SerieRitardo ?

usavo seriestat per la cosiddetta frequenza (mancante per tutti quei discorsi).
Comunque nettamente più veloce della freq uguale a zero.

 

[LuigiB]

si perche la funzione del ritardo parte dlla fine e appena trova il primo esito esce dovendo tornare i lritardo ...
quindi non deve analizzare tutte le estrazioni per ogni combinazione.

 

[LuigiB]

a questo proposito dato che non c'era ho inserito il parametro inizio in serieritardo in modo che uno possa impostare un valore diverso da 1
magari si puo partire dalla famosa prima estrazione valida intorno alla 4000 mi pare.. in questo modo sarà ancora piu veloce

SerieRitardo(aNumeri() As Integer, Ruote As Object, Sorte As Integer, Fine As Integer, Optional aPos() As Boolean = Nothing, Optional ByRef EstrEsaminate As Integer = 0, Optional Inizio As Integer = 0) As Integer

 

[Mike58]

Fatto in Tabella con verifica ultima estrazione se Terno sortito.

Class Script
    Sub Main
        Dim Inizio As Integer =1
        Dim Fine As Integer = EstrazioniArchivio-1
        Dim fin As Integer = EstrazioniArchivio
        Dim Classe As Integer = 3
        Dim Sorte As Integer = 3
        Dim aRuote() As Integer
        Dim nMaxRitPos = Fine - (Inizio -1)
        Dim aN(90) As Integer
        Dim aCol (Classe ) As Integer
        Dim nIntegrali As Integer
        Dim nSviluppate As Integer
        Dim kn As Integer
        Dim nColor As Integer = ColoreBlu
        Dim aUscite () ,T() As String
        Dim esito As String
        If ScegliRuote (aRuote) Then
            T = { " N. " , "  Terni vergini  " , "  Esito Ultima Estrazione  "}
            Call InitTabella(T,ColoreVerde ,,,ColoreBianco )
            For k As Integer = 1 To 90
                aN(k) = k
            Next
            nIntegrali = InitSviluppoIntegrale (aN , Classe )
            Do While GetCombSviluppo (aCol)
                If SerieRitardo ( aCol ,aRuote ,Sorte,Fine ) = nMaxRitPos Then
                    esito = "--"
                    If VerificaEsito (aCol , aRuote ,Sorte ,fin,,,,aUscite)
                        For k1 As Integer = 0 To aUscite.GetUpperBound(0)
                            If aUscite(k1) <> "" Then esito = aUscite(k1)
                        Next
                    End If
                    kn +=1
                    T = {kn , StringaNumeri(aCol), esito  }
                    Call AddRigaTabella (T)
                    'Scrivi ( FormatSpace (kn,2)  & ") " &  StringaNumeri (aCol ))
                End If
                nSviluppate +=1
                If nSviluppate Mod 1000 = 0 Then
                    Messaggio ("Terni vergini su Tutte le Ruote -  Trovati : " & kn & Space (10) & "Tempo di Elab... " & FormattaSecondi ( SecondiTrascorsi )  )
                    AvanzamentoElab ( 1 , nIntegrali , nSviluppate )
                    'MessaggioLista (kn & " -  " & FormattaSecondi ( SecondiTrascorsi ),nColor)
                    If ScriptInterrotto Then Exit Do
                End If
            Loop
Scrivi (" Terni Vergini Ruota : " & NomeRuota (aRuote(1)) ,1)
            Scrivi ( FormattaSecondi ( SecondiTrascorsi ))
        End If
        CreaTabella()
    End Sub
End Class

Terni Vergini Ruota : TT
00:03:04

N. ​	Terni vergini ​	Esito Ultima Estrazione ​
1​	2.10.47​	--​
2​	3.7.12​	--​

 

[Mike58]

a questo proposito dato che non c'era ho inserito il parametro inizio in serieritardo in modo che uno possa impostare un valore diverso da 1
magari si puo partire dalla famosa prima estrazione valida intorno alla 4000 mi pare.. in questo modo sarà ancora piu veloce

SerieRitardo(aNumeri() As Integer, Ruote As Object, Sorte As Integer, Fine As Integer, Optional aPos() As Boolean = Nothing, Optional ByRef EstrEsaminate As Integer = 0, Optional Inizio As Integer = 0) As Integer

dalla 3950 estratte tutte le 10 ruote (tutte)
l'aggiunta con inizio opzionale - Otiima - così se omesso non devono essere riscritti gli altri script.
👏👌

 

[LuigiB]

ho provato ma ahime non cabia moltissimo colpa di tanti terni che non escono ... la classica stria della coperta troppo corta .. se uno esamina meno estrazioni cis sono piu terni che non sono usciti che costringono comunque ad analizzare tutte le estrazioni

 

[LuigiB]

ho provato ma ahime non cabia moltissimo colpa di tanti terni che non escono ... la classica stria della coperta troppo corta .. se uno esamina meno estrazioni cis sono piu terni che non sono usciti che costringono comunque ad analizzare tutte le estrazioni anche se queste sono 5000 invece che 10000 alla fine parecchi terni se le devono leggere tutte quante

 

[i legend]

ciao a tutti
non posso farlo con spaziolight perche ho cancellato la penultima versione e l ultima non riesco a scaricarla , problemi di linea .
ecco lo script in spaziometria , un algoritmo diverso,ma controlla se da risultati corretti

Option Explicit
Sub Main
    Dim aN(88,89,90)
    Dim idestr,r,e1,e2,e3,ntro,m
    Call ResetTimer
    For idestr = 1 To EstrazioneFin
        If ScriptInterrotto Then Exit For
        For r = 1 To 10
            If ScriptInterrotto Then Exit For
            ReDim aEstr(0)
            Call GetArrayNumeriRuota(idestr,r,aEstr)
            If aEstr(1) > 0 Then
                Call OrdinaMatriceTurbo(aEstr,1)
                For e1 = 1 To 3
                    For e2 = e1 + 1 To 4
                        For e3 = e2 + 1 To 5
                            aN(aEstr(e1),aEstr(e2),aEstr(e3)) = 1
                        Next
                    Next
                Next
            End If
        Next
        Call AvanzamentoElab(1,EstrazioneFin,idestr)
    Next
    For e1 = 1 To 88
        If ScriptInterrotto Then Exit For
        For e2 = e1 + 1 To 89
            If ScriptInterrotto Then Exit For
            For e3 = e2 + 1 To 90
                If ScriptInterrotto Then Exit For
                If aN(e1,e2,e3) = "" Then ntro = ntro + 1 :Scrivi ntro & "  " & e1 & "." & e2 & "." & e3
                m = m + 1
                Call AvanzamentoElab(1,117480,m)
            Next
        Next
    Next
    Scrivi TempoTrascorso
End Sub

 

[i legend]

Buona notte

 

[Mike58]

Bravo Legend 49 secondi.
Neanche io ad ora non sono riuscito a scaricare la versine 1.0.29 . tempo stimato 1 ora , magari vedo domani...
Torna presto che c'è bisogno del tuo estro.

 

[i legend]

Credo che con spaziolight sia ancora più veloce

 

[Mike58]

Vediammo domani ci provo.
Scaricata utima versione.

 

[LuigiB]

alla fine il motivo per cui è lento è che

Credo che con spaziolight sia ancora più veloce

bhe hai fatto un algoritmo apposito .. bravo legend , va trasformato cosi .. non fatemi vedere sti cicli for nidificati per fare gli sviluppi ci ha messo 2 secondi ...

Class Script
    Sub Main
        Dim Inizio As Integer =1
        Dim Fine As Integer = EstrazioniArchivio
        Dim Classe As Integer = 3
        Dim Sorte As Integer = 3
        Dim aRuote() As Integer
        Dim nMaxRitPos = Fine - (Inizio -1)
        Dim aN() As Integer
        Dim aCol (Classe ) As Integer
        Dim nIntegrali As Integer
        Dim nSviluppate As Integer
        Dim Coll As Collection = New Collection
        Dim sRiga As String
        If ScegliRuote (aRuote) Then
            ImpostaRuotaTT ( aruote )
            For idEstr As Integer = Inizio To Fine
                For r As Integer = 1 To  aRuote.getupperbound(0)
                    If GetNumeriRuota ( idEstr ,aRuote(r),aN) Then
                        Call OrdinaVettore (aN ,1,,1)
                        InitSviluppoIntegrale (aN ,Classe)
                        Do While GetCombSviluppo ( aCol )
                            sRiga = StringaNumeri ( aCol )
                            AddItemCollection ( Coll , sRiga ,sRiga )
                        Loop
                    End If
                Next
               
            Next
            ReDim aN(90)
            For k As Integer =1 To 90
                aN(k)= k
            Next
            InitSviluppoIntegrale (aN , Classe )
            Do While GetCombSviluppo (aCol )
                sRiga = StringaNumeri (aCol)
                If Not Coll.contains ( sRiga ) Then
                    Scrivi (sRiga)
                End If
            Loop
            Scrivi ( FormattaSecondi ( SecondiTrascorsi ))
        End If
    End Sub
    Sub ImpostaRuotaTT ( byref aRuote as integer ())
        dim bTutte as boolean
        for k as integer = 1 to aruote.getupperbound(0)
            if aruote(k) = 12 then
                btutte = true
                exit for
            end if
        next
   
        if btutte then
            redim aRuote (10)
            for k as integer =1 to 10
                aRuote(k) = k
            next
        end if

    end sub

End Class

 

[Mike58]

Io Invece ci stavo mettendo 2 ore .

😅

 

[LuigiB]

Io Invece ci stavo mettendo 2 ore .

😅

ahahahaha

 

[i legend]

Luigi è sempre un piacere leggere i tuoi script. Elegante e veloce.
Tra spaziometria e spaziolight la differenza di esecuzione degli script è davvero notevole.sembrano eseguiti ai due pc diversi.
Grazie come sempre

 

[LuigiB]

Luigi è sempre un piacere leggere i tuoi script. Elegante e veloce.
Tra spaziometria e spaziolight la differenza di esecuzione degli script è davvero notevole.sembrano eseguiti ai due pc diversi.
Grazie come sempre

Si perche in realtà non è uno script è un compilato.. infatti si scrive in vbnet

 

[Rafele ‘o Ruoss’]

Buongiorno a tutti , chiedo cortesemente se fosse possibile, inserire in ogni script sviluppato laddove possibile anche la previsione di gioco e i colpi teorici .sempre che non abbia detto un eresia.
grazie e buon lavoro

 

[i legend]

Non sono stati inseriti script che danno previsioni. Stiamo cercando ( semplicemente ) di testare le funzioni di questo nuovo software.

 

[Xeroxs]

Buongiorno a Tutti,

Nel Testare quanto sto leggendo sul VB.NET e facendo vari tentativi, vorrei capire una piccola anomalia che accade quando scrivo il "grado" che uso nel Testo, per semplicità riporto l'esempio

Class Script
    Sub Main
    'inserire qui il proprio codice...
    'Test
    Scrivi ("1° Caso")
    Scrivi ("2° Caso")
    End Sub
End Class

è l'esito evidenziato viene scritto in questo modo

1° Caso
2° Caso

Perchè scrive anche questo carattere "Â", è un errore mio, del mio PC o di VB.NEt, o devo scriverlo diversamente se volessi utilizzarlo nel mio modo

Scusate se faccio questo tipo di richiesta difronte alla vostra bravura ma vorrei capire il motivo se noto, o magari lo stampa solo a me.

Grazie