"Evidenziare" Ricerca su estrazione/i

[Xeroxs]

Buongiorno a Tutti,
Volevo chiedere se qualcuno può aiutarmi a modificare un listato in modo da ottenere una cosa del genere ad esempio vorrei evidenziare a fianco delle estrazioni ad esempio la mia ricerca sulle terzine simmetriche, se trovato ambo riportare a fianco l'intera Terzina evidenziando in rosso il numero mancante

06.08.2020
Bari 17.88.49.90.62
Cagliari 39.59.66.24.21
Firenze 58.64.04.29.79 04.34.64 trovato ambo 64.04 scrivere in rosso il 34
Genova 58.11.19.35.04
Milano 38.12.70.04.19
Napoli 50.66.43.87.55
Palermo 25.22.52.62.05 22.52.82 trovato ambo 22.52 scrivere in rosso l 82
Roma 79.28.20.64.46
Torino 42.49.05.14.41
Venezia 24.73.22.46.19
Nazionale 58.76.81.64.59
------------------------
Se possibile mi piacerebbe colorare anche l'ambo nel quadro estrazionale

Ho visto in alcuni post che il bravo "Joe" lo esponeva per altre ricerche fatto in questo modo, a lui chiedo se vuole postare ciò che ha sviluppato per poterlo utilizzare per le mie ricerche..

Questo è il listato

Option Explicit
Sub Main
Dim Ini,Fin,Es,R,P,E(5)
Ini = EstrazioneFin - 3
Fin = EstrazioneFin
For Es = Ini To Fin
Scrivi DataEstrazione(Es),True
For R = 1 To 12 : If R = 11 Then R = 12
'For R = 1 To 10
Scrivi FormatSpace(NomeRuota(R),10),True,False
For P = 1 To(5)
E(P) = Format2(Estratto(Es,R,P))
Next
Scrivi StringaNumeri(E)
Next
Scrivi String(24,"-")
Next
End Sub


Spero nel vostro aiuto
Grazie come sempre.

 

[joe]

Ciao Xeroxs,

Negli anni ho già esaudito molte volte richieste identiche.

Sicché mi è più comodo e trovo più giusto evitare di dover rifare tutto dal principio.

Ultimamente sul sito di di Sean 69 trovi al post dal titolo "Linguaggio Lottoscript"

praticamente già fatto quanto hai chiesto.

 

[Xeroxs]

Grazie, vedrò
Sempre gentile

 

[Xeroxs]

Buongiorno a Tutti,
Ho cercato quanto proposto da Joe ed ho trovato il listato che rintraccia ambo simmetrico
Questo è il listato

Option Explicit
Sub Main
Dim Ini,Fin,Es,R,P,Q,E(5),D
Ini = EstrazioneFin - 9
Fin = EstrazioneFin
D = 30
For Es = Ini To Fin
Scrivi DataEstrazione(Es),True
For R = 1 To 12 : If R = 11 Then R = 12
'For R = 1 To 10
Scrivi FormatSpace(NomeRuota(R),10),True,False
For P = 1 To(5)
E(P) = Format2(Estratto(Es,R,P))
Next
Scrivi StringaNumeri(E) & " " & Space(1),False,False
OrdinaMatrice E,False
For P = 1 To 4
For Q = P + 1 To 5
If Distanza(E(P),E(Q)) = D Then
Scrivi E(P) & "." & E(Q) & Space(1),False,False,,2
End If
Next
Next
Scrivi ""
Next
Scrivi String(43,"-")
Next
End Sub

Poi ho studiato e cercato di capire come fare a riportare l'elemento mancante della terzina simmetrica
con una condizione IF cercando poi di riportare accanto ambo simmetrico trovato il numero mancante della terzina... ma dopo ore di tentativi sarà anche la poca concentrazione non capisco perchè non riporta il valore esatto
Questo è il listato che volevo correggere


Option Explicit
Sub Main
Dim Ini,Fin,Es,R,P,Q,E(5),D,N(2) ' Ho aggiunto N per Elemento mancante
Ini = EstrazioneFin - 4
Fin = EstrazioneFin
D = 30
For Es = Ini To Fin
Scrivi DataEstrazione(Es),True
For R = 1 To 12 : If R = 11 Then R = 12
Scrivi FormatSpace(NomeRuota(R),10),True,False
For P = 1 To(5)
E(P) = Format2(Estratto(Es,R,P))
Next
Scrivi StringaNumeri(E) & " " & Space(1),False,False
OrdinaMatrice E,False
For P = 1 To 4
For Q = P + 1 To 5
N(1) = Estratto(Es,R,P)
N(2) = Estratto(Es,R,Q)
If Distanza(E(P),E(Q)) = D Then
If Fuori90(N(1) + 30) = N(2) Then N(1) = Fuori90(N(1) + 60) Else N(1) = Fuori90(N(1) + 30) '------ Quì ho aggiunto per tovare elemnto mancante della Terzina
Scrivi E(P) & "." & E(Q) & Space(1),False,False,,2 ' Scrive l'ambo simmetrico Trovato
Scrivi " Elemento mancante: "& Format2(N(1)) ' Dovrebbe scrivere elemnto mancante - VOLEVO scriverlo a fianco dell'ambo trovato
End If
Next
Next
Scrivi ""
Next
Scrivi String(43,"-")
Next
End Sub


Qualcuno può aiutarmi a capire dove mi sono perso.
Non Pensate che mi voglio fissare su una cosa magari semplice sto cercando di imaparare e capire anche leggendo le guide proposte da claudio ma è ovvio che non posso assimilarle in breve tempo per questo se non è un problema a volte chiederò un Help per dritte o correzioni, e mi rendo conto delle difficolta che trovo, ma non voglio arrendermi.

Spero in un aiutino per arrivare al traguardo da me fissato.

 

[joe]

Scusa ma...

... ricordo di aver scritto quale è il terzo al fianco dell' ambo.

Inoltre quegli script sono corredati di tutte le spiegazioni.

Diciamola così hai 3 elementi ... li scrivi:

Scrivi e(p) &" " e(q) & " " & n(1).

Fine del problema.

 

[Xeroxs]

Grazi Joe appena rientro provo,
Hai ragione ben descritti i tuoi listati e sono utili per me capire, penso che la poca concentrazione non ha fatto capire la logica tra due e tre numeri.
Al rientro vedo è poi cerco di evidenziare il 3 elemento mancante....
Grazie ancora.

 

[salvo50]

Ciao a Tutti, se ci sono tutte e tre come si deve comportare lo script,
perchè ho modificato lo script, ma dove l'elemento mancante, non manca
ottengo questo

 

[Xeroxs]

Ciao, Salvo50
Questo è un bel dilemma, almeno per me, purtroppo rientro tardi e non ho modo di provare.
Io per quanto modesto il mio sapere in materia bisognerebbe forse con un if se la terzina è presente non la deve riportare in quanto lo scopo sarebbe rintracciare l elemento mancante di un ambo della terzina simmetrica se presente, ma non saprei come impostarlo se la terzina è presente.
Comunque grazie anche per il tuo contributo.

 

[Xeroxs]

che strano dal talete mi era sembrato di aver visto un riscontro di I-Legend ma non lo vedo più, ma forse mi sbaglio...

 

[joe]

Buona serata a tutte/i.

Effettivamente il Terzo Simmetrico da noi detto "mancante",

potrebbe (e può) essere "presente".

Non è un errore dello script considerare i 3 Ambi

perché in un Terno (se c'è un Terno) ci sono.

Se vogliamo dirla diversamente con una terzina di numeri,

si compongono 3 Ambi. E' giusto che siano 3.

Quello che manca è una descrizione del "cosa fare" ... in caso di ...

Ovvero, nel caso-raro in cui è presente una terzina simmetrica

tutta in una ruota.

Dopo aver deciso "cosa fare" si può agire traducendo

la decisione in istruzioni dello sript.

 

[Xeroxs]

Buongiorno a Tutti,
un grazie a Tutti per i vostri interventi
Ho corretto lo script ma ho un errore in out che non capisco dove è sbagliato visto che in alcuni valori è esatto ed in altri no.


Vedi sotto

18.07.2020
Bari 45.48.09.11.02
Cagliari 23.85.29.05.34
Firenze 60.34.84.66.70
Genova 42.44.04.62.32 32.62 Elemento mancante 74 (quì scrive 74 e non 2)

Milano 32.41.31.16.23
Napoli 02.73.34.29.90
Palermo 30.13.38.82.66
Roma 12.16.19.72.13 12.72 Elemento mancante 42 (giusto)

Torino 63.90.45.21.64
Venezia 45.50.80.43.55 50.80 Elemento mancante 20 (giusto)

Nazionale 13.81.66.47.25



25.07.2020
Bari 39.02.71.66.03
Cagliari 67.20.32.82.06
Firenze 02.41.14.17.61
Genova 90.28.01.69.10
Milano 69.40.64.58.12
Napoli 52.90.34.60.54 60.90 Elemento mancante 90 (Giusto)

Palermo 40.13.49.43.66 13.43 Elemento mancante 70 (Quì riporta 70 e non 73)

Roma 90.80.81.44.75
Torino 31.45.86.23.79
Venezia 52.33.84.42.56
Nazionale 49.25.19.07.17 19.49 Elemento mancante 49 (Giusto)

e poi dove rintraccia l'ambo simmetrico va a capo e si crea spazio con la ruota successiva


Chiedo a Salvo50 visto che hai corretto lo script (infatti i tuoi out sono corretti) se mi aiuti a capire e correggere lo script.
Anche gli altri se vogliono intervenire.

Grazie, come sempre.

 

[salvo50]

Ciao a Tutti.

Ciao Xeroxs, le variabili N(1) e N(2) che hai agginto e nel modo che le hai usate non sono altro che doppioni di E(P) ed E(Q), quindi l'elemento mancante non può essere N(1) oppure N(2), il FOR-NEXT che hai aggiunto lo puoi anche togliere, al posto di N(1) e N(2), puoi usare E(P) ed E(Q) che sono la stessa cosa, quindi devi aggiungere una variabile che deve rappresentare l'elemento mancante, io per esempio l'ho chiamata Manca, nuturalmente te puoi chiamarla come ti pare


nello spoiler ho messo come trovare l'elemento mancante

 

[joe]

In una frase del tipo:

Pierino mangia la mela.

Dobbiamo distinguere:

Il soggetto (Pierino)

Il verbo (mangia)

il complemento oggetto (la mela)

If Fuori90(N(1) + 30) = N(2) Then N(1) = Fuori90(N(1) + 60) Else N(1) = Fuori90(N(1) + 30) '------ Quì ho aggiunto per tovare elemnto mancante della Terzina

Il terzo non può essere contemporaneamente (oggetto e soggetto)

Non puoi scrivere IF (N(1) + 30) = N(2) .... then N(3) = ...

Se due numeri, sono N(1) e N(2)

n(3) ... non deve essere contemporaneamente "numero" e "risultato".

Osserva come nel mio script avevo chiamato E(P) E(Q) .... 2 dei 5 numeri.

Cioè avevo detto essere "E" i 5 (Numeri) Estratti.

In sintesi hai fatto un pasticciotto.

Le soluzioni sono alcune che incominciano con ... il correggi da te ...

riprendendo lo script che t'ho proposto e lo studi.

Focalizzando l'attenzione sul come "da 5 numeri" ... si sviluppano ... 10 Ambi.

Ovvero sul come distinguere quali sono i 5 Numeri e quali sono i 10 Ambi

e poi (NON ULTIMO) "come" memorizzare i risultati del calcolo del mancante.

Come nella grammatica ... se hai "DATO" un valore ai 5 soggetti n(1).. n(.5) su cui operare ...

N(3) è un "dato" e non un può essere "un risultato" che fai diventare (nuovamente) dato.

Perché così facendo ... N(3) = Fuori90 (N(1) + ... ) diventa essere un errore.

Non ultimo, avevo scritto di non usare quello script (perché è sbagliato) e di sostituirlo con quello pubblicato dopo.

Perché il "Format2" in esso presente trasforma il numero-estratto in una stringa di "2 CIFRE",

Stringa sulla quale i calcoli numerici (+30 / +60) potrebbero dare risultati sbagliati.

 

[Xeroxs]

Ok Joe Grazie,
ci provo

 

[joe]

Option Explicit
Sub Main
  Dim Ini,Fin,Es,R,P,Q,A,B,C ' A.B = Ambo Simmetrico / C = Elemento Mancante
  Ini = EstrazioneFin - 4
  Fin = EstrazioneFin
  For Es = Ini To Fin
    Scrivi DataEstrazione(Es),True
    For R = 1 To 12 : If R = 11 Then R = 12
      Scrivi FormatSpace(NomeRuota(R),10),True,False
      Scrivi StringaEstratti(Es,R) & " " & Space(1),False,False
      For P = 1 To 4
        A = Estratto(Es,R,P)
        For Q = P + 1 To 5
          B = Estratto(Es,R,Q)
          If Distanza(A,B) = 30 Then
            If Fuori90(A + 30) = B Then C = Fuori90(A + 60) Else C = Fuori90(A + 30) 'Calcolo Elemnto Mancante
            Scrivi Format2(A) & "." & Format2(B),False,False,,2 ' Scrive l'ambo simmetrico Trovato
            Scrivi " Elemento mancante: " & Format2(C),False,False 'Scrive Elemento Mancante
          End If
        Next
      Next
      Scrivi ""
    Next
    Scrivi String(53,"-")
  Next
End Sub

 

[Xeroxs]

Grazie Joe e Salvo sia per i consigli che per lo spingermi a fare le cose da solo e credetemi lo apprezzo molto, ho Visto che Joe ha postato lo script e che dire perfetto, intanto io mi ero spinto a correggere quanto da Voi esposto e rileggendo riga per riga ho capito in questa fase il mio " pasticciotto " ma direi anche peggio visto il tipo di errore che senza concentrazione ho fatto.

Quello di Joe è perfetto come sempre che dire se non bravo.

Io Ti scrivo il mio ricorretto e dà correttamente il risultato, ora spero di non aver sbagliato se ho ricorretto il listato che Joe diceva che

"Non ultimo, avevo scritto di non usare quello script (perché è sbagliato) e di sostituirlo con quello pubblicato dopo.

Perché il "Format2" in esso presente trasforma il numero-estratto in una stringa di "2 CIFRE",

Stringa sulla quale i calcoli numerici (+30 / +60) potrebbero dare risultati sbagliati."

ma a vedere come riporta i valori sembra giusto poi ditemi se sbaglio.

ora chiedo se è giusto quanto ho scritto oppure no, certamente sono in "working progress" ma se penso che qualche mese fa non sapevo leggerli nemmeno, per me sono passi enormi, molto distante da una autonomia ma qualche passo avanti penso di averlo fatto, ora devo abiutuarmi a scrivere listati fin dalla base di continuo, perchè solo così posso capire il vero linguaccio e farlo mio.


Option Explicit
Sub Main
Dim Ini,Fin,Es,R,P,Q,E(5),D,M
Ini = EstrazioneFin - 36
Fin = EstrazioneFin
D = 30
For Es = Ini To Fin
Scrivi DataEstrazione(Es),True
For R = 1 To 12 : If R = 11 Then R = 12
Scrivi FormatSpace(NomeRuota(R),10),True,False
For P = 1 To(5)
E(P) = Format2(Estratto(Es,R,P))
Next
Scrivi StringaNumeri(E) & " " & Space(1),False,False
OrdinaMatrice E,False
For P = 1 To 4
For Q = P + 1 To 5
If Distanza(E(P),E(Q)) = D Then
M = Fuori90(E(P) + D)
If M = CInt(E(Q)) Then M = Fuori90(E(P) + 2*D)
Scrivi E(P) & "." & E(Q) & " " & " Elemento mancante "& Format2(M) & " ",False,False,,0
End If
Next
Next
Scrivi ""
Next
Scrivi String(43,"-")
Next
End Sub



Grazie ancora Joe e Salvo50

 

[joe]

Lo script funziona bene.

PERO'

Format2 è una istruzione-utility finalizzata a far si che il numero sia sempre SCRITTO con 2 cifre.

Mentre a livello di calcolo 2+3=5 e non è utile fare in modo che sia "02+03=05".

Se non altro perché quando si leggono gli estratti essi sono moltissimi ...

mentre il Format2 è utile solo quando gli estratti vengono scritti.

E ... sono pochi i numeri da scrivere, a fronte dei molti che sono letti.

Quindi evitando il Fuori90 in lettura "E(P) = Fuori90( ..."si risparmiano moltissime operazioni inutili.

Esse essendo inutili, sono dannose, perché rallentano inutilmente lo script.

 

[Xeroxs]

Grazie ancora, Joe

 

[salvo50]

Grazie Joe, sapevo che format2 mette lo zero prima del numerino ma non sapevo che lo trasformasse in stringa,

If Fuori90(A + 30) = B Then C = Fuori90(A + 60) Else C = Fuori90(A + 30)

Anche questa riga per me è molto istruttiva, perchè fino a stamattina per trovare l'elemento mancante di una terna, ho sempre usato 4 IF-THEN, metodo scopiazzato da altri script.

 

[i legend]

Ciao
A=30
B=60
C=fuori90(a+30)
If c=b then c=fuori90(c+30)
Con un solo if
Indifferentemente che a sia > o < di b