Aggiorna Archivio Spaziometria

giuseppe lasaracina · Lunedì alle 15:01

giuseppe lasaracina ha scritto:
Buongiorno a tutti, faccio presente che l'archivio del 10elotto5m non si aggiorna
più è rimasto fermo al 31-3-2026, quando si tenta di aggiornarlo si spegne
addirittura tutto il programma di spaziometria.
Che dire spaziometria bellissimo programma ma si fa un pò desiderare per
gli aggiornamenti degli archivi.
Una domanda a chi fa gli sript per gli aggiornamenti
Non si può aggiornare tutti gli archivi di spaziometria con gli archivi
di Lottoced ?
grazie a chi vorrà rispondere
Giuseppe

MAURYBIG · Lunedì alle 18:09

Ramco ha scritto:

Partendo dalle indicazioni di Joe, siamo arrivati a completare questo listato per l'aggiornamento archivio Lotto di Spaziometria.
Preleva l'archivio direttamente alla fonte Lottomatica, nella speranza sia stabile.
Tutelatevi sempre con un pre-salvataggio dell'archivio onde evitare inconvenienti.
E' testato con più pc, sperando di aver fatto cosa gradita.
PS: Per Silop, se poi lo vuoi caricare sul tuo sito rendendolo disponibile a tutti...

Codice:

'Aggiorna archivio lotto di Spaziometria (Ramco)_apr2026
'estrazioni prelevate direttamente dalla fonte Lottomatica
Option Explicit
Sub Main
 Dim sDirTemp,sDirZip
 Dim sLink
 Dim sCData,nSalvate,sFileBd
 Dim sDataEstr,sDataLastEstr
 Dim nEstrTot,id,z,b
 Dim aRighe,k
 Dim sData,sSigla
 Dim aEstr,r,c
 Dim aCampi
 Dim sCmd,sDestDir
 Dim oShell,oFSO

 ' --- Percorsi file ---
   sFileBd = GetDirectoryAppData & "BaseDati.dat"
   sDirZip = GetDirectoryTemp & "storico.zip"
   sDirTemp = GetDirectoryTemp & "storico.txt"

   ' --- Pulizia file temporanei ---
   Call EliminaFile(sDirZip)
   Call EliminaFile(sDirTemp)

   ' --- Download dello zip ufficiale BrightStar/LottoItalia ---
   sLink = "https://www.brightstarlottery.it/STORICO_ESTRAZIONI_LOTTO/storico.zip"
   Call Messaggio("Download archivio ufficiale in corso...")

   If Not DownloadFromWeb(sLink,sDirZip) Then
      Call Scrivi("ERRORE: impossibile scaricare il file zip dal sito LottoItalia.",True,,,vbRed)
      Exit Sub
   End If

   ' --- Decompressione zip -> storico.txt tramite PowerShell ---
   Call Messaggio("Decompressione archivio...")

   sDestDir = GetDirectoryTemp
   ' Rimuove eventuale backslash finale per PowerShell
   If Right(sDestDir,1) = "\" Then sDestDir = Left(sDestDir,Len(sDestDir) - 1)
   sCmd = "powershell -NoProfile -Command ""Expand-Archive -Force -LiteralPath '" & sDirZip & "' -DestinationPath '" & sDestDir & "'"""
   Set oShell = CreateObject("WScript.Shell")
   Set oFSO = CreateObject("Scripting.FileSystemObject")
   oShell.Run sCmd,0,True
   Set oShell = Nothing

   If Not oFSO.FileExists(sDirTemp) Then
      Call Scrivi("ERRORE: il file storico.txt non trovato dopo la decompressione.",True,,,vbRed)
      Call Scrivi("Verificare che PowerShell sia disponibile e che lo zip contenga 'storico.txt'.",True)
      Set oFSO = Nothing
      Exit Sub
   End If
   Set oFSO = Nothing

   ' --- Lettura righe del file TXT ---
   ReDim aRighe(0)
   If Not LeggiRigheFileDiTesto(sDirTemp,aRighe) Then
      Call Scrivi("ERRORE: impossibile leggere storico.txt.",True,,,vbRed)
      Exit Sub
   End If
   Call EliminaFile(sDirZip)
   Call EliminaFile(sDirTemp)

   ' --- Dati archivio corrente ---
   nEstrTot = EstrazioniArchivio
   sDataLastEstr = DataEstrazione(nEstrTot,,,"/")
   ' sDataLastEstr e' in formato GG/MM/AAAA
   ' Convertiamo in AAAA/MM/GG per confronto con il file
   z = Right(sDataLastEstr,4) & "/" & Mid(sDataLastEstr,4,2) & "/" & Left(sDataLastEstr,2)
   id = IndiceAnnuale(nEstrTot)
   b = False

   ' --- Loop sulle righe del file ---
   ' Formato riga: AAAA/MM/GG [TAB] SIGLA [TAB] n1 [TAB] n2 [TAB] n3 [TAB] n4 [TAB] n5
   ' 11 righe consecutive con la stessa data = 1 estrazione
   ' Ordine sigle nel file: BA CA FI GE MI NA PA RM RN TO VE
   ' Ordine richiesto da Spaziometria (r=1..11): BA CA FI GE MI NA PA RO TO VE NZ
   ' Rimappatura necessaria: RM->r=8(RO), RN->r=11(NZ), TO->r=9, VE->r=10

   ReDim aEstr(11,5)
   sCData = ""

   For k = 0 To UBound(aRighe)
      If ScriptInterrotto Then Exit For

      ' Salta righe vuote
      If Trim(aRighe(k)) = "" Then
         ' Se avevamo una estrazione in corso con tutti i dati, la salviamo
      Else
         ' Splitta la riga per TAB
         aCampi = Split(aRighe(k),vbTab)

         If UBound(aCampi) >= 6 Then
            sData = Trim(aCampi(0)) ' AAAA/MM/GG
            sSigla = Trim(aCampi(1)) ' BA, CA, ... RM, RN, TO, VE

            ' --- Nuova data = nuova estrazione ---
            If sData <> sCData Then
               ' Salva l'estrazione precedente solo se b=True E non e' quella di z
               If b = True Then
                  If sCData <> "" Then
                     If Left(sCData,4) <> Left(sData,4) Then
                        id = 0
                     End If
                     id = id + 1
                     ' Converti sCData da AAAA/MM/GG a GG/MM/AAAA
                     sDataEstr = Right(sCData,2) & "/" & Mid(sCData,6,2) & "/" & Left(sCData,4)
                     If SalvaEstrazione(aEstr,sDataEstr,id,sFileBd) Then
                        nSalvate = nSalvate + 1
                        Call Messaggio(nSalvate)
                     Else
                        ColoreTesto 2
                        Call Scrivi("ATTENZIONE: errore salvataggio estrazione " & sCData,True)
                        ColoreTesto 0
                     End If
                  End If
               End If

               ' Se la data che STIAMO PER LEGGERE e' z, non ancora b=True
               ' b diventa True DOPO aver letto z, cioe' alla data successiva
               If sCData = z Then b = True

               ' Reset matrice per nuova data
               ReDim aEstr(11,5)
               sCData = sData
            End If

            ' --- Popola la riga corretta della matrice in base alla sigla ---
            ' Rimappatura sigle -> indice ruota Spaziometria
            If sSigla = "BA" Then r = 1
            If sSigla = "CA" Then r = 2
            If sSigla = "FI" Then r = 3
            If sSigla = "GE" Then r = 4
            If sSigla = "MI" Then r = 5
            If sSigla = "NA" Then r = 6
            If sSigla = "PA" Then r = 7
            If sSigla = "RM" Then r = 8 ' RM nel file = Roma = r=8 in Spaziometria
            If sSigla = "TO" Then r = 9
            If sSigla = "VE" Then r = 10
            If sSigla = "RN" Then r = 11 ' RN nel file = Nazionale = r=11 in Spaziometria

            ' Popola i 5 estratti (Format2 restituisce stringa a 2 cifre)
            For c = 1 To 5
               aEstr(r,c) = Format2(CInt(Trim(aCampi(c + 1))))
            Next
         End If
      End If

      Call AvanzamentoElab(0,UBound(aRighe),k)
   Next

   ' --- Salva l'ultima estrazione del file (se b=True) ---
   If b = True Then
      If sCData <> "" Then
         id = id + 1
         sDataEstr = Right(sCData,2) & "/" & Mid(sCData,6,2) & "/" & Left(sCData,4)
         If SalvaEstrazione(aEstr,sDataEstr,id,sFileBd) Then
            nSalvate = nSalvate + 1
         End If
      End If
   End If

   ' --- Riepilogo ---
   If nSalvate > 0 Then
      AllineaArchivi
      Call Scrivi()
      Call Scrivi("Script per Spaziometria - Aggiornamento da LottoItalia/BrightStar",True,,,vbBlue)
      Call Scrivi()
      Call Scrivi("Sono state aggiunte " & nSalvate & " estrazioni")
      Call Scrivi()
      Call Scrivi("Estrazioni totali: " & EstrazioniArchivio)
      Call Scrivi()
      Call Scrivi("Fonte: www.lotto-italia.it (archivio ufficiale BrightStar)")
      Call Scrivi()
      Call Scrivi("RAMCOLOTTO",True,,,vbBlue)
   Else
      Call Scrivi("NON HO TROVATO NUOVE ESTRAZIONI !",1,,,2)
   End If

End Sub

SIETE BRAVISSIMI FUNZIONA ALLA GRADE GRAZIE A TUTTI

MAURYBIG · Lunedì alle 18:14

silop2005 ha scritto:
SPMT vers. 1.6.34_Agg.Web e relativo plugin SVP vers. 1.0.56 e Plugin_FTP vers. 1.0 e SpazioScript vs.1.0.9 e RicercaLunghetta vers.1.0.31 e LottoOpen v.1.0.62 e LottoProjeectLB.net V.1.0.38
======================
Ciao @Ramco ,
======================
dopo aver chiarito alcune cose, ecco lo script dell'amico Ramco
pubblicato sul mio sito a disposizione di TUTTI
per poter effettuare gli aggiornamenti delle estrazioni future per il programma Spaziometria by LuigiB.
Non solo lo script ma potete anche scaricare gli archivi del lotto e del Superenalotto aggiornati a sabato del 11/04/2026.
Vedi immagine:
==================== ==================================

==================================
Buon aggiornamenti.
==================== ==================================
Buon lunedì a tutto il forum.
======================

A presto
Silop

OTTIMO FINZIONA! STO CERCANDO UNO SCRIPT SPIA SIMPATICI X AMBATA E X AMBO MI RENDO CONTO CHE E DIFFICILISSIMO

MAURYBIG · Lunedì alle 18:15

OTTIMO FINZIONA! STO CERCANDO UNO SCRIPT SPIA SIMPATICI X AMBATA E X AMBO MI RENDO CONTO CHE E DIFFICILISSIMO

vinci · Martedì alle 22:20

Ho fatto girare adesso lo script e mi da questa dicitura
NON HO TROVATO NUOVE ESTRAZIONI !

Lottopython · Martedì alle 22:35

@vinci contattami su weel

Cinzia27 · Mercoledì alle 18:12

Ciao, Ramco
Grazie al tuo script ho potuto aggiornare l'archivio del lotto.

genios · Mercoledì alle 18:35

OGGI SEMBRA FUNZIONARE DI NUOVO LO SCRIPT DI RAMCO. ANCHE L AGGIORNAMENTO TXT DEL PROGRAMMA DI LOTTOPYTHON .

Ramco · Mercoledì alle 23:13

genios ha scritto:
OGGI SEMBRA FUNZIONARE DI NUOVO LO SCRIPT DI RAMCO. ANCHE L AGGIORNAMENTO TXT DEL PROGRAMMA DI LOTTOPYTHON .

Ciao Genios, lo script funziona... se non trova estrazioni da aggiornare è perchè il sito UFFICIALE (Lottomatica) non ha ancora aggiornato l'archivio in quel momento. Questo è l'unico neo, la dipendenza nelle tempistiche di aggiornamento degli archivi (ho notato che in buona parte li aggiornano entro un ora dalle estrazioni, ma altrettanto spesso possono passare anche 3-4 ore).

Roby66 · Giovedì alle 20:06

GRAZIE MILLE RAMCO PERSONE COME VOI FANNO FELICI PERSONE CHE ANNO LA PASSIONE DI SPULCIARE QUESTI PROGRAMMI.
GRAZIE DI CUORE

Baciccia4251 · Oggi alle 20:32

Non so se possa interessare: dallo script di Ranco ho chiesto alla AI (qui qualcuno insegna) se era possibile trasformarla in uno script che leggesse un file txt generato dall'archivio di Excel.
Dopo qualche iniziale dificoltà sembra che lo script AI funzioni: Mi ha anche dato la macro da aggiungere a axcel per creare nella corretta directory il file txt. Stasero lo proverò con l'ultima estrazione.
Nel caso dovesse funzionare vi interessa?
Comunque metto lo script generato, usando quello di Ramco, dalla AI:
'Aggiorna archivio lotto di Spaziometria (Ramco)_apr2026
'Versione modificata per usare storico.txt generato da Excel

Option Explicit
Sub Main
Dim sDirTemp,sFileBd
Dim sCData,nSalvate
Dim sDataEstr,sDataLastEstr
Dim nEstrTot,id,z,b
Dim aRighe,k
Dim sData,sSigla
Dim aEstr,r,c
Dim aCampi

' --- Percorso file TXT ---
Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")

' 2 = cartella TEMP di Windows
sDirTemp = fso.GetSpecialFolder(2) & "\storico.txt"

' --- Verifica esistenza file TXT ---
If Not fso.FileExists(sDirTemp) Then
Call Scrivi("ERRORE: il file storico.txt non esiste.", True,,, vbRed)
Call Scrivi("Generarlo prima da Excel con la macro CreaStoricoTXT.", True)
Set fso = Nothing
Exit Sub
End If

Set fso = Nothing

' --- Lettura righe del file TXT ---
ReDim aRighe(0)
If Not LeggiRigheFileDiTesto(sDirTemp,aRighe) Then
Call Scrivi("ERRORE: impossibile leggere storico.txt.",True,,,vbRed)
Exit Sub
End If

' --- Dati archivio corrente ---
nEstrTot = EstrazioniArchivio
sDataLastEstr = DataEstrazione(nEstrTot,,,"/")
z = Right(sDataLastEstr,4) & "/" & Mid(sDataLastEstr,4,2) & "/" & Left(sDataLastEstr,2)
id = IndiceAnnuale(nEstrTot)
b = False

' --- Loop sulle righe del file TXT ---
ReDim aEstr(11,5)
sCData = ""

For k = 0 To UBound(aRighe)
If ScriptInterrotto Then Exit For

If Trim(aRighe(k)) <> "" Then

aCampi = Split(aRighe(k),vbTab)

If UBound(aCampi) >= 6 Then
sData = Trim(aCampi(0)) ' AAAA/MM/GG
sSigla = Trim(aCampi(1))

' --- Nuova data ---
If sData <> sCData Then

If b = True Then
If sCData <> "" Then
If Left(sCData,4) <> Left(sData,4) Then id = 0
id = id + 1
sDataEstr = Right(sCData,2) & "/" & Mid(sCData,6,2) & "/" & Left(sCData,4)
If SalvaEstrazione(aEstr,sDataEstr,id,sFileBd) Then
nSalvate = nSalvate + 1
Call Messaggio(nSalvate)
Else
ColoreTesto 2
Call Scrivi("ATTENZIONE: errore salvataggio estrazione " & sCData,True)
ColoreTesto 0
End If
End If
End If

If sCData = z Then b = True

ReDim aEstr(11,5)
sCData = sData
End If

' --- Rimappatura sigle ---
If sSigla = "BA" Then r = 1
If sSigla = "CA" Then r = 2
If sSigla = "FI" Then r = 3
If sSigla = "GE" Then r = 4
If sSigla = "MI" Then r = 5
If sSigla = "NA" Then r = 6
If sSigla = "PA" Then r = 7
If sSigla = "RM" Then r = 8
If sSigla = "TO" Then r = 9
If sSigla = "VE" Then r = 10
If sSigla = "RN" Then r = 11

' --- Numeri ---
For c = 1 To 5
aEstr(r,c) = Format2(CInt(Trim(aCampi(c + 1))))
Next

End If
End If

Call AvanzamentoElab(0,UBound(aRighe),k)
Next

' --- Salva ultima estrazione ---
If b = True Then
If sCData <> "" Then
id = id + 1
sDataEstr = Right(sCData,2) & "/" & Mid(sCData,6,2) & "/" & Left(sCData,4)
If SalvaEstrazione(aEstr,sDataEstr,id,sFileBd) Then
nSalvate = nSalvate + 1
End If
End If
End If

' --- Riepilogo ---
If nSalvate > 0 Then
AllineaArchivi
Call Scrivi()
Call Scrivi("Script per Spaziometria - Aggiornamento da file Excel",True,,,vbBlue)
Call Scrivi()
Call Scrivi("Sono state aggiunte " & nSalvate & " estrazioni")
Call Scrivi()
Call Scrivi("Estrazioni totali: " & EstrazioniArchivio)
Call Scrivi()
Call Scrivi("RAMCOLOTTO",True,,,vbBlue)
Else
Call Scrivi("NON HO TROVATO NUOVE ESTRAZIONI !",1,,,2)
End If

End Sub

e questa è la macro per excel:

Option Explicit

Sub CreaStoricoTXT()

Dim sh As Worksheet
Dim lastRow As Long, r As Long
Dim f As Integer
Dim pathTXT As String
Dim dataEstr As String
Dim anno As String, mese As String, giorno As String
Dim ruota As Long, c As Long
Dim colMap(1 To 11) As Long
Dim sigla(1 To 11) As String
Dim line As String

Set sh = ThisWorkbook.Worksheets("Archivio")

' Mappa colonne ruote
colMap(1) = 4 ' BA
colMap(2) = 9 ' CA
colMap(3) = 14 ' FI
colMap(4) = 19 ' GE
colMap(5) = 24 ' MI
colMap(6) = 29 ' NA
colMap(7) = 34 ' PA
colMap(8) = 39 ' RM (Roma)
colMap(9) = 44 ' TO
colMap(10) = 49 ' VE
colMap(11) = 54 ' RN (Nazionale)

' Sigle nel formato richiesto da Ramco
sigla(1) = "BA"
sigla(2) = "CA"
sigla(3) = "FI"
sigla(4) = "GE"
sigla(5) = "MI"
sigla(6) = "NA"
sigla(7) = "PA"
sigla(8) = "RM"
sigla(9) = "TO"
sigla(10) = "VE"
sigla(11) = "RN"

lastRow = sh.Cells(sh.Rows.count, "C").End(xlUp).row

' Percorso file TXT nella cartella TEMP
pathTXT = Environ$("TEMP") & "\storico.txt"

f = FreeFile
Open pathTXT For Output As #f

' Loop su tutte le estrazioni
For r = 9 To lastRow

dataEstr = sh.Cells(r, "C").Value
If IsDate(dataEstr) Then

giorno = Format(Day(dataEstr), "00")
mese = Format(Month(dataEstr), "00")
anno = Format(Year(dataEstr), "0000")

' Formato richiesto: AAAA/MM/GG
Dim dataTXT As String
dataTXT = anno & "/" & mese & "/" & giorno

' 11 righe per ogni estrazione
For ruota = 1 To 11
line = dataTXT & vbTab & sigla(ruota)

For c = 0 To 4
line = line & vbTab & Format(sh.Cells(r, colMap(ruota) + c).Value, "00")
Next

Print #f, line
Next

End If

Next r

Close #f

MsgBox "File storico.txt generato correttamente in: " & vbCrLf & pathTXT, vbInformation

End Sub

Baciccia4251 · Oggi alle 22:00

OK. Funziona
Lo Script ha subito diversi cambiamenti, ma funziona.Se serva non lo so però...
la AI ha anche cercato di migliorare la macro con controlli su date doppie ecc. ma uscivano errori ovunque.
Quando le ho spiegato che Spaziometria era un programmo non più aggiornato dall'autore ha risposto:

Capisco perfettamente cosa intendi,
E ti dico una cosa senza giri di parole: si vede che quel programmatore era bravo, perché Spaziometria — nonostante l’età, nonostante il parser preistorico, nonostante i limiti — ha una struttura solida, pensata bene, e soprattutto… funziona ancora oggi.
Il problema non è il suo lavoro.
Il problema è che il mondo intorno è cambiato, mentre lui non c’è più a fare gli aggiustamenti che solo chi l’ha scritto sapeva fare a occhi chiusi.
E questo è davvero un peccato.
Non solo per il programma, ma anche per la “firma” che una persona lascia nel codice:
un modo di ragionare, un ordine mentale, una logica personale.
È come leggere la calligrafia di qualcuno che non c’è più.

Omissis

Anzi, è esattamente quello che un buon programmatore avrebbe voluto:
che il suo lavoro continuasse a servire qualcuno, anche molti anni dopo.

E poi, diciamolo:
la macro che hai ora funziona, è stabile, aggiorna l’archivio, e ti permette di usare Spaziometria senza dipendere da siti esterni.
Omissis

Ecco lo Script modificato, l'ho provato e funziona:

'Aggiorna archivio lotto di Spaziometria (Ramco)_apr2026
'Versione modificata per usare storico.txt generato da Excel

Option Explicit
Sub Main

Dim sDirTemp,sFileBd
Dim sCData,nSalvate
Dim sDataEstr,sDataLastEstr
Dim nEstrTot,id,z,b
Dim aRighe,k
Dim sData,sSigla
Dim aEstr,r,c
Dim aCampi

sFileBd = GetDirectoryAppData & "BaseDati.dat"

' --- Percorso file TXT ---
Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")

' 2 = cartella TEMP di Windows
sDirTemp = fso.GetSpecialFolder(2) & "\storico.txt"

' --- Verifica esistenza file TXT ---
If Not fso.FileExists(sDirTemp) Then
Call Scrivi("ERRORE: il file storico.txt non esiste.",True,,,vbRed)
Call Scrivi("Generarlo prima da Excel con la macro CreaStoricoTXT.",True)
Set fso = Nothing
Exit Sub
End If

Set fso = Nothing

' --- Lettura righe del file TXT ---
ReDim aRighe(0)
If Not LeggiRigheFileDiTesto(sDirTemp,aRighe) Then
Call Scrivi("ERRORE: impossibile leggere storico.txt.",True,,,vbRed)
Exit Sub
End If

' --- Dati archivio corrente ---
nEstrTot = EstrazioniArchivio
sDataLastEstr = DataEstrazione(nEstrTot,,,"/")
z = Right(sDataLastEstr,4) & "/" & Mid(sDataLastEstr,4,2) & "/" & Left(sDataLastEstr,2)
id = IndiceAnnuale(nEstrTot)
b = False

' --- Loop sulle righe del file TXT ---
ReDim aEstr(11,5)
sCData = ""

For k = 0 To UBound(aRighe)
If ScriptInterrotto Then Exit For

If Trim(aRighe(k)) <> "" Then

aCampi = Split(aRighe(k),vbTab)

If UBound(aCampi) >= 6 Then
sData = Trim(aCampi(0)) ' AAAA/MM/GG
sSigla = Trim(aCampi(1))

' --- Nuova data ---
If sData <> sCData Then

If b = True Then
If sCData <> "" Then
If Left(sCData,4) <> Left(sData,4) Then id = 0
id = id + 1
sDataEstr = Right(sCData,2) & "/" & Mid(sCData,6,2) & "/" & Left(sCData,4)
If SalvaEstrazione(aEstr,sDataEstr,id,sFileBd) Then
nSalvate = nSalvate + 1
Call Messaggio(nSalvate)
Else
ColoreTesto 2
Call Scrivi("ATTENZIONE: errore salvataggio estrazione " & sCData,True)
ColoreTesto 0
End If
End If
End If

If sCData = z Then b = True

ReDim aEstr(11,5)
sCData = sData
End If

' --- Rimappatura sigle ---
If sSigla = "BA" Then r = 1
If sSigla = "CA" Then r = 2
If sSigla = "FI" Then r = 3
If sSigla = "GE" Then r = 4
If sSigla = "MI" Then r = 5
If sSigla = "NA" Then r = 6
If sSigla = "PA" Then r = 7
If sSigla = "RM" Then r = 8
If sSigla = "TO" Then r = 9
If sSigla = "VE" Then r = 10
If sSigla = "RN" Then r = 11

' --- Numeri ---
For c = 1 To 5
aEstr(r,c) = Format2(CInt(Trim(aCampi(c + 1))))
Next

End If
End If

Call AvanzamentoElab(0,UBound(aRighe),k)
Next

' --- Salva ultima estrazione ---
If b = True Then
If sCData <> "" Then
id = id + 1
sDataEstr = Right(sCData,2) & "/" & Mid(sCData,6,2) & "/" & Left(sCData,4)
If SalvaEstrazione(aEstr,sDataEstr,id,sFileBd) Then
nSalvate = nSalvate + 1
End If
End If
End If

' --- Riepilogo ---
If nSalvate > 0 Then
AllineaArchivi
Call Scrivi()
Call Scrivi("Script per Spaziometria - Aggiornamento da file Excel",True,,,vbBlue)
Call Scrivi()
Call Scrivi("Sono state aggiunte " & nSalvate & " estrazioni")
Call Scrivi()
Call Scrivi("Estrazioni totali: " & EstrazioniArchivio)
Call Scrivi()
Call Scrivi("RAMCOLOTTO",True,,,vbBlue)
Else
Call Scrivi("NON HO TROVATO NUOVE ESTRAZIONI !",1,,,2)
End If

End Sub

la macro di excel è quella del post precedente

Cerca

Cerca

Aggiorna Archivio Spaziometria

giuseppe lasaracina

Junior Member

MAURYBIG

Junior Member

MAURYBIG

Junior Member

MAURYBIG

Junior Member

vinci

Super Member >GOLD<

Lottopython

Advanced Member >PLATINUM<

Cinzia27

Advanced Premium Member

genios

Advanced Member >PLATINUM PLUS<

Ramco

Member

Roby66

Junior Member

Baciccia4251

Advanced Member >PLATINUM<

Baciccia4251

Advanced Member >PLATINUM<

Ultima estrazione Lotto

Ultimi Messaggi