AMBETTI PER MIKE58

[trivellatomariotretre33]

CIAO MIKE58 POTRESTI REALIZZARE UNO SCRIPT CON TABBELLA
PER LE COMBINAZIONI DI AMBETTO PER SOLO AMBI
ESEMPIO
AMBO 1-90
COMBINAZIONI
1 89
90 2

AMBO 2-90
COMBINAZIONI
2 89 1
90 1 3

E COSI DI SEGUITO X TUTTI GLI AMBI GRAZIE DI CUORE

 

[Mike58]

Ciao amico Trivellato, uno script di tutti gli ambi per Ambetto è abbastanza complesso da gestire perché andrebbe ad analizzare tutti i possibili 4096 ambi generabili e le tabelle hanno un massimo di righe supportabili.

In effetti sono stato quello che ha chiesto a LuigiB di creare un codice vbscript per gestire la sorte Ambetto e aveva creato una funzione ad ok che legge tale procedura, ma ahinoi limitativa seppur efficace.

Tuttavia aveva creato oltre alla funzione anche uno script per leggere le Formazioni Registrate ed analizzarle per Ambetto.

Si possono registrare in formazioni registrate tutte le combinazioni che si vogliono analizzare e richiamarle con lo script.

Ti faccio un esempio.

Supponiamo di voler analizzare le combinazioni di decina per ambo
in formazione registrata formiamo delle combinazioni od ok

2.5.8
12.15.18
22.25.28
32.25.38

etc. etc.
in questo modo andremo ad analizzare gli ambetti che si possono formare con questi numeri capogiochi.

eccoti lo script.

Option Explicit
Sub Main
	Dim idEstr,Ruota
	Dim Inizio,Fine
	Dim nClasseFrz
	Dim id,k
	Dim nElemFrz
	Dim nQAmbetti
	Dim nEstrTot
	Dim nFrqMedia
	Dim sNomeFrz
	Inizio = EstrazioneIni
	Fine = EstrazioneFin
	Ruota = ScegliRuota
	nEstrTot =(Fine + 1) - Inizio
	ReDim aElemFormazione(0)
	Call RichiediFormazione(aElemFormazione,nClasseFrz,sNomeFrz)
	nElemFrz = UBound(aElemFormazione)
	ReDim aValStat(nElemFrz,4)
	' indice 0 il ritardo
	'        1 freq
	'        2 ritmax
	'        3 incr rit max
	'        4 presenze
	
	If Ruota > 0 And nClasseFrz > 1 Then
		For id = 1 To nElemFrz
			ReDim aNumInGioco(0)
			Call GetNumInGiocoFromElemFrz(id,aElemFormazione,aNumInGioco,nClasseFrz)
			For idEstr = Inizio To Fine
				' inserire qui il codice che analizza l'estrazione corrente
				nQAmbetti = VerificaAmbetto(aNumInGioco,Ruota,idEstr,"",0)
				If nQAmbetti > 0 Then
					aValStat(id,0) = 0
					aValStat(id,1) = aValStat(id,1) + nQAmbetti
					aValStat(id,3) = 0
					aValStat(id,4) = aValStat(id,4) + 1
				Else
					aValStat(id,0) = aValStat(id,0) + 1
					If aValStat(id,0) > aValStat(id,2) Then
						aValStat(id,2) = aValStat(id,0)
						aValStat(id,3) = aValStat(id,3) + 1
					End If
				End If
				If ScriptInterrotto Then Exit For
			Next
			Call AvanzamentoElab(1,nElemFrz,id)
			If ScriptInterrotto Then Exit For
		Next
		Dim aV
		aV = Array("","Formazione","Ritardo","Frequenza","RitardoMax","IncrRitMax","Presenze","I.C.")
		Call InitTabella(aV,2,,3,5)
		For id = 1 To nElemFrz
			ReDim aNumInGioco(0)
			Call GetNumInGiocoFromElemFrz(id,aElemFormazione,aNumInGioco,nClasseFrz)
			aV(1) = StringaNumeri(aNumInGioco)
			aV(2) = aValStat(id,0)
			aV(3) = aValStat(id,1)
			aV(4) = aValStat(id,2)
			aV(5) = aValStat(id,3)
			aV(6) = aValStat(id,4)
			nFrqMedia = Dividi(nEstrTot,aValStat(id,4))
			aV(7) = Round(Dividi(aValStat(id,0),nFrqMedia),3)
			Call AddRigaTabella(aV)
		Next
		
		Call Scrivi("Statistica_Ambetto",1,1,2,4,3)
		Call Scrivi("Analisi su formazione : " & sNomeFrz)
		Call Scrivi("Sulla ruota           : " & NomeRuota(Ruota))
		Call Scrivi("Da                    : " & GetInfoEstrazione(Inizio))
		Call Scrivi("A                     : " & GetInfoEstrazione(Fine))
		Call Scrivi("Totali range          : " & nEstrTot)
		Call Scrivi
		Call CreaTabella(2)
	End If
End Sub
Sub GetNumInGiocoFromElemFrz(id,aElemFormazione,aNumInGioco,nClasseFrz)
	Dim k
	ReDim aNumInGioco(nClasseFrz)
	For k = 1 To nClasseFrz
		aNumInGioco(k) = aElemFormazione(id,k)
	Next
End Sub
Sub RichiediFormazione(aElemFormazione,nClasseFrz,sNome)
	Dim s
	Dim n
	Dim id
	ReDim aNomiForm(0)
	Call ElencoFileInDirectory(GetDirectoryAppData & "formazioni\",aNomiForm,".frz")
	id = ScegliOpzioneMenu(aNomiForm,1,"Selezione formazione")
	If GetElementiFormazione(aNomiForm(id),aElemFormazione) Then
		nClasseFrz = GetClasseFormazione(aNomiForm(id))
		sNome = aNomiForm(id)
	End If
End Sub

Come dicevo sopre i codici sono limitati ma con un progetto ad ok si potrebbe anche creare qualcosa di diverso.

Ciao per adesso è questo che ti posso consigliare.

 

[trivellatomariotretre33]

grazie Mike58 gentile come sempre nell'attesa mi sbircio questo
pero sarebbe bello realizzare l'altro o quasi sempre di qualcosa che si rifferisce all'ambetto
ancora grazie
alla prossima ciao
se poi ci saranno novita' controllero' giornaliermente ancora grazie
ciao Mike58