Pe il gentilissimo Luigi

[solare]

Ciao Luigi, scusami se ti chiedo questa soluzione, questo listato che tu mi ai fatto presenta un problema e cioè con l'avanzare delle estrazioni non cambia il range di statistica in output esempio se avvio ho un range attuale 8382-8399 (cicli da 18) questo resta uguale anche inserendo altre estrazioni.
Inoltre ti chiedo sempre se puoi inserire la possibilità di selezionare il periodo dei cicli, es. cicli da 18, 9, oppure 10.
Grazie
Sub Main
Dim TipoArc
Dim nCicli
Dim Inizio,Fine
Dim idEstr
Dim idDecina
Dim sErr
Dim nTotale
ReDim aNum(10)
ReDim aRuote(1)



nCicli = Int(InputBox("Inserire il numero dei cicli da 18",,10))
TipoArc = ScegliArchivio
Inizio =(EstrazioniArchivioDL -(nCicli * 18)) + 1
Fine = EstrazioniArchivioDL - 17



If nCicli > 0 And Inizio > 0 And TipoArc > 0 Then

Call ImpostaArchivio10ELotto(TipoArc)

For idDecina = 1 To 9
nTotale = 0
Call AlimentaNumeri(idDecina,aNum)
ReDim aTitoli(2)
aTitoli(1) = " Range "
aTitoli(2) = " Frequenza "
Call InitTabella(aTitoli)
For idEstr = Inizio To Fine Step 18
ReDim aValori(2)
aValori(1) = CStr(idEstr) & " - " & CStr(idEstr + 17)
aValori(2) = SerieFreqDL(idEstr,idEstr + 17,aNum,1)
nTotale = nTotale + CLng(aValori(2))
Call AddRigaTabella(aValori)
Next
ReDim aValori(2)
aValori(1) = "Totale"
aValori(2) = nTotale
Call AddRigaTabella(aValori,vbYellow)


Call Scrivi("Decina analizzata " & StringaNumeri(aNum))

Call Scrivi

Call CreaTabella
Next
Else
If nCicli <= 0 Then
sErr = "Numero di cicli non valido"
End If
If Inizio <= 0 Then
sErr = "Troppi cicli rispetto alle estrazioni del range"
End If
If idDecina <= 0 Then
sErr = "Nessuna decina selezionata"
End If
If TipoArc <= 0 Then
sErr = "Specificare quale archivio 10 e lotto"
End If


MsgBox sErr,vbCritical
End If
End Sub
Function ScegliDecina()
ReDim aVoci(8)
Dim k,i
For k = 1 To 81 Step 10
aVoci(i) = "Decina " & k & " - " & k + 9
i = i + 1
Next
ScegliDecina = ScegliOpzioneMenu(aVoci,0,"Selezione decina") + 1
End Function
Sub AlimentaNumeri(idDecina,aNum)
Dim i,k,y
i =((idDecina - 1) * 10) + 1
For k = i To(i - 1) + 10
y = y + 1
aNum = k
Next
End Sub
Function ScegliArchivio()

ReDim aVoci(1)

aVoci(0) = "Dieci e lotto"
aVoci(1) = "Dieci e lotto 5 min"


ScegliArchivio = ScegliOpzioneMenu(aVoci,0,"Selezione archivio") + 1
End Function

 

[solare]

Decina analizzata 71.72.73.74.75.76.77.78.79.80

Range Frequenza 8229 - 8238 23 8247 - 8256 18 8265 - 8274 16 8283 - 8292 19 8301 - 8310 20 8319 - 8328 18 8337 - 8346 28 8355 - 8364 19 8373 - 8382 18 8391 - 8400 27 Totale 206

I valori riportati sopra dopo aver avviato il listato con nuove estrazioni del 10elotto ogni 5 minuti non cambiano le frequenze delle decine del periodo analizzato.

 

[LuigiB]

Scusa ma dopo aver aggiornato le estrazioni lo modifichi il range di analisi ?

 

[solare]

Scusami ma non riesco a capire quale range devo impostare, visto che quando avvii la schermata relativa all'eventuale caricamento degli script l'unica possibilità di selezionare il range è relativo al gioco del lotto e non al 10elotto ogni 5 minuti.
Forse sbaglio io ma non capisco dove..
Grazie

 

[LuigiB]

prova con questo altro script, a me funziona

Sub Main
	Dim TipoArc
	Dim nCicli
	Dim Inizio,Fine
	Dim idEstr
	Dim idDecina
	Dim sErr
	Dim nTotale
	ReDim aNum(10)
	ReDim aRuote(1)
	nCicli = Int(InputBox("Inserire il numero dei cicli da 18",,10))
	TipoArc = ScegliArchivio
	Call ImpostaArchivio10ELotto(TipoArc)
	Inizio =(EstrazioniArchivioDL -(nCicli * 18)) + 1
	Fine = EstrazioniArchivioDL - 17
	If nCicli > 0 And Inizio > 0 And TipoArc > 0 Then
		
		For idDecina = 1 To 9
			nTotale = 0
			Call AlimentaNumeri(idDecina,aNum)
			ReDim aTitoli(2)
			aTitoli(1) = " Range "
			aTitoli(2) = " Frequenza "
			Call InitTabella(aTitoli)
			For idEstr = Inizio To Fine Step 18
				ReDim aValori(2)
				aValori(1) = CStr(idEstr) & " - " & CStr(idEstr + 17)
				aValori(2) = SerieFreqDL(idEstr,idEstr + 17,aNum,1)
				nTotale = nTotale + CLng(aValori(2))
				Call AddRigaTabella(aValori)
			Next
			ReDim aValori(2)
			aValori(1) = "Totale"
			aValori(2) = nTotale
			Call AddRigaTabella(aValori,vbYellow)
			Call Scrivi("Decina analizzata " & StringaNumeri(aNum))
			Call Scrivi
			Call CreaTabella
		Next
	Else
		If nCicli <= 0 Then
			sErr = "Numero di cicli non valido"
		End If
		If Inizio <= 0 Then
			sErr = "Troppi cicli rispetto alle estrazioni del range"
		End If
		If idDecina <= 0 Then
			sErr = "Nessuna decina selezionata"
		End If
		If TipoArc <= 0 Then
			sErr = "Specificare quale archivio 10 e lotto"
		End If
		MsgBox sErr,vbCritical
	End If
End Sub
Function ScegliDecina()
	ReDim aVoci(8)
	Dim k,i
	For k = 1 To 81 Step 10
		aVoci(i) = "Decina " & k & " - " & k + 9
		i = i + 1
	Next
	ScegliDecina = ScegliOpzioneMenu(aVoci,0,"Selezione decina") + 1
End Function
Sub AlimentaNumeri(idDecina,aNum)
	Dim i,k,y
	i =((idDecina - 1) * 10) + 1
	For k = i To(i - 1) + 10
		y = y + 1
		aNum(y) = k
	Next
End Sub
Function ScegliArchivio()
	ReDim aVoci(1)
	aVoci(0) = "Dieci e lotto"
	aVoci(1) = "Dieci e lotto 5 min"
	ScegliArchivio = ScegliOpzioneMenu(aVoci,0,"Selezione archivio") + 1
End Function

 

[solare]

Ciao Luigi, ti ringrazio come sempre della tua disponibilità
gratuita.....sei grande
Comunque tutto OK