Aggiorna Archivio Spaziometria

[raflotto]

trovata un'altra 19/03/2026

 

[Ramco]

Ciao Raf, ti consiglio di scaricare l'archivio da Silop, e lo sostituisci nella giusta directory... poi aggiorni tranquillamente con lo script. Lo script in essere non modifica nessuna estrazione precedente, si limita alla verifica ed aggiorna...

 

[Reacher]

Si ti conviene sostituire con gli archivi aggiornati
Ma ho notato anche che hai la versione 1.6.34....aggiorna alla 1.6.54

 

[joe]

C'è chi utilizza, vecchi sistemi operativi (anche su macchine virtuali) e vecchie versioni di Spaziometria.

Spaziometria in particolare fu fatta quando il sistema operativo era XP, con il quale, oggi,

è complicato connettersi al web, i suoi siti ed utilizzare gli archivi da cui ricavare i dati per l'aggiornamento.

Sulle macchine virtuali, normalmente i dati ed i programmi, si rendono comuni al il Pc vero e proprio e quello Virtuale,

attraverso una cartella che è letteralmente condivisa dalle due "macchine" (di cui una è quella generata da Virtual-Box).

Dunque semplicemente trasferendo una copia dell'archivio BaseDati.dat dal Pc-Fisico alla cartella condivisa con il Pc-Virtuale,

si simula a tutti gli effetti il Download dal Web di questo File-Archivio (BaseDati.dat).

Trasferito, sovracrivendo, il vecchio archivio di Spaziometria si ha l'aggiornamento delle Estrazioni.

Dunque Spaziometria sarà funzionante con i vecchi sistemi operativi e con archivio aggiornato.



In questa immagine è dimostrato come si può utilizzare una vecchia versione di Spaziometria operante in Win XP,

Didimostra, allo stesso tempo, che si è potuto aggiornare l' Archivio, fino all'ultima estrazione effettuata.

 

[raflotto]

Buongiorno, adesso non sono a casa , stasera provo.
La cosa che non capisco come fanno ad uscire estrazioni che non esistono.
Comunque grazie per la risposta e complimenti per il lavoro che fate

 

[joe]

Analogamente a quanto è scritto nel messaggio #44,

se il file BaseDati.dat è nel Web ed è accessibile al PC (Host) in cui è presente la macchina virtuale,

dopo il download, si può trasferire, anche in questo caso l'Archivio alla cartella Condivisa.

poi dalla cartella condivisa alla DirctoryDati di Spaziometria così anche con questa seconda modalità,

si avrà l'aggiornamento per sostituzione dell'Archivio.

 

[raflotto]

Si ti conviene sostituire con gli archivi aggiornati
Ma ho notato anche che hai la versione 1.6.34....aggiorna alla 1.6.54

Ciao , ho anche questa di versione su un'altro pc.
Grazie per la risposta

 

[joe]

In ultimo wget permette (ancora) l'accesso ai dati del web, anche ai sistemi operativi più vecchi.

Tuttavia il supporto per XP è stato dismesso da qualche tempo.

Dunque si deve cercare l'ultima versione di Wget.exe compatibile (1.19.4).

Questo eseguibile deve essere messo nella cartella System e/o System32.

Per una maggiore compatibilità con i vecchi script anche nella DirecotryDati di Spaziometria,

come LuigiB lo ha aggiunto alle versioni più recenti di Spaziometria.

Cioè affiancare al sistema operativo di una versione di wget, funzionante e/o che era assente.

Con questa utility, gli script che contengono le istruzioni per utilizzare wget possono continuare ad aggiornare l'archivio.

 

[raflotto]

buonasera, ho aggiornato l'archivio di Silop con lo script di Ramco , adesso mi sembra corretto.
Grazie

 

[silop2005]

SPMT vers. 1.6.34_Agg.Web e relativo plugin SVP vers. 1.0.56 e Plugin_FTP vers. 1.0 e SpazioScript vs.1.0.9 e RicercaLunghetta vers.1.0.31 e LottoOpen v.1.0.62 e LottoProjeectLB.net V.1.0.38

======================

Per TUTTI ,

======================

OGNI FINE MESE SUL MIO SITO​

potete scaricare per il vostro programma Spaziometria by LuigiB

l'archivio intero del LOTTO classico (11 ruote),

l'archivio intero del SUPERENALOTTO

e lo script di RAMCO per aggiornare le estrazioni del lotto.

Vedi immagine e link:

==================== ==================================

==================================

Buon aggiornamenti a TUTTI.

Ringrazio per "i mi piace": bubù, dbr

==================== ==================================

Buon mercoledì a tutto il forum.

======================

A presto

Silop

 

[sogno]

Partendo dalle indicazioni di Joe, siamo arrivati a completare questo listato per l'aggiornamento archivio Lotto di Spaziometria.
Preleva l'archivio direttamente alla fonte Lottomatica, nella speranza sia stabile.
Tutelatevi sempre con un pre-salvataggio dell'archivio onde evitare inconvenienti.
E' testato con più pc, sperando di aver fatto cosa gradita.
PS: Per Silop, se poi lo vuoi caricare sul tuo sito rendendolo disponibile a tutti...

'Aggiorna archivio lotto di Spaziometria (Ramco)_apr2026
'estrazioni prelevate direttamente dalla fonte Lottomatica
Option Explicit
Sub Main
 Dim sDirTemp,sDirZip
 Dim sLink
 Dim sCData,nSalvate,sFileBd
 Dim sDataEstr,sDataLastEstr
 Dim nEstrTot,id,z,b
 Dim aRighe,k
 Dim sData,sSigla
 Dim aEstr,r,c
 Dim aCampi
 Dim sCmd,sDestDir
 Dim oShell,oFSO

 ' --- Percorsi file ---
   sFileBd = GetDirectoryAppData & "BaseDati.dat"
   sDirZip = GetDirectoryTemp & "storico.zip"
   sDirTemp = GetDirectoryTemp & "storico.txt"

   ' --- Pulizia file temporanei ---
   Call EliminaFile(sDirZip)
   Call EliminaFile(sDirTemp)

   ' --- Download dello zip ufficiale BrightStar/LottoItalia ---
   sLink = "https://www.brightstarlottery.it/STORICO_ESTRAZIONI_LOTTO/storico.zip"
   Call Messaggio("Download archivio ufficiale in corso...")

   If Not DownloadFromWeb(sLink,sDirZip) Then
      Call Scrivi("ERRORE: impossibile scaricare il file zip dal sito LottoItalia.",True,,,vbRed)
      Exit Sub
   End If

   ' --- Decompressione zip -> storico.txt tramite PowerShell ---
   Call Messaggio("Decompressione archivio...")

   sDestDir = GetDirectoryTemp
   ' Rimuove eventuale backslash finale per PowerShell
   If Right(sDestDir,1) = "\" Then sDestDir = Left(sDestDir,Len(sDestDir) - 1)
   sCmd = "powershell -NoProfile -Command ""Expand-Archive -Force -LiteralPath '" & sDirZip & "' -DestinationPath '" & sDestDir & "'"""
   Set oShell = CreateObject("WScript.Shell")
   Set oFSO = CreateObject("Scripting.FileSystemObject")
   oShell.Run sCmd,0,True
   Set oShell = Nothing

   If Not oFSO.FileExists(sDirTemp) Then
      Call Scrivi("ERRORE: il file storico.txt non trovato dopo la decompressione.",True,,,vbRed)
      Call Scrivi("Verificare che PowerShell sia disponibile e che lo zip contenga 'storico.txt'.",True)
      Set oFSO = Nothing
      Exit Sub
   End If
   Set oFSO = Nothing

   ' --- Lettura righe del file TXT ---
   ReDim aRighe(0)
   If Not LeggiRigheFileDiTesto(sDirTemp,aRighe) Then
      Call Scrivi("ERRORE: impossibile leggere storico.txt.",True,,,vbRed)
      Exit Sub
   End If
   Call EliminaFile(sDirZip)
   Call EliminaFile(sDirTemp)

   ' --- Dati archivio corrente ---
   nEstrTot = EstrazioniArchivio
   sDataLastEstr = DataEstrazione(nEstrTot,,,"/")
   ' sDataLastEstr e' in formato GG/MM/AAAA
   ' Convertiamo in AAAA/MM/GG per confronto con il file
   z = Right(sDataLastEstr,4) & "/" & Mid(sDataLastEstr,4,2) & "/" & Left(sDataLastEstr,2)
   id = IndiceAnnuale(nEstrTot)
   b = False

   ' --- Loop sulle righe del file ---
   ' Formato riga: AAAA/MM/GG [TAB] SIGLA [TAB] n1 [TAB] n2 [TAB] n3 [TAB] n4 [TAB] n5
   ' 11 righe consecutive con la stessa data = 1 estrazione
   ' Ordine sigle nel file: BA CA FI GE MI NA PA RM RN TO VE
   ' Ordine richiesto da Spaziometria (r=1..11): BA CA FI GE MI NA PA RO TO VE NZ
   ' Rimappatura necessaria: RM->r=8(RO), RN->r=11(NZ), TO->r=9, VE->r=10

   ReDim aEstr(11,5)
   sCData = ""

   For k = 0 To UBound(aRighe)
      If ScriptInterrotto Then Exit For

      ' Salta righe vuote
      If Trim(aRighe(k)) = "" Then
         ' Se avevamo una estrazione in corso con tutti i dati, la salviamo
      Else
         ' Splitta la riga per TAB
         aCampi = Split(aRighe(k),vbTab)

         If UBound(aCampi) >= 6 Then
            sData = Trim(aCampi(0)) ' AAAA/MM/GG
            sSigla = Trim(aCampi(1)) ' BA, CA, ... RM, RN, TO, VE

            ' --- Nuova data = nuova estrazione ---
            If sData <> sCData Then
               ' Salva l'estrazione precedente solo se b=True E non e' quella di z
               If b = True Then
                  If sCData <> "" Then
                     If Left(sCData,4) <> Left(sData,4) Then
                        id = 0
                     End If
                     id = id + 1
                     ' Converti sCData da AAAA/MM/GG a GG/MM/AAAA
                     sDataEstr = Right(sCData,2) & "/" & Mid(sCData,6,2) & "/" & Left(sCData,4)
                     If SalvaEstrazione(aEstr,sDataEstr,id,sFileBd) Then
                        nSalvate = nSalvate + 1
                        Call Messaggio(nSalvate)
                     Else
                        ColoreTesto 2
                        Call Scrivi("ATTENZIONE: errore salvataggio estrazione " & sCData,True)
                        ColoreTesto 0
                     End If
                  End If
               End If

               ' Se la data che STIAMO PER LEGGERE e' z, non ancora b=True
               ' b diventa True DOPO aver letto z, cioe' alla data successiva
               If sCData = z Then b = True

               ' Reset matrice per nuova data
               ReDim aEstr(11,5)
               sCData = sData
            End If

            ' --- Popola la riga corretta della matrice in base alla sigla ---
            ' Rimappatura sigle -> indice ruota Spaziometria
            If sSigla = "BA" Then r = 1
            If sSigla = "CA" Then r = 2
            If sSigla = "FI" Then r = 3
            If sSigla = "GE" Then r = 4
            If sSigla = "MI" Then r = 5
            If sSigla = "NA" Then r = 6
            If sSigla = "PA" Then r = 7
            If sSigla = "RM" Then r = 8 ' RM nel file = Roma = r=8 in Spaziometria
            If sSigla = "TO" Then r = 9
            If sSigla = "VE" Then r = 10
            If sSigla = "RN" Then r = 11 ' RN nel file = Nazionale = r=11 in Spaziometria

            ' Popola i 5 estratti (Format2 restituisce stringa a 2 cifre)
            For c = 1 To 5
               aEstr(r,c) = Format2(CInt(Trim(aCampi(c + 1))))
            Next
         End If
      End If

      Call AvanzamentoElab(0,UBound(aRighe),k)
   Next

   ' --- Salva l'ultima estrazione del file (se b=True) ---
   If b = True Then
      If sCData <> "" Then
         id = id + 1
         sDataEstr = Right(sCData,2) & "/" & Mid(sCData,6,2) & "/" & Left(sCData,4)
         If SalvaEstrazione(aEstr,sDataEstr,id,sFileBd) Then
            nSalvate = nSalvate + 1
         End If
      End If
   End If

   ' --- Riepilogo ---
   If nSalvate > 0 Then
      AllineaArchivi
      Call Scrivi()
      Call Scrivi("Script per Spaziometria - Aggiornamento da LottoItalia/BrightStar",True,,,vbBlue)
      Call Scrivi()
      Call Scrivi("Sono state aggiunte " & nSalvate & " estrazioni")
      Call Scrivi()
      Call Scrivi("Estrazioni totali: " & EstrazioniArchivio)
      Call Scrivi()
      Call Scrivi("Fonte: www.lotto-italia.it (archivio ufficiale BrightStar)")
      Call Scrivi()
      Call Scrivi("RAMCOLOTTO",True,,,vbBlue)
   Else
      Call Scrivi("NON HO TROVATO NUOVE ESTRAZIONI !",1,,,2)
   End If

End Sub

Buon mezzodi perche con riesco ad aggiornare le estrazioni seguendo le indicazioni date consigli suggerimenti

 

[Reacher]

Qual è l errore che ti appare?

 

[joe]

Ho provato questo script, adesso, e funziona.

Può dipendere dalla versione di Spaziometria che hai installato o da qualche altro problema.

Dovresti descrivere meglio cosa intendi con non funziona.

Cioè se avevi problemi con altri metodi ed anche questo fallisce.

Se funzionava e adesso non va più.

Eventualmente quali messaggi di errore ricevi o se apparentemente funziona ma poi non aggiorna ecc. ecc.