listato manara

[fata65]

Fonte: (Metodo)
Lottologo: (Osvaldo Manara)
Nome: (Ambi Gi.Os)

Condizione in gioco:
1 Ruota
1 Ambate
2 Ambi

Gli ambi sui quali si basa la tecnica vale a dire gli ambi Gi.Os sono particolari tipi di ambi che hanno la caratteristica di avere tra gli elementi che li compongono una cifra vertice comune.

Il metodo è semplicissimo da applicare. Infatti, basta attendere la sortita di uno dei qualsiasi ambi Gi.Os su una ruota e sulla stessa ruota andremo a giocare i numeri corrispondenti. Per poter applicare la tecnica gli ambi Gi.Os da rintracciare dovranno essere uniti e i numeri che li formano non devono essere presenti su altre ruote. Per una maggiore comodità ho creato una tabella che racchiude tutti gli ambi Gi.Os con i relativi numeri da porre in gioco.

Voglio anticipare che per gli ambi 14-47 e 56-67 non è stata possibile l'elaborazione della previsione, pertanto la sortita di questi 2 ambi non mette in gioco nessuna previsione.

Partendo dal 1984 ho analizzato circa 1014 estrazioni. Si sono presentati 337 casi utili, il compendio statistico è il seguente:





Casi giocabili Ambate Ambi Esiti negativi Tot vincite
337 208 250 03 458

---------------------------TABELLA AMBI Gi.Os---------------------------
Ambo Gi.Os Capogioco Ambi in gioco


1°Ambo 2°Ambo
01 - 12 85 85-27 85-35
02 - 24 15 15-50 15-83
03 - 36 27 27-26 27-82
04 - 48 38 38-21 38-03
10 - 21 70 70-33 70-49
12 - 23 75 75-37 75-74
13 - 35 87 87-47 87-49
15 - 59 74 74-78 74-85
20 - 42 15 15-03 15-30
21 - 32 43 43-14 43-90
23 - 34 76 76-71 76-85
24 - 46 03 03-04 03-10
25 - 58 83 83-40 83-74
30 - 63 42 42-75 42-78
31 - 53 55 55-23 55-01
32 - 43 15 15-58 15-46
34 - 45 80 80-07 80-81
35 - 57 13 13-08 13-31
36 - 69 42 42-01 42-84
40 - 84 28 28-22 28-40
41 - 74 23 23-49 23-74
42 - 64 57 57-47 57-07
43 - 54 12 12-09 12-86
45 - 56 85 85-40 85-32
46 - 68 39 39-55 39-73
52 - 85 81 81-17 81-16
53 - 75 31 31-63 31-03
54 - 65 12 12-61 12-67
57 - 79 32 32-60 32-10
64 - 86 56 56-79 56-64
65 - 76 41 41-13 41-04
67 - 78 54 54-27 54-48
78 - 89 36 36-74 36-90

 

[fata65]

si puo creare uno script

 

[LuigiB]

nel periodo che dice lui ovviamente i risultati sembrano entusiasmanti , invece facendo la prova con le ultime 1000 estrazioni si va in perdita ...

Option Explicit
Class clsAmboGiOs
	Public aNumAmbo(90)
	Public aAmbata(1)
	Public aAmbo1(2)
	Public aAmbo2(2)
End Class
Sub Main
	Dim collAmbi
	Dim idEstr
	Dim Inizio,Fine
	Dim nDurata
	nDurata = 10
	Inizio = EstrazioneIni
	Fine = EstrazioneFin
	Set collAmbi = GetNewCollection
	Call InitAmbiGiOs(collAmbi)
	For idEstr = Inizio To Fine
		ReDim aEstr(11,5)
		If GetEstrazioneCompleta(idEstr,aEstr) Then
			Call CercaAmbiEGioca(collAmbi,aEstr,idEstr,nDurata)
		End If
		Call AvanzamentoElab(Inizio,Fine,idEstr)
		If ScriptInterrotto Then Exit For
	Next
	Call ScriviResoconto
End Sub
Sub InitAmbiGiOs(collAmbi)
	Call AddAmbo(collAmbi,"01 - 12 85 85-27 85-35")
	Call AddAmbo(collAmbi,"02 - 24 15 15-50 15-83")
	Call AddAmbo(collAmbi,"03 - 36 27 27-26 27-82")
	Call AddAmbo(collAmbi,"04 - 48 38 38-21 38-03")
	Call AddAmbo(collAmbi,"10 - 21 70 70-33 70-49")
	Call AddAmbo(collAmbi,"12 - 23 75 75-37 75-74")
	Call AddAmbo(collAmbi,"13 - 35 87 87-47 87-49")
	Call AddAmbo(collAmbi,"15 - 59 74 74-78 74-85")
	Call AddAmbo(collAmbi,"20 - 42 15 15-03 15-30")
	Call AddAmbo(collAmbi,"21 - 32 43 43-14 43-90")
	Call AddAmbo(collAmbi,"23 - 34 76 76-71 76-85")
	Call AddAmbo(collAmbi,"24 - 46 03 03-04 03-10")
	Call AddAmbo(collAmbi,"25 - 58 83 83-40 83-74")
	Call AddAmbo(collAmbi,"30 - 63 42 42-75 42-78")
	Call AddAmbo(collAmbi,"31 - 53 55 55-23 55-01")
	Call AddAmbo(collAmbi,"32 - 43 15 15-58 15-46")
	Call AddAmbo(collAmbi,"34 - 45 80 80-07 80-81")
	Call AddAmbo(collAmbi,"35 - 57 13 13-08 13-31")
	Call AddAmbo(collAmbi,"36 - 69 42 42-01 42-84")
	Call AddAmbo(collAmbi,"40 - 84 28 28-22 28-40")
	Call AddAmbo(collAmbi,"41 - 74 23 23-49 23-74")
	Call AddAmbo(collAmbi,"42 - 64 57 57-47 57-07")
	Call AddAmbo(collAmbi,"43 - 54 12 12-09 12-86")
	Call AddAmbo(collAmbi,"45 - 56 85 85-40 85-32")
	Call AddAmbo(collAmbi,"46 - 68 39 39-55 39-73")
	Call AddAmbo(collAmbi,"52 - 85 81 81-17 81-16")
	Call AddAmbo(collAmbi,"53 - 75 31 31-63 31-03")
	Call AddAmbo(collAmbi,"54 - 65 12 12-61 12-67")
	Call AddAmbo(collAmbi,"57 - 79 32 32-60 32-10")
	Call AddAmbo(collAmbi,"64 - 86 56 56-79 56-64")
	Call AddAmbo(collAmbi,"65 - 76 41 41-13 41-04")
	Call AddAmbo(collAmbi,"67 - 78 54 54-27 54-48")
	Call AddAmbo(collAmbi,"78 - 89 36 36-74 36-90 ")
End Sub
Sub AddAmbo(collAmbi,sRiga)
	Dim aNumeri
	Dim cAmbo
	If GetNumeriRiga(sRiga,aNumeri) Then
		Set cAmbo = New clsAmboGiOs
		cAmbo.aNumAmbo(aNumeri(1)) = True
		cAmbo.aNumAmbo(aNumeri(2)) = True
		cAmbo.aAmbata(1) = aNumeri(3)
		cAmbo.aAmbo1(1) = aNumeri(4)
		cAmbo.aAmbo1(2) = aNumeri(5)
		cAmbo.aAmbo2(1) = aNumeri(6)
		cAmbo.aAmbo2(2) = aNumeri(7)
		collAmbi.add cAmbo
	End If
End Sub
Function GetNumeriRiga(sRiga,aNumeri)
	Dim k,i,sTmp,sChr
	ReDim aNumeri(0)
	sTmp = ""
	i = 0
	For k = 1 To Len(sRiga)
		sChr = Mid(sRiga,k,1)
		If IsNumeric(sChr) Then
			sTmp = sTmp & sChr
		Else
			If sTmp <> "" Then
				If Int(sTmp) > 0 And Int(sTmp) <= 90 Then
					i = i + 1
					ReDim Preserve aNumeri(i)
					aNumeri(i) = Int(sTmp)
				End If
			End If
			sTmp = ""
		End If
	Next
	If sTmp <> "" Then
		If Int(sTmp) > 0 And Int(sTmp) <= 90 Then
			i = i + 1
			ReDim Preserve aNumeri(i)
			aNumeri(i) = Int(sTmp)
		End If
	End If
	If i = 7 Then
		GetNumeriRiga = True
	End If
End Function
Sub CercaAmbiEGioca(collAmbi,aEstr,idEstr,nDurata)
	Dim r,rr,p,e
	Dim bGioca,nGioc
	Dim cAmbo
	ReDim aPosteAmbata(1)
	ReDim aPosteAmbo(2)
	ReDim aRuote(1)
	
	
	aPosteAmbata(1) = 1
	aPosteAmbo(2) = 1
	nGioc = 0
	For r = 1 To 11
		For Each cAmbo In collAmbi
			p = 0
			ReDim aNumAmbo(2)
			For e = 1 To 5
				If cAmbo.aNumAmbo(aEstr(r,e)) Then 
					p = p + 1
					aNumAmbo(p) =aEstr(r,e)
				End If
			Next
			If p = 2 Then
				If IsAmboUnito(aEstr,r,aNumAmbo) Then
					bGioca = True
					For rr = 1 To 11
						If rr <> r Then
							p = 0
							For e = 1 To 5
								If cAmbo.aNumAmbo(aEstr(rr,e)) Then p = p + 1
							Next
						End If
						If p > 0 Then bGioca = False
					Next
					If bGioca Then
					
					
						aRuote(1) = Iif(r = 11,12,r)
						nGioc = nGioc + 1
						Call ImpostaGiocata(nGioc,cAmbo.aAmbata,aRuote,aPosteAmbata,nDurata,1,,1)
						nGioc = nGioc + 1
						Call ImpostaGiocata(nGioc,cAmbo.aAmbo1,aRuote,aPosteAmbo,nDurata,2,,1)
						nGioc = nGioc + 1
						Call ImpostaGiocata(nGioc,cAmbo.aAmbo2,aRuote,aPosteAmbo,nDurata,2,,1)
						
						Call Scrivi (StringaEstratti (idEstr ,Iif(r=11,12,r)),True)
						Call Scrivi ("Ambo rilevato " & StringaNumeri(aNumAmbo),True)
						Call Gioca(idEstr)
					End If
				End If
			End If
		Next
	Next
	
End Sub
Function IsAmboUnito(aEstr,r,aNumAmbo)
	Dim k 
	For k = 1 To 4
		If aEstr(r,k)=aNumAmbo(1) Or aEstr(r,k)=aNumAmbo(2) Then
			If aEstr(r,k+1)=aNumAmbo(1) Or aEstr(r,k+1)=aNumAmbo(2) Then
				IsAmboUnito = True
				Exit Function 
			End If 

		End If 
	Next
	
End Function

 

[fata65]

Grazie luigi infatti non ci sono grandi risultati