UNA RICERCA CHE POTREBBE APRIRE NUOVI ORIZZONTI!!!

[mazuma]

CIAO

Il script funziona. Quella riga non centra niente. Deve impostare a 50 il range dell archivio.

Un saluto a tutti.

 

[Baffoblu]

quote:Originally posted by rob

HO FATTO ESATTAMENTE COME MI HAI SUGGERITO PERO' PURTROPPO SI INTERROMPE E MI DA QUESTO ERRORE!!

Lo script inizia con la "O" di Option Explicit

e finisce con la "n" di End Function

Non ci deve essere nulla di aggiunto ne prima ne dopo.


lo script va copiato tutto in ogni sua parte senza omettere nulla.

Non mettete un range di estrazioni troppo elevato, perchè vi si potrebbe impallare, dandovi la sensazione che sia bloccato e molto probabilmente darvi anche errore.

 

[bigalbe]

quote:Originally posted by bigalbe

A me da sempre questo errore a prescindere dal range impostato (anche 5 estrazioni).

A fine elaborazione appare questa box:

clsTableHtmLd.CreaTabella
13 - Type mismatch

se poi clicco su OK appare la schermata dell'output vuota.



Versione di Spaziometria installata 1.3.9

bigalbe

Raqazzi a me lo script gira senza problemi, ma alla fine mi da l'errore descirtto sopra.

bigalbe

 

[bergie]

 

[LuigiB]

ciao Ragazzi quella riga che dite voi serve per il precalcolo dei ritardi non è il range da analizzare.

Hanno detto bene Mazuma e Bergie !

 

[LuigiB]

Ciao , questo script fa la stessa cosa ma è piu veloce ,
inoltre nel precedente c'era un errore sulal ruota nazionale, lo cancello per non fare confusione.

P.S.
Con questo script non c'è limite sulle estrazioni da analizzare, dipende solo dalla velocità del pc

Option Explicit
Dim aEstrRit()
Dim aColori()
Dim nLenRiga
Dim nIdPrimaEstr

Sub Main
	Dim Inizio,Fine
	Dim r,k,e,i
	Dim RitDelRit,FreqDelRit
	  
	Dim sRiga
	Dim nCol
	Dim aR(1)
	Dim aN(1)
	Inizio = EstrazioneIni
	Fine = EstrazioneFin
	ReDim aEstrRit(EstrazioniArchivio,12,5)
	Call InitAlimentaTabella
	
	ReDim FreqDelRit(12,250)
	Call Messaggio("Calcolo tabella ritardi")
	nIdPrimaEstr  = Inizio -200
	nIdPrimaEstr = CInt(InputBox("Inserire la prima estrazione dalla quale conteggiare i ritardi (per default è 200 estrazioni indietro rispetto all'inizio range in analisi)" ,"Prima estrazione" ,nIdPrimaEstr  ))
	
	If nIdPrimaEstr  <=0 Then nIdPrimaEstr  = 1
	
	For k = nIdPrimaEstr  To Inizio - 1
		For r = 1 To 12
			If r <> 11 Then
				aR(1) = r
				For e = 1 To 5
					aN(1) = Estratto(k,r,e)
					aEstrRit(k,r,e) = RitardoCombinazione(aR,aN,1,k - 1)
					If aEstrRit(k,r,e) > 250 Then aEstrRit(k,r,e) = 250
					FreqDelRit(r,aEstrRit(k,r,e)) = FreqDelRit(r,aEstrRit(k,r,e)) + 1
				Next
			End If
		Next
		Call AvanzamentoElab(nIdPrimaEstr  ,Inizio - 1,k)
		If ScriptInterrotto Then Exit Sub
	Next
	Call Messaggio("Analisi range in corso...")
	For k = Inizio To Fine
		ReDim aRigaNumeri(57)
		ReDim aRigaRitardi(57)
		ReDim aRigaRitardiDei(57)
		ReDim aRigaFrequenzaDei(57)
		aRigaNumeri(1) = DataEstrazione(k)
		aRigaNumeri(2) = k
		aRigaRitardi(1) = "Rit"
		aRigaRitardiDei(1) = "RitDeiRit"
		aRigaFrequenzaDei(1) = "FrqRit"
		nCol = 2
		For r = 1 To 12
			If r <> 11 Then
				aR(1) = r
				For e = 1 To 5
					nCol = nCol + 1
					aN(1) = Estratto(k,r,e)
					aEstrRit(k,r,e) = RitardoCombinazione(aR,aN,1,k - 1)
					RitDelRit = GetRitardoDelRitardo(aEstrRit(k,r,e),k - 1,r)
					If aEstrRit(k,r,e) > 250 Then aEstrRit(k,r,e) = 250
					FreqDelRit(r,aEstrRit(k,r,e)) = FreqDelRit(r,aEstrRit(k,r,e)) + 1
					aRigaNumeri(nCol) = aN(1)
					aRigaRitardi(nCol) = aEstrRit(k,r,e)
					aRigaRitardiDei(nCol) = RitDelRit
					aRigaFrequenzaDei(nCol) = FreqDelRit(r,aEstrRit(k,r,e))
				Next
			End If
		Next
		Call Scriviriga(aRigaNumeri ,DataEstrazione( k) , k)
		Call Scriviriga(aRigaRitardi, "Ritardi" ,"")
		Call Scriviriga(aRigaRitardiDei , "RitDeiRit","" )
		Call Scriviriga(aRigaFrequenzaDei , "FreqDeiRit","")
		sRiga = String(nLenRiga,"-")
		Call Scrivi(sRiga)
	
		
		Call AvanzamentoElab(Inizio,Fine,k)
		If ScriptInterrotto Then Exit For
	Next
	
End Sub
Sub InitAlimentaTabella()
	Dim sRiga
	Dim r
	nLenRiga = 11 + 5 +(29*11)+ (11*3) + 1
	sRiga = String(nLenRiga,"-")
	Call Scrivi(sRiga)
	sRiga = "|" & FormatSpace("Data",10) & "|"
	sRiga = sRiga & FormatSpace("Id",4) & "|"
	For r = 1 To 12
		If r <> 11 Then
			sRiga = sRiga & " " & FormatSpace(NomeRuota(r),28) & "|*|"
		End If
	Next
	Call Scrivi(sRiga)
	sRiga = String(nLenRiga,"-")
	Call Scrivi(sRiga)
End Sub
Sub  Scriviriga(aRiga ,  sData  , Id  )
	Dim sRiga
	Dim r , e , nCol
	
	
	sRiga = "|" & FormatSpace(sData,10) & "|"
	sRiga = sRiga & FormatSpace(Id,4,True ) & "|"
	nCol = 2
	For r = 1 To 12
		If r <> 11 Then
			For e = 1 To 5
				nCol = nCol +1 
				sRiga = sRiga & FormatSpace(aRiga (nCol),5 ,True) & "|"
			Next
			sRiga = sRiga & "*|"
		End If
	Next
	Call Scrivi (sRiga)
	
End Sub 

Function GetRitardoDelRitardo(RitDaEsaminare,IdEstr,ruota)
	Dim k,e,b
	Dim RitDelRit
	RitDelRit = 0
	b = False
	For k = IdEstr To  nIdPrimaEstr Step - 1
		For e = 1 To 5
			If aEstrRit(k,ruota,e) = RitDaEsaminare Then
				b = True
				Exit For
			End If
			
		Next
		
		If b Then Exit For
		RitDelRit = RitDelRit + 1
	Next
	GetRitardoDelRitardo = RitDelRit
End Function

 

[Baffoblu]

quote:Originally posted by Baffoblu

quote:Originally posted by rob

HO FATTO ESATTAMENTE COME MI HAI SUGGERITO PERO' PURTROPPO SI INTERROMPE E MI DA QUESTO ERRORE!!

Lo script inizia con la "O" di Option Explicit

e finisce con la "n" di End Function

Non ci deve essere nulla di aggiunto ne prima ne dopo.


lo script va copiato tutto in ogni sua parte senza omettere nulla.

Non mettete un range di estrazioni troppo elevato, perchè vi si potrebbe impallare, dandovi la sensazione che sia bloccato e molto probabilmente darvi anche errore.

 

[LuigiB]

rob ho modificato lo script ..prova l'ultima versione che ho postato

 

[bigalbe]

Ho modificato il range estrazioni nella finestra principale del programma.
Ora funziona tutto regolarmente.
Grazie.

bigalbe

 

[LuigiB]

Big , usa il nuovo script che ho postato , l'altro cancellalo

 

[claudio8]

quote:Originally posted by rob

CIAO RAGA'...MI PIACEREBBE MOLTO SE QUALCHE SCRIPTER VOLENTEROSO REALIZZASSE UNO SCRIPT CHE PERMETTA DI STABILIRE UN
CERTO NUMERO DI ESTRAZIONI RETROATTIVE E CHE POI FACCIA UN'ANALISI DI TUTTE LE CINQUINE SORTITE CALCOLANDO IL RITARDO CRONOLOGICO (DI
OGNI SINGOLO NUMERO CHE FORMA LA CINQUINA IN ESAME)
POI PER FARE UN BEL LAVORO CI VORREBBE UNA TABELLA RIASSUNTIVA CHE INDICHI PER OGNI RITARDO LA RELATIVA FREQUENZA E IL RELATIVO RITARDO--->
ES. IL RITARDO 23 E' USCITO 24 VOLTE ED HA UN RITARDO DI 51 ESTRAZIONI</u>

E VIA DICENDO!!-MA A COSA SERVIREBBE TUTTO CIO'??-SICURAMENTE E' UNA NUOVA ED INEDITA RICERCA STATISTICA UTILE AD ANALIZZARE E
STUDIARE COME SI FORMANO LE CINQUINE DA QUALI RITARDI SPECIFICI SONO FORMATE!!-SE C'E' QUALCUNO CHE VOGLIA REALIZZARLO LO RINGRAZIO
IN ANTICIPO!!-GRAZIE ROB

lo ho riscritto perchè così è possibile leggerlo tutto d'un fiato

Lo spot che conosciamo dice "Ti Piace vincere facile ? " .. io rispondo SI !!!"

 

[rob]

LUIGI HAI FATTO UN LAVORO FANTASTICO,SOPRATUTTO NON HO MAI VISTO UNO SCRIPT COSI' ORDINATO!!-COMPLIMENTI DAVVERO E UN RINGRAZIAMENTO A TUTTI QUELLI CHE SONO INTERVENUTI!!

-SALUTI ROB