Novità

Estrazione del Lotto

Su LottoCED puoi seguire le estrazioni del lotto in diretta tra

Ricerca Spia su Una Di Due Ruote o Entrambe

Xeroxs

Super Member >PLATINUM<
Buongiorno a Tutti,
Incuriosi da un video visto su Youtube volevo testarne gli esiti cosi ho ripreso uno Script che avevo fatto per altri metodi, ma non riesco ad imporre di trovare la spia voluta o sulla Ruota r1 o la ruota r2 o (presente su Entrambe)
Nell' esempio reale vorrei imporre di cercare sulla Ruota Di Genova o Torino la presenza della spia 12 ( La Spia può essere presente anche su una sola Ruota o Genova o Torino)
Trovata la condizione impongo la Giocata, Non pensavo di avere delle difficolta invece non riesco ad imporre la ricerca della condizione, nemmeno con degli If o sugli estratti o sulle Ruote, ho cercato anche di incastrare la ricerca ruote ed estratti ma nulla sempre cose strane nell'elaborazione.
Ho cercato se esistessero degli script che avessero questo tipo di condizione ma ho solo visto che la spia era sempre presente su entrambe le ruote di ricerca...

Vi posto lo script sperando come sempre in un vostro intervento per aiutarmi a risolvere l'arcano.

Codice:
Option Explicit
Sub Main()
   Dim r1,r2,ruote(2),p1,p2,A,B
   Dim Ambata(2),posta(1),Clp
   Dim Ini,Fin,Es,QE,K,Spy
   posta(1) = 1
   Spy = CInt(InputBox("Inserisci il numero spia",,12))
   QE = InputBox(" Quante estrazioni vuoi controllare? ","",50)
   Clp = InputBox("per quanti colpi?","colpi di gioco",4)
   Ini = EstrazioneFin - QE
   Fin = EstrazioneFin
   For Es = Ini To Fin
      Messaggio "elab. estr. [" &(Es) & "] di " & DataEstrazione(Es,1)
      Call AvanzamentoElab(Ini,Fin,Es)
      '------------------------------------------------------ Ruote Di Ricerca Della Spia
      r1 = GE_
      r2 = TO_
            For p1 = 1 To 5
               For p2 = 1 To 5
                  A = Estratto(Es,r1,p1)
                  B = Estratto(Es,r2,p2)
                  '--------------------------------------------- Creo le Condizioni per la Ricerca Del Numero Spia
                  If A = Spy And A = B Then
                  ' Test
                  'If A = Spy And A <> B Then
                  'If A And B = Spy Then
                  'If A Or B = Spy Then
                     '-----------------------------------------------
                        ColoreTesto 1 : K = K + 1 : Scrivi String(96,"*") & " Caso n°" & Format2(K),1
                        Scrivi
                        'Scrivi DataEstrazione(Es) & " " & SiglaRuota(r1) & " " & StringaEstratti(Es,r1) & " Spia [" & Format2(Spy) & "]",1
                        Scrivi DataEstrazione(Es,1) & " [ " & SiglaRuota(r1) & " - " & StringaEstratti(Es,r1) & _
                        " ]   [ " & Format2(A) & " ]" & " Pos " & Format2(p1)
                        Scrivi DataEstrazione(Es,1) & " [ " & SiglaRuota(r2) & " - " & StringaEstratti(Es,r2) & _
                        " ]   [ " & Format2(B) & " ]" & " Pos " & Format2(p2)
                        Scrivi : ColoreTesto 0
                        '----------------------------------------------------------------------------- Ruote Di Gioco
                        ruote(1) = BA_
                        ruote(2) = NA_
                        '----------------------------------------------------------------------------- Ambata
                        Ambata(1) = Fuori90(Estratto(Es,NA_,3) + 29)
                        'Ambata(2) = 90
                        '
                        ImpostaGiocata 1,Ambata,ruote,posta,Clp,1
                        Gioca Es,1
                  End If
               Next
            Next
         Next
      Scrivi
   'Scrivi String(88,"*") & " Casi trovati : " & Format2(K),1,,,7
   'ColoreTesto 2
   'Scrivi" casi trovati : " & K,1
   ColoreTesto 0
   ScriviResoconto
End Sub

Grazie Come sempre
 

salvo50

Advanced Member >PLATINUM PLUS<
Ciao a Tutti.

Ciao Xeroxs, in questa riga

If A = Spy And A = B Then

invece di And, devi mettere OR
If A = Spy Or B = Spy Then

And = ci devono essere tutti e due

Or = uno oppure l'altro o tutti e due

Xor = uno oppure l'altro, ma non tutti e due
 
Ultima modifica:

Xeroxs

Super Member >PLATINUM<
Ciao, e Grazie Salvo50,
Ho provato questa Soluzione ma mi riscrive più volte la condizione cambiando l estratto della ruota, forse devo trovare il modo di scrivere la condizione, ma non comprendo perchè genera questo errore
 

salvo50

Advanced Member >PLATINUM PLUS<
Oltre a mettere Or devi cambiare anche la seconda parte
If A = Spy Or B = Spy Then

B = Spy non A = B
 

Xeroxs

Super Member >PLATINUM<
Ciao, Purtroppo anche così
If A = Spy Or B = Spy Then
me ne scrive sempre cinque estrazioni e deve solo una, davvero non comprendo il perchè... 😭 😭 😭 😭
 

salvo50

Advanced Member >PLATINUM PLUS<
Credevo che il problema fosse solo quello della condizione
 
Ultima modifica:

Xeroxs

Super Member >PLATINUM<
In Pratica quello della condizione dovrebbe essere Giusto, ma se lascio A= B stampa corretto ma volendo solo su una delle due Ruote Stampa come ho riportato di Seguito, Mannaggia Ci sto provando in mille modi, Se fosse un Ciclo For mi darebbe errore anche come era in Origine...
MaH...

************************************************************************************************ Caso n°01

23.07.2020 GE 35.46.32.19.84 Spia [12]

Estrazione generatrice del pronostico 09798 [ 70 - 23/07/2020]
G 0001 Numeri in gioco : 54 su BA NA per Estratto

V N. [54 ] [NA] [.. .. .. .. 54] C. 1 Estratto 09799 [ 71 - 25/07/2020]
Interrotta per esito verificato

************************************************************************************************ Caso n°02

23.07.2020 GE 35.46.32.19.84 Spia [12]

Estrazione generatrice del pronostico 09798 [ 70 - 23/07/2020]
G 0001 Numeri in gioco : 54 su BA NA per Estratto

V N. [54 ] [NA] [.. .. .. .. 54] C. 1 Estratto 09799 [ 71 - 25/07/2020]
Interrotta per esito verificato

************************************************************************************************ Caso n°03

23.07.2020 GE 35.46.32.19.84 Spia [12]

Estrazione generatrice del pronostico 09798 [ 70 - 23/07/2020]
G 0001 Numeri in gioco : 54 su BA NA per Estratto

V N. [54 ] [NA] [.. .. .. .. 54] C. 1 Estratto 09799 [ 71 - 25/07/2020]
Interrotta per esito verificato

************************************************************************************************ Caso n°04

23.07.2020 GE 35.46.32.19.84 Spia [12]

Estrazione generatrice del pronostico 09798 [ 70 - 23/07/2020]
G 0001 Numeri in gioco : 54 su BA NA per Estratto

V N. [54 ] [NA] [.. .. .. .. 54] C. 1 Estratto 09799 [ 71 - 25/07/2020]
Interrotta per esito verificato

************************************************************************************************ Caso n°05

23.07.2020 GE 35.46.32.19.84 Spia [12]

Estrazione generatrice del pronostico 09798 [ 70 - 23/07/2020]
G 0001 Numeri in gioco : 54 su BA NA per Estratto

V N. [54 ] [NA] [.. .. .. .. 54] C. 1 Estratto 09799 [ 71 - 25/07/2020]
Interrotta per esito verificato



17.09.2020 GE 71.11.62.85.12 Spia [12]

Estrazione generatrice del pronostico 09822 [ 94 - 17/09/2020]
G 0001 Numeri in gioco : 16 su BA NA per Estratto

V N. [16 ] [NA] [.. .. .. 16 ..] C. 2 Estratto 09824 [ 96 - 22/09/2020]
Interrotta per esito verificato

************************************************************************************************ Caso n°07
 

salvo50

Advanced Member >PLATINUM PLUS<
Ho dato un'occhiata, e mi sembra normale che lo fa 5 volte, nel ciclo for p2, gli dici di giocare sempre lo stesso numero

Ambata(1) = Fuori90(Estratto(Es,NA_,3) + 29)

dopo 5 colpi cambia perche cambia Es, ma la ruota è sempre Napoli, posizione sempre 3, più sempre 29,

il numero di Napoli cambia, quando cambia l'estrazione
 

Master

Advanced Member >GOLD<
Ciao
Questa è una delle possibili soluzioni
sostituisci queste righe e remma la secoda ruota


'------------------------------------------------------ Ruote Di Ricerca Della Spia
'r1 = GE_
'r2 = TO_
For r1 = 1 To 10
For p1 = 1 To 5
'For p2 = 1 To 5
A = Estratto(Es,r1,p1)
'B = Estratto(Es,r2,p2)

'--------------------------------------------- Creo le Condizioni per la Ricerca Del Numero Spia
If r1 = GE_ And A = Spy Or r1 = TO_ And A = Spy Then


' Test
'If A = Spy And A <> B Then
'If A And B = Spy Then
'If A Or B = Spy Then
 

i legend

Advanced Member >PLATINUM PLUS<
Ciao Controlla che funzioni ,
Codice:
Option Explicit
' NOTA BENE:
' controllare se lo script fa quanto richiesto
' non si escludono possibili ed eventuali bugs
Sub Main
   Dim Ini,Fin,IdEstr,m,idCs,sVal
   Dim R,p,E,aSpia,nPres
   ReDim aRuote(0),aIdEstr(0),aRit(0)
   Call ScegliRuote(aRuote)
   If Not ValidaRicercaRuota(aRuote,sVal) Then
      Scrivi sVal
      Exit Sub
   End If
   ' seleziono i dati in Input
   Call ScegliRange(Ini,Fin,EstrazioneIni,EstrazioneFin)
   If Ini < 1 Or Fin > EstrazioneFin Then
      Scrivi " Range Data non Valido"
      Exit Sub
   End If
   Call Scegli_N_Spia(aSpia)
   If Not isNumeroValidoLotto(aSpia(1)) Then
      Scrivi "IL numero selezionato non è valido"
      Exit Sub
   End If
   nPres = ScegliPresenzaSpia(UBound(aRuote))
   If nPres < 1 Then
      Scrivi " numero minimo di presenze non valido non Valido"
      Exit Sub
   End If
   Call ElencoRitardiTurbo(aSpia,aRuote,1,Ini,Fin,aRit,aIdEstr)
   ' testo in output
   Scrivi " Inizio Ricerca:      ",1,0,RGB(200,200,200)
   Scrivi "  " & Ini,1,,,RGB(0,128,192),3
   Scrivi " Fine Ricerca:        ",1,0,RGB(200,200,200)
   Scrivi "  " & Fin,1,,,RGB(0,128,192),3
   Scrivi " Estratto Spia:       ",1,0,RGB(200,200,200)
   Scrivi "  " & StringaNumeri(aSpia,,1),1,,,RGB(0,128,192),3
   Scrivi " Ruote di Ricerca:    ",1,0,RGB(200,200,200)
   Scrivi "  " & StringaRuote(aRuote),1,,,RGB(0,128,192),3
   Scrivi
   Scrivi FormatSpace(" La spia deve essere presente almeno su  " & nPres & "  delle ruote selezionate ",194),1,,vbRed,vbWhite
   Scrivi
   ' inizio ricerca
   idCs = 0
   For IdEstr = 1 To UBound(aIdEstr) - 1
      m = 0
      ' cerco se il numero minimo di presenze è rispettatto
      For R = 1 To UBound(aRuote)
         If Posizione(aIdEstr(IdEstr),aRuote(R),aSpia(1)) Then m = m + 1
      Next
      If m >= nPres Then
         idCs = idCs + 1
         Scrivi FormatSpace(idCs,5,1),1,0,RGB(220,220,220)
         Scrivi " | ",1,0
         Scrivi " " & GetInfoEstrazione(aIdEstr(IdEstr)) & " ",1,0,RGB(210,249,176),RGB(63,122,10)
         Scrivi " | ",1,0
         For R = 1 To UBound(aRuote)
            Scrivi "  " & FormatSpace(NomeRuota(aRuote(R)),10),1,0,RGB(220,220,220)
            Scrivi " | ",1,0,,,3
            For p = 1 To 5
               E = Estratto(aIdEstr(IdEstr),aRuote(R),p)
               If E = aSpia(1) Then
                  Scrivi " " & Format2(E) & " ",1,0,RGB(210,249,176),RGB(63,122,10)
               Else
                  Scrivi " " & Format2(E) & " ",1,0
               End If
            Next
            Scrivi" | ",1,0
         Next
         Scrivi
         Call AvanzamentoElab(Ini,Fin,aIdEstr(IdEstr))
         If ScriptInterrotto Then Exit For
      End If
   Next
End Sub
Sub Scegli_N_Spia(aSpia)
   Dim aE(89)
   Dim e,n
   ReDim aSpia(1)
   For e = 0 To 89
      aE(e) = e + 1
   Next
   aSpia(1) = ScegliOpzioneMenu(aE,0,"Seleziona Numero Spia ") + 1
End Sub
Function ValidaRicercaRuota(aRuote,sVal)
   Dim R,bRet
   If UBound(aRuote) Then
      bRet = True
      For R = 1 To UBound(aRuote)
         If aRuote(R) = 11 Then
            bRet = False
            sVal = "Hai selezionato la ruota tutte"
            Exit For
         End If
      Next
   Else
      sVal = " non hai selezionato alcuna ruota"
   End If
   ValidaRicercaRuota = bRet
End Function
Function ScegliPresenzaSpia(ubAr)
   ReDim aV(ubAr - 1)
   Dim i
   For i = 0 To UBound(aV)
      aV(i) = i + 1
   Next
   ScegliPresenzaSpia = ScegliOpzioneMenu(aV,0,"Numero minimo di presenze") + 1
End Function
 

Xeroxs

Super Member >PLATINUM<
Ciao, a Tutti
Che Dire, Un Grazie di Cuore a Tutti
Salvo50, Master, Claudio8 ed I-legend
Posso dire che Ogni Vostro Intervento è stato Utile per Spingermi a trovare comunque anche per Conto mio la soluzione anche se alla Fine quaesta volta senza il vostro intervento la vedevo Dura,
Grazie Salvo50, mi hai aiutato tanto nel capire che gli If conviene bene studiarli bene pezzo per pezzo, altrimenti non ci sarei arrivato,
Grazie Master Con la parte da Te Proposta lo script funziona come dovrebbe, vedo poi se trovo altre soluzioni ma solo per capire vie alternative che mi aiuteranno in futuro, analizzerò bene quanto da Te postato, infatti mi scrive anche come nell'ultimo caso due righe di estrazione ma perchè la spia è presente su Genova e Torino.
Grazie Anche a Te Claudio, Che comunque mi hai spinto a veder meglio i vari cicli For
Grazie anche a Te I-Legend che posso dire Un Ottimo Script per prendere Spunti per la ricerca di Spie con presenze multiple.
Scusatemi se non Vi Ho risposto subito perchè preso dalla ricerca della soluzione.

Grazie Ancora a Tutti Voi.
 

Master

Advanced Member >GOLD<
Ciao a tutti

E' giusto quello che dici,
nell'estrazione del 17/9 e del 5/11 le giocate sono doppie perchè la spia è uscita su tutte e due le ruote
in questi casi c'è anche la soluzione per eliminare la doppia giocata
momentaneamente non l'ho inserita per non confonderti le idee..
buona domenica
 

i legend

Advanced Member >PLATINUM PLUS<
Ciao, contento che funzioni.
Nello script ,ci sono soluzioni veloci ed esempi di formattazione particolari, che mi sembra siano interesse di studio per te.
Dagli script di qualche decina di anni fa, dove chi sapeva listare erano pochissimi, oggi grazie a LuigiB si possono realizzare output che non hanno nulla da invidiare a form di un software .
Anche la logica e gli algoritmi di ricerca si sono evoluti.
Se ti interessa imparare per te , e non semplicemente per realizzare listato per i tuoi amici, ( c è anche chi arrotonda lo stipendio cosi) , ti consiglio di leggere i post di luigi.
Non troverai maestro migliore.
Io purtroppo, visto il lavoro fisicamente faticoso, e tutti i dolori che mi comporta, non ho più neanche la voglia o la capacità di trovare soluzioni interessanti , ma in passato mi sono davvero divertito tantissimo ad imparare e a cercare di passare quel poco che ho imparato.😁
Importantissimo per me :

1)Usare sempre option explicit

2)Dichiarare le variabili

3) non scrivere più comandi sulla stessa linea . Non serve a nulla e complica la vita a chi scrive e a chi legge. Mai giocare a chi ha lo script più corto 🤣🤣🤣🤣

4) pensare sempre ad una soluzione elegante e veloce.

5) il punto 4perché chi legge e vuole imparare prende gli script come esempi.

6) RINGRAZIARE LUIGIB CHE HA RESO POP LA PROGRAMMAZIONE 👍
 

i legend

Advanced Member >PLATINUM PLUS<
Grazie salvo .
Fa piacere vedere i tuoi pollicioni in su .
Se posso permettermi, credo tu abbia eguagliato se non superato chi all inizio del tuo percorso ha cercato di darti qualche suggerimento 👍.
Questo è nell ordine delle cose ed è giusto che sia così.
 

Xeroxs

Super Member >PLATINUM<
Grazie I-Legend
Userò i tuoi consigli davvero preziosi, hai ragione su tutto, faccio script anche per me trovando anche soluzioni che molti programmi non fanno, Sto studiando alcuni vostri script perché li ritengo giustamente preziosi, sono ancora indietro su alcune cose, ma credo di essere molto migliorato almeno per tutti quelli basilari, e mi piace molto imparare, lo script da Te postato davvero ottimo per imparare, io sono arrivato qui, da 1 anno direi e purtroppo mi sono perso molti dei vostri script e dei vostri consigli, e direi che il lavoro fatto da Luigi per questo programma non l ho mai visto neanche in altri campi.
Grazie come sempre
 

Ultima estrazione Lotto

  • Estrazione del lotto
    giovedì 21 gennaio 2021
    Bari
    18
    43
    19
    69
    15
    Cagliari
    17
    27
    61
    09
    76
    Firenze
    69
    63
    81
    26
    61
    Genova
    89
    36
    07
    81
    66
    Milano
    39
    82
    74
    12
    40
    Napoli
    07
    53
    05
    73
    88
    Palermo
    27
    58
    08
    52
    19
    Roma
    17
    38
    39
    40
    29
    Torino
    66
    90
    17
    74
    29
    Venezia
    08
    12
    88
    40
    87
    Nazionale
    71
    21
    54
    79
    77
    Estrazione Simbolotto
    Bari
    38
    04
    36
    33
    01
Alto