Per Joe o chi è capace

[solare]

Ciao, avrei bisogno una modifica a questo listato:
In pratica all'avvio mi dovrebbe dare la possibilità di elaborare: quanti anni e quale mese
Grazie infinite

Option Explicit

Sub Main
'Archivio per Trivellato
' Script By Joe
   Dim Ini,Fin,IdEstr,R,P,sEstr,sChr_Num,sChr_Col
   sChr_Num = "."
   sChr_Col = Chr(32)
   Call ScegliRange(Ini,Fin,EstrazioneIni,EstrazioneFin)
   Call ResetTimer
   For IdEstr = Fin To Ini Step - 1
      Call AvanzamentoElab(Ini,Fin,IdEstr)
       sEstr = Data(IdEstr) & sChr_Col
      For R = 1 To 12
         If R = 11 Then R = 12
         ReDim aEstr(0)
         Call GetArrayNumeriRuota(IdEstr,R,aEstr)
         For P = 1 To 5
            sEstr = sEstr & CStr(Format2(aEstr(P)))
            If P < 5 Then sEstr = sEstr & sChr_Num
         Next
         sEstr = sEstr & sChr_Col
      Next
      Scrivi sEstr
   Next
End Sub

Function Data(Es)
   Dim D,M
   D = DataEstrazione(Es)
   M = Mese(Es)
   Data = Left(D,2) & Space(1) & Left(MeseNome(M),3) & Space(1) & Anno(Es)
End Function

 

[trivellatomariotretre33]

CIAO BUONGIORNO A JOE E TUTTI , DAVVERO AI AVUTO UN INTUIZIONE CHE POTREBBE DARE BUONI FRUTTI SPERIAMO CHE RIESCANO IN QUESTA MODIFICA . O JOE O ALTRI GRAZIE.

 

[Master]

Ciao
Provate questa soluzione

Option Explicit


Sub Main
   'Archivio per Trivellato
   ' Script By Joe modificato per solare scelta anni e mese By Master
   Dim Ini,Fin,IdEstr,R,P,sEstr,sChr_Num,sChr_Col
   Dim Mes,AnIni,AnFin
   sChr_Num = "."
   sChr_Col = Chr(32)
   Mes = CInt(InputBox("Inserisci MESE di ricerca","MESE",1))
   AnIni = CInt(InputBox("Inserisci  ANNO INIZIO ricerca","ANNO",2015))
   AnFin = CInt(InputBox("Inserisci  ANNO FINE ricerca","ANNO",2019))
   'Call ScegliRange( Ini,Fin,EstrazioneIni,EstrazioneFin)
   Ini = EstrazioneIni
   Fin = EstrazioneFin
   Call ResetTimer
   For IdEstr = Fin To Ini Step - 1
      If Mese(IdEstr) = Mes And Anno(IdEstr) >= AnIni And Anno(IdEstr) <= AnFin Then
         Call AvanzamentoElab(Ini,Fin,IdEstr)
         sEstr = Data(IdEstr) & sChr_Col
         For R = 1 To 12
            If R = 11 Then R = 12
            ReDim aEstr(0)
            Call GetArrayNumeriRuota(IdEstr,R,aEstr)
            For P = 1 To 5
               sEstr = sEstr & CStr(Format2(aEstr(P)))
               If P < 5 Then sEstr = sEstr & sChr_Num
            Next
            sEstr = sEstr & sChr_Col
         Next
         Scrivi sEstr
      End If
   Next
End Sub
Function Data(Es)
   Dim D,M
   D = DataEstrazione(Es)
   M = Mese(Es)
   Data = Left(D,2) & Space(1) & Left(MeseNome(M),3) & Space(1) & Anno(Es)
End Function

 

[claudio8]

x Solare,
una curiosità
a cosa ti servono le estrazioni che estrapoli?

 

[joe]

Ciao Claudio.

Se ricordo bene mi aveva richiesto di poter avere un archivio

per un programma che necessitava di quel formato specifico.

Excel o qualcosa di simile con le sole estrazioni di un determinato mese.

Lo script originale oltre fare quanto richiesto, ha in più la possibilità,

di poter scegliere ANCHE porzioni di mese, in ranghi più flessibilmente modulabili.

Per esempio:

Le estrazioni avvenute nel mese di novembre nelle ultime 1000 Estrazioni.

Per il resto vi si possono applicare tutte le normali ricerche, statistiche e metodi,

che diverranno mensilmente orientate.

 

[solare]

Ciao Master, perfetto
grazie infinite