Novità

Estrazione del Lotto

Su LottoCED puoi seguire le estrazioni del lotto in diretta tra

Voglio fare un regalo a tutti .

genios

Advanced Member >GOLD<
Vediamo se chi voleva farci un regalo ha ragione . Scripter Il Santo Natale è vicino e non possiamo festeggiarlo come sempre tramutate per favore questo regalo in script.

Ciao Eugenio img20201124_12455502.jpg
 

Giggio

Super Member >PLATINUM<
Caro Genios io aggiungo un regalo pure da parte mia...

lo script procede cosi :
-per ogni estrazione individua la prima ruota dove ci sono 2 e soltanto 2 tra le formazioni delle decine naturali che siano entro i limiti del ritardo previsto
- dalla lungetta piu ritardata prende i prim 7 numeri piu recenti
-dalla lunghetta meno ritardata prende i primi 6 numeri piu recenti
- li unisce a farli diventare una lunghett a da 13
- verifica i risultati di gioco.
- passa alla prossima estrazione.


questo in teoria .. bisogna vedere se da dati esatti ...

Ciao ...



Codice:
Option Explicit
Class clsRuota
   Private m_CollFormazioni
   Private m_Ruota
   Sub Class_Initialize
      Set m_CollFormazioni = GetNewCollection
   End Sub
   Public Property Let Ruota(v)
      m_Ruota = v
   End Property
   Public Property Get Ruota
      Ruota = m_Ruota
   End Property
   Public Property Get CollFormazioni
      Set CollFormazioni = m_CollFormazioni
   End Property
   Public Property Set CollFormazioni(NewValue)
      m_CollFormazioni = NewValue
   End Property
   Sub AddFormazione(cFrz)
      m_CollFormazioni.Add cFrz
   End Sub
End Class
Class clsFormazione
   Private aNum
   Private mRitardo
   Sub SetNumeri(sNum)
      Dim av,k,e
      ReDim aNum(90)
      av = Split(sNum,";")
      For k = 0 To UBound(av)
         If isNumeroValidoLotto(Int(av(k))) Then
            e = e + 1
            aNum(e) = Int(av(k))
         End If
      Next
      ReDim Preserve aNum(e)
   End Sub
   Sub CalcRitardi(Ruota,idEstr,nSorte)
      ReDim aR(1)
      aR(1) = Ruota
      mRitardo = RitardoCombinazioneTurbo(aR,aNum,nSorte,idEstr)
   End Sub
   Sub PrendiNumeriPiuRecenti(nQuantita,aRetNum,idPrimoElem,idEstr,Ruota , bDettagli )
      Dim k
      ReDim aE(10,2)
      For k = 1 To 10
         aE(k,1) = aNum (k)
         aE(k,2) = RitardoEstrattoTurbo(aNum(k),idEstr,Ruota)
      Next
      Call OrdinaMatrice(aE,1,2)
     
      If bDettagli  Then
         For k  =1 To 10
           
            If k <= nQuantita Then
                Scrivi Format2(aE (k,1))  & " Rit : " & aE(k,2) ,True
            Else
                Scrivi Format2(aE (k,1))  & " Rit : " & aE(k,2) ,False
          
          
            End If
         Next
      End If
     
      
     
      For k = 1 To nQuantita
         aRetNum((idPrimoElem - 1) + k) = aE(k,1)
      Next
   End Sub
   Sub ScriviNumeri
      Call Scrivi (StringaNumeri ( aNum )  & " Rit : " & mRitardo ) 
   End Sub
   Public Property Get Ritardo
      Ritardo = mRitardo
   End Property
End Class
Sub Main
   Dim CollRuote
   Dim idEstr,RitMin,RitMax
   Dim cFrz1,cFrz2
   Dim nSorte
   Dim RuotaDiGioco
   Dim aRegistro
   Dim nTotCasi , nTotVincenti
   Dim nUltima
   Dim bDettagli 
  
   ReDim aQPerEsito (5)
   
   
   If MsgBox  ("MOSTRARE I DETTAGLI DELLE LUNGHETTE GIOCATE CON LE FORMAZONI SCELTE E GLI ESITI ?"  , vbQuestion + vbYesNo ) = vbYes Then
      bDettagli = True
     
   End If
   
   nSorte = 2
   RitMin = 27
   RitMax = 36
   Call AlimentaCollRuote(CollRuote)
   Call AlimentaRegistro (aRegistro )
  
   For idEstr = EstrazioneIni To EstrazioneFin
      Call CalcolaRitardi(CollRuote,idEstr,nSorte)
      If TrovaFormazioniDaGiocare(CollRuote,cFrz1,cFrz2,RitMin,RitMax,RuotaDiGioco) Then
         Call GiocaLunghetta(cFrz1,cFrz2,RuotaDiGioco,idEstr,RuotaDiGioco,nSorte,aRegistro ,nTotCasi , nTotVincenti , aQPerEsito ,bDettagli  )
      End If
      Call AvanzamentoElab(EstrazioneIni,EstrazioneFin,idEstr)
      nUltima  = idEstr
      If ScriptInterrotto Then Exit For
   Next
  
   Call ScriviRegistro (aQPerEsito   , aRegistro ,nTotCasi , nTotVincenti ,EstrazioneIni , nUltima    )
End Sub
Sub  AlimentaRegistro (aRegistro )
   ReDim aRegistro (5 ,3)
  
   aRegistro (1 ,1)=1 :aRegistro (1 ,2) = 3
   aRegistro (2 ,1)=4 :aRegistro (2 ,2) = 5
   aRegistro (3 ,1)=6 :aRegistro (3 ,2) = 7
   aRegistro (4 ,1)=8 :aRegistro (4 ,2) = 10
   aRegistro (5 ,1)=11 :aRegistro (5 ,2) = 10000000
  
  

  
  

End Sub
Sub AlimentaCollRuote(CollRuote)
   Dim r
   Dim cFrz,cRuota
   Set CollRuote = GetNewCollection
   For r = 1 To 12
      If r <> 11 Then
         Set cRuota = New clsRuota
         cRuota.Ruota = r
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("1;2;3;4;5;6;7;8;9;10")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("11;12;13;14;15;16;17;18;19;20")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("21;22;23;24;25;26;27;28;29;30")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("31;32;33;34;35;36;37;38;39;40")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("41;42;43;44;45;46;47;48;49;50")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("51;52;53;54;55;56;57;58;59;60")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("61;62;63;64;65;66;67;68;69;70")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("71;72;73;74;75;76;77;78;79;80")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("81;82;83;84;85;86;87;88;89;90")
         Call cRuota.AddFormazione(cFrz)
         CollRuote.Add cRuota
      End If
   Next
End Sub
Sub CalcolaRitardi(collRuote,idEstr,nSorte)
   Dim cRuota,cFrz
   For Each cRuota In collRuote
      For Each cFrz In cRuota.CollFormazioni
         Call cFrz.CalcRitardi(cRuota.Ruota,idEstr,nSorte)
      Next
   Next
End Sub
Function TrovaFormazioniDaGiocare(CollRuote,cFrz1,cFrz2,RitMin,RitMax,RuotaDiGioco)
   Dim cRuota,cFrz
   Dim nTrovate
   For Each cRuota In CollRuote
      nTrovate = 0
      For Each cFrz In cRuota.CollFormazioni
         If cFrz.Ritardo >= RitMin And cFrz.Ritardo <= RitMax Then
            nTrovate = nTrovate + 1
            Select Case nTrovate
            Case 1
               Set cFrz1 = cFrz
            Case 2
               Set cFrz2 = cFrz
            Case Else
               Exit For
            End Select
         End If
      Next
      If nTrovate = 2 Then
         RuotaDiGioco = cRuota.ruota
         TrovaFormazioniDaGiocare = True
         Exit Function
      End If
   Next
   TrovaFormazioniDaGiocare = False
End Function
Sub GiocaLunghetta(cFrz1,cFrz2,RuotaDiGioco,idEstr,Ruota,nSorte , aRegistro , nTotCasi , nTotVincenti ,aQPerEsito   , bDettagli )
  
   Dim sEsito,nRetColpi ,sRetEstratti
   ReDim aNumLunghetta(13)
  
   nTotCasi  = nTotCasi  + 1
  
   If bDettagli  Then
      Call Scrivi("Numeri ricavati all'estrazione " & GetInfoEstrazione(idEstr) ,True )
      Scrivi
   End If

   If cFrz1.ritardo >= cFrz2.ritardo Then
      If bDettagli  Then cFrz1.ScriviNumeri 
      Call cFrz1.PrendiNumeriPiuRecenti(7,aNumLunghetta,1,idEstr,Ruota,bDettagli  )
      If bDettagli  Then cFrz2.ScriviNumeri  
      Call cFrz2.PrendiNumeriPiuRecenti(6,aNumLunghetta,8,idEstr,Ruota,bDettagli  )
     
     
   Else
      If bDettagli  Then cFrz2.ScriviNumeri  
      Call cFrz2.PrendiNumeriPiuRecenti(7,aNumLunghetta,1,idEstr,Ruota,bDettagli  )
  
      If bDettagli  Then cFrz1.ScriviNumeri  
      Call cFrz1.PrendiNumeriPiuRecenti(6,aNumLunghetta,8,idEstr,Ruota ,bDettagli  )
  
   End If
   
   
   If bDettagli  Then Call Scrivi("Lunghetta : " & StringaNumeri(aNumLunghetta))
   ReDim aRuoteG(1)
   aRuoteG(1) = Ruota
   If  VerificaEsito(aNumLunghetta,aRuoteG,idEstr + 1,nSorte,,,sEsito,nRetColpi ,sRetEstratti) Then
     
      Call RegistraVincita ( aRegistro , nRetColpi , sEsito ,aQPerEsito   )
      If bDettagli  Then Scrivi sEsito & " colpi : " & nRetColpi & " Numeri  : " & sRetEstratti
      nTotVincenti  = nTotVincenti  +1
   Else
      If bDettagli  Then Scrivi "Senza esito" & " colpi : " & nRetColpi
 
 
   End If
  
  
  
   If bDettagli  Then
      Scrivi
      Scrivi
   End If
  
End Sub

Sub RegistraVincita ( aRegistro , nColpi ,  sEsito ,aQPerEsito)
   Dim k
  
   Select Case sEsito
   Case "Estratto"
      aQPerEsito(1)  = aQPerEsito (1) +1
  
   Case "Ambo"
      aQPerEsito(2)  = aQPerEsito (2) +1
   Case "Terno"
      aQPerEsito(3)  = aQPerEsito (3) +1
   Case "Quaterna"
    
      aQPerEsito(4)  = aQPerEsito (4) +1
   Case "Cinquina"
      aQPerEsito(5)  = aQPerEsito (5) +1
   
   End Select
  
   For k = 1 To UBound (aRegistro)
      If nColpi >= aRegistro ( k ,1) And nColpi <= aRegistro ( k,2) Then
         aRegistro (k ,3) =   aRegistro (k ,3) + 1  
      End If
   Next

End Sub


Sub  ScriviRegistro (aQPerEsito , aRegistro ,nTotCasi , nTotVincenti , Inizio , fine  )

   Dim  k
  
   Scrivi
  
  
   Scrivi "Resoconto del metodo"
   Scrivi "Estrazione inizio : "  & GetInfoEstrazione ( Inizio)
   Scrivi "Estrazione fine   : "  & GetInfoEstrazione ( fine )
   Scrivi "Casi totali       : "  & nTotCasi
   Scrivi "Casi vincenti     : "  & nTotVincenti  & " (" &   Round(ProporzioneX ( nTotVincenti , nTotCasi ,100  ),3)  & "%" & ")"
  
   Scrivi
  
  
   Dim aD
   aD = Array ("" ,"Colpi Min" , "Colpi Max" , "Vincenti" ,"Perc")
   Call InitTabella ( aD , vbBlue , ,,vbWhite)
  
   For k = 1 To UBound (aRegistro)
      aD (1) = aRegistro( k,1)
      aD (2) = aRegistro( k,2)
      aD (3) = aRegistro( k,3)
      aD (4) = Round ( ProporzioneX(aRegistro( k,3) , nTotVincenti ,100  )  , 3)
     
      Call AddRigaTabella (aD )
     
        
   Next
  
   Call CreaTabella
  
   Scrivi
  
   aD = Array ("" ,"Sorte" , "Quantita" , "Perc")
   Call InitTabella ( aD , vbBlue , ,,vbWhite)
   For k = 1 To 5
      aD (1)  = NomeSorte(k)
      aD(2) = aQPerEsito (k)
      aD(3) = Round ( ProporzioneX ( aD(2) ,nTotVincenti , 100 ) ,3)
     
      Call AddRigaTabella (aD )

   Next  
   Call CreaTabella

End Sub
 

genios

Advanced Member >GOLD<
Ottimo Giggio . Eppur non mi sei nuovo . Sei mica di Roma . Cosi mi insegni a programmare . Farò ulteriori controlli ma mi sembra vada bene .Potremmo aggiungere l' esito sulla ventina . Giocando la ventina una bella quaterna . Ciao Eugenio
NAPOLI.jpg
 

toon

Member
Bel regalo di Natale , anticipato, la statistica da ottimi risultati.
Lo script mi pare funzioni bene.
Grazie ad Entrambi, ottimo lavoro.
 

Giggio

Super Member >PLATINUM<
purtroppo lo script che vado a postare dimostra ancora una volta che al lotto se ci giochi perdi , poi magari mi dimostrerete che mi sbaglio ..
Ho previsto di adottare una progressione di 15 colpi giocando il famoso sistema da 13 quartine per ambo
La progressione di 15 colpi si puo cambiare anche perche con questa di esempio ci vogliono 20.000 euro per arrivare al 15esimo colpo e vincere 5 euro ...

Codice:
Option Explicit
Class clsColonna
   Dim aNumeriOrig ' numeri della colonna matrice
   Dim NumeriSostituiti(10) ' numeri della colonna con le sostituzioni prese dal pronostico
   Sub SetNumeri(sNum)
      Dim av,k,e
      ReDim aNumeriOrig(10)
      av = Split(sNum,";")
      For k = 0 To UBound(av)
         If isNumeroValidoLotto(Int(av(k))) Then
            e = e + 1
            aNumeriOrig(e) = Int(av(k))
         End If
      Next
   End Sub
   Sub ConvertiColonna(aLunghetta,aRetCol)
      Dim k
      ReDim aRetCol(UBound(aNumeriOrig))
      For k = 1 To UBound(aRetCol)
         aRetCol(k) = aLunghetta(aNumeriOrig(k))
      Next
   End Sub
End Class
Class clsRuota
   Private m_CollFormazioni
   Private m_Ruota
   Sub Class_Initialize
      Set m_CollFormazioni = GetNewCollection
   End Sub
   Public Property Let Ruota(v)
      m_Ruota = v
   End Property
   Public Property Get Ruota
      Ruota = m_Ruota
   End Property
   Public Property Get CollFormazioni
      Set CollFormazioni = m_CollFormazioni
   End Property
   Public Property Set CollFormazioni(NewValue)
      m_CollFormazioni = NewValue
   End Property
   Sub AddFormazione(cFrz)
      m_CollFormazioni.Add cFrz
   End Sub
End Class
Class clsFormazione
   Private aNum
   Private mRitardo
   Sub SetNumeri(sNum)
      Dim av,k,e
      ReDim aNum(90)
      av = Split(sNum,";")
      For k = 0 To UBound(av)
         If isNumeroValidoLotto(Int(av(k))) Then
            e = e + 1
            aNum(e) = Int(av(k))
         End If
      Next
      ReDim Preserve aNum(e)
   End Sub
   Sub CalcRitardi(Ruota,idEstr,nSorte)
      ReDim aR(1)
      aR(1) = Ruota
      mRitardo = RitardoCombinazioneTurbo(aR,aNum,nSorte,idEstr)
   End Sub
   Sub PrendiNumeriPiuRecenti(nQuantita,aRetNum,idPrimoElem,idEstr,Ruota,bDettagli)
      Dim k
      ReDim aE(10,2)
      For k = 1 To 10
         aE(k,1) = aNum(k)
         aE(k,2) = RitardoEstrattoTurbo(aNum(k),idEstr,Ruota)
      Next
      Call OrdinaMatrice(aE,1,2)
      If bDettagli Then
         For k = 1 To 10
            If k <= nQuantita Then
               Scrivi Format2(aE(k,1)) & " Rit : " & aE(k,2),True
            Else
               Scrivi Format2(aE(k,1)) & " Rit : " & aE(k,2),False
            End If
         Next
      End If
      For k = 1 To nQuantita
         aRetNum((idPrimoElem - 1) + k) = aE(k,1)
      Next
   End Sub
   Sub ScriviNumeri
      Call Scrivi(StringaNumeri(aNum) & " Rit : " & mRitardo)
   End Sub
   Public Property Get Ritardo
      Ritardo = mRitardo
   End Property
End Class
Sub Main
   Dim CollRuote
   Dim CollSistema
   Dim idEstr,RitMin,RitMax
   Dim cFrz1,cFrz2
   Dim nSorte
   Dim RuotaDiGioco
   Dim aRegistro
   Dim nTotCasi,nTotVincenti
   Dim nUltima
   Dim bDettagli
   Dim nColpiUsati
   Dim aPosteProg
   Dim aLunghetta
   Dim bGioca
   ReDim aQPerEsito(5)
   
   
   If MsgBox("MOSTRARE I DETTAGLI DELLE LUNGHETTE GIOCATE CON LE FORMAZONI SCELTE E GLI ESITI ?",vbQuestion + vbYesNo) = vbYes Then
      bDettagli = True
   End If
   If MsgBox("SIMULARE LE GIOCATE CON LA PROGRESSIONE ?",vbQuestion + vbYesNo) = vbYes Then
      bGioca = True
   End If
   
   
   nSorte = 2
   RitMin = 27
   RitMax = 36
   
   ReDim aProgressioni(15)
   ' la progressione prevede di vincere minimo 10 euro entro 15 colpi giocati per ambo
   
    aProgressioni(1) = 3.00
   aProgressioni(2) = 5.00
   aProgressioni(3) = 7.50
   aProgressioni(4) = 12.00
   aProgressioni(5) = 18.50
   aProgressioni(6) = 28.50
   aProgressioni(7) = 44.00
   aProgressioni(8) = 68.50
   aProgressioni(9) = 106.00
   aProgressioni(10) = 164.50
   aProgressioni(11) = 255.00
   aProgressioni(12) = 395.50
   aProgressioni(13) = 613.50
   aProgressioni(14) = 951.00
   aProgressioni(15) = 1475.00


   
   
   
   Call AlimentaCollRuote(CollRuote)
   Call AlimentaRegistro(aRegistro)
   Call AlimentaColonneSistema(CollSistema)
   For idEstr = EstrazioneIni To EstrazioneFin
      Call CalcolaRitardi(CollRuote,idEstr,nSorte)
      If TrovaFormazioniDaGiocare(CollRuote,cFrz1,cFrz2,RitMin,RitMax,RuotaDiGioco) Then
         Call VerificaLunghetta(cFrz1,cFrz2,RuotaDiGioco,idEstr,RuotaDiGioco,nSorte,aRegistro,nTotCasi,nTotVincenti,aQPerEsito,bDettagli,nColpiUsati,aLunghetta)
         If bGioca Then Call GiocaLunghetta(CollSistema,aLunghetta,nColpiUsati,RuotaDiGioco,nSorte,aProgressioni,idEstr)
      End If
      Call AvanzamentoElab(EstrazioneIni,EstrazioneFin,idEstr)
      nUltima = idEstr
      If ScriptInterrotto Then Exit For
   Next
   Call ScriviRegistro(aQPerEsito,aRegistro,nTotCasi,nTotVincenti,EstrazioneIni,nUltima)
   ScriviResoconto
End Sub
Sub AlimentaRegistro(aRegistro)
   ReDim aRegistro(6,3)
   aRegistro(1,1) = 1 :aRegistro(1,2) = 3
   aRegistro(2,1) = 4 :aRegistro(2,2) = 5
   aRegistro(3,1) = 6 :aRegistro(3,2) = 7
   aRegistro(4,1) = 8 :aRegistro(4,2) = 10
   aRegistro(5,1) = 11 :aRegistro(5,2) = 13
   aRegistro(6,1) = 14 :aRegistro(6,2) = 10000000
   
End Sub
Sub AlimentaCollRuote(CollRuote)
   Dim r
   Dim cFrz,cRuota
   Set CollRuote = GetNewCollection
   For r = 1 To 12
      If r <> 11 Then
         Set cRuota = New clsRuota
         cRuota.Ruota = r
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("1;2;3;4;5;6;7;8;9;10")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("11;12;13;14;15;16;17;18;19;20")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("21;22;23;24;25;26;27;28;29;30")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("31;32;33;34;35;36;37;38;39;40")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("41;42;43;44;45;46;47;48;49;50")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("51;52;53;54;55;56;57;58;59;60")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("61;62;63;64;65;66;67;68;69;70")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("71;72;73;74;75;76;77;78;79;80")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("81;82;83;84;85;86;87;88;89;90")
         Call cRuota.AddFormazione(cFrz)
         CollRuote.Add cRuota
      End If
   Next
End Sub
Sub CalcolaRitardi(collRuote,idEstr,nSorte)
   Dim cRuota,cFrz
   For Each cRuota In collRuote
      For Each cFrz In cRuota.CollFormazioni
         Call cFrz.CalcRitardi(cRuota.Ruota,idEstr,nSorte)
      Next
   Next
End Sub
Function TrovaFormazioniDaGiocare(CollRuote,cFrz1,cFrz2,RitMin,RitMax,RuotaDiGioco)
   Dim cRuota,cFrz
   Dim nTrovate
   For Each cRuota In CollRuote
      nTrovate = 0
      For Each cFrz In cRuota.CollFormazioni
         If cFrz.Ritardo >= RitMin And cFrz.Ritardo <= RitMax Then
            nTrovate = nTrovate + 1
            Select Case nTrovate
            Case 1
               Set cFrz1 = cFrz
            Case 2
               Set cFrz2 = cFrz
            Case Else
               Exit For
            End Select
         End If
      Next
      If nTrovate = 2 Then
         RuotaDiGioco = cRuota.ruota
         TrovaFormazioniDaGiocare = True
         Exit Function
      End If
   Next
   TrovaFormazioniDaGiocare = False
End Function
Sub VerificaLunghetta(cFrz1,cFrz2,RuotaDiGioco,idEstr,Ruota,nSorte,aRegistro,nTotCasi,nTotVincenti,aQPerEsito,bDettagli,nRetColpiDiGioco,aNumLunghetta)
   Dim sEsito,nRetColpi,sRetEstratti
   ReDim aNumLunghetta(13)
   nTotCasi = nTotCasi + 1
   If bDettagli Then
      Call Scrivi("Numeri ricavati all'estrazione " & GetInfoEstrazione(idEstr) & " per " & NomeRuota (RuotaDiGioco) ,True,,vbYellow,,4)
      Scrivi
   End If
   If cFrz1.ritardo >= cFrz2.ritardo Then
      If bDettagli Then cFrz1.ScriviNumeri
      Call cFrz1.PrendiNumeriPiuRecenti(7,aNumLunghetta,1,idEstr,Ruota,bDettagli)
      If bDettagli Then cFrz2.ScriviNumeri
      Call cFrz2.PrendiNumeriPiuRecenti(6,aNumLunghetta,8,idEstr,Ruota,bDettagli)
   Else
      If bDettagli Then cFrz2.ScriviNumeri
      Call cFrz2.PrendiNumeriPiuRecenti(7,aNumLunghetta,1,idEstr,Ruota,bDettagli)
      If bDettagli Then cFrz1.ScriviNumeri
      Call cFrz1.PrendiNumeriPiuRecenti(6,aNumLunghetta,8,idEstr,Ruota,bDettagli)
   End If
   If bDettagli Then Call Scrivi("Lunghetta : " & StringaNumeri(aNumLunghetta))
   ReDim aRuoteG(1)
   aRuoteG(1) = Ruota
   If VerificaEsito(aNumLunghetta,aRuoteG,idEstr + 1,nSorte,,,sEsito,nRetColpi,sRetEstratti) Then
      Call RegistraVincita(aRegistro,nRetColpi,sEsito,aQPerEsito)
      If bDettagli Then Scrivi sEsito & " colpi : " & nRetColpi & " Numeri  : " & sRetEstratti
      nTotVincenti = nTotVincenti + 1
   Else
      If bDettagli Then Scrivi "Senza esito" & " colpi : " & nRetColpi
   End If
   nRetColpiDiGioco = nRetColpi
   If bDettagli Then
      Scrivi
      Scrivi
   End If
End Sub
Sub RegistraVincita(aRegistro,nColpi,sEsito,aQPerEsito)
   Dim k
   Select Case sEsito
   Case "Estratto"
      aQPerEsito(1) = aQPerEsito(1) + 1
   Case "Ambo"
      aQPerEsito(2) = aQPerEsito(2) + 1
   Case "Terno"
      aQPerEsito(3) = aQPerEsito(3) + 1
   Case "Quaterna"
      aQPerEsito(4) = aQPerEsito(4) + 1
   Case "Cinquina"
      aQPerEsito(5) = aQPerEsito(5) + 1
   End Select
   For k = 1 To UBound(aRegistro)
      If nColpi >= aRegistro(k,1) And nColpi <= aRegistro(k,2) Then
         aRegistro(k,3) = aRegistro(k,3) + 1
      End If
   Next
End Sub
Sub ScriviRegistro(aQPerEsito,aRegistro,nTotCasi,nTotVincenti,Inizio,fine)
   Dim k
   Scrivi
   Scrivi "Resoconto del metodo"
   Scrivi "Estrazione inizio : " & GetInfoEstrazione(Inizio)
   Scrivi "Estrazione fine   : " & GetInfoEstrazione(fine)
   Scrivi "Casi totali       : " & nTotCasi
   Scrivi "Casi vincenti     : " & nTotVincenti & " (" & Round(ProporzioneX(nTotVincenti,nTotCasi,100),3) & "%" & ")"
   Scrivi
   Dim aD
   aD = Array("","Colpi Min","Colpi Max","Vincenti","Perc")
   Call InitTabella(aD,vbBlue,,,vbWhite)
   For k = 1 To UBound(aRegistro)
      aD(1) = aRegistro(k,1)
      aD(2) = aRegistro(k,2)
      aD(3) = aRegistro(k,3)
      aD(4) = Round(ProporzioneX(aRegistro(k,3),nTotVincenti,100),3)
      Call AddRigaTabella(aD)
   Next
   Call CreaTabella
   Scrivi
   aD = Array("","Sorte","Quantita","Perc")
   Call InitTabella(aD,vbBlue,,,vbWhite)
   For k = 1 To 5
      aD(1) = NomeSorte(k)
      aD(2) = aQPerEsito(k)
      aD(3) = Round(ProporzioneX(aD(2),nTotVincenti,100),3)
      Call AddRigaTabella(aD)
   Next
   Call CreaTabella
End Sub
Sub AlimentaColonneSistema(coll)
   Set coll = GetNewCollection
   Call AddColonna(coll,"2;3;5;11")
   Call AddColonna(coll,"3;4;6;12")
   Call AddColonna(coll,"4;5;7;13")
   Call AddColonna(coll,"1;5;6;8")
   Call AddColonna(coll,"2;6;7;9")
   Call AddColonna(coll,"3;7;8;10")
   Call AddColonna(coll,"4;8;9;11")
   Call AddColonna(coll,"5;9;10;12")
   Call AddColonna(coll,"6;10;11;13")
   Call AddColonna(coll,"1;7;11;12")
   Call AddColonna(coll,"2;8;12;13")
   Call AddColonna(coll,"1;3;9;13")
   Call AddColonna(coll,"1;2;4;10")
End Sub
Sub AddColonna(coll,sNumeri)
   Dim clsCol
   Set clsCol = New clsColonna
   clsCol.SetNumeri(sNumeri)
   coll.Add clsCol
End Sub
Sub GiocaLunghetta(CollSistema,aLunghetta,nColpiUsati,RuotaDiGioco,nSorte,aPosteProg,idEstr)
   Dim idG,k
   Dim cCol
   Dim aN
   ReDim aP(10)
   ReDim aRt(1)
   aRt(1) = RuotaDiGioco
   For k = 1 To UBound(aPosteProg)
      idG = 0
      If k <= nColpiUsati Then
         Scrivi "Colpo : " & k,True,,,,4
         aP(nSorte) = aPosteProg(k)
         For Each cCol In CollSistema
            idG = idG + 1
            Call cCol.ConvertiColonna(aLunghetta,aN)
            Call ImpostaGiocata(idG,aN,aRt,aP,1)
         Next
         Gioca(idEstr - 1) + k
      End If
   Next
End Sub
 

toon

Member
Magari chiedo troppo, ma non è possibile specificare su che ruota viene individuata la decina di ricerca?
Magari riusciamo ad ottimizzare l'ottimo metodo, magari anche a restringere le gicate.
Grazie.
 

Giggio

Super Member >PLATINUM<
il fatto è che lo script cerca una condizione per cui esistano solo e soltanto due delle formazioni appartenenti alle decine che abbiano un ritardo compreso nel range previsto , sicche non è detto che se uno usa una ruota specifica trovi sempre qualcosa da giocare ...per questa ragione lo script le considera tutte e prende la prima adatta.
 

toon

Member
Grazie per la risposta, ma non è possibile far indicare quale è la ruota che lo script ha identificato?
Dal momento che trova la condizione, non c'è la possibilità di fargli, oltre ai numeri trovati, anche la ruota?
Io faccio presto a chiedere, ma penso non sia altrettanto facile eseguirlo in uno script..
:rolleyes: ;)(y)
 

toon

Member
Non me pia pe rompi...., Ma da la ruota dove esce l'ambo della lunghetta, non la ruota dove è stata trovata la condizione di calcolo..
Ti prego, abbi pazienza...😞😩
 

toon

Member
Vergogaaaaaaaa....
Stavo utilizzando il primo....:sleep::sleep:😔😔 il rincog........to olee!!!!
Grazie, ecco dove era l'errore, nell'occhio che guarda, il mio....
Grazie e perdonami di averTi fatto perdere tempo.
 

Giggio

Super Member >PLATINUM<
ad ogni colpo gioca la posta realtiva a quel colpo per le 13 quartine.
bastano pochi casi negativi (cioe superiori a 15 colpi) per far infrangere i sogni ....
 

Giggio

Super Member >PLATINUM<
forse aspettando che la lunghetta maturi si riesce ad andare in positivo ...certo i casi da giocare si riducono di parecchio soprattutto perche dalle poche prove che ho fatto bisogna giocare le lunghette che abbiano superato le 32 estrazioni di ritardo.
Con quest'altra versione dello script ho aggiunto la possibilita di impostare il ritardo minimo dopo l quale giocare , ma attenzione la fregatura sta sempre dietro l'angolo e comunque sostenere 13 qurtine per ambo mi pare pesante ... qualcuno che si intende di progressioni potrebbe postarne una adatta...


Codice:
-- sostituito....
 
Ultima modifica:

Giggio

Super Member >PLATINUM<
lo script ora prende in considerazione tutti i casi possibili dati dalla ricerca delle condizioni su tutte l e ruote , prima appena trovava la condizione su una ruota costruiva la lunghetta e la giocava , ora potrebbe trovare piu lunghette su ruote diverse a partire dalla stessa estrazione , avendo introdotto il parametro di attesa era necessario torvare tutte le lunghette che si potevano ottenere da una singola estrazione per poi avere piu possibilita che una maturasse sopra il ritardo minimo.
Almeno i casi da esaminare sono un po' di piu ...

Codice:
Option Explicit
Class clsCoppiaFormazioni
   Public Ruota
   Public cFrz1
   Public cFrz2
 
End Class
Class clsColonna
   Dim aNumeriOrig ' numeri della colonna matrice
   Dim NumeriSostituiti(10) ' numeri della colonna con le sostituzioni prese dal pronostico
   Sub SetNumeri(sNum)
      Dim av,k,e
      ReDim aNumeriOrig(10)
      av = Split(sNum,";")
      For k = 0 To UBound(av)
         If isNumeroValidoLotto(Int(av(k))) Then
            e = e + 1
            aNumeriOrig(e) = Int(av(k))
         End If
      Next
   End Sub
   Sub ConvertiColonna(aLunghetta,aRetCol)
      Dim k
      ReDim aRetCol(UBound(aNumeriOrig))
      For k = 1 To UBound(aRetCol)
         aRetCol(k) = aLunghetta(aNumeriOrig(k))
      Next
   End Sub
End Class
Class clsRuota
   Private m_CollFormazioni
   Private m_Ruota
   Sub Class_Initialize
      Set m_CollFormazioni = GetNewCollection
   End Sub
   Public Property Let Ruota(v)
      m_Ruota = v
   End Property
   Public Property Get Ruota
      Ruota = m_Ruota
   End Property
   Public Property Get CollFormazioni
      Set CollFormazioni = m_CollFormazioni
   End Property
   Public Property Set CollFormazioni(NewValue)
      m_CollFormazioni = NewValue
   End Property
   Sub AddFormazione(cFrz)
      m_CollFormazioni.Add cFrz
   End Sub
End Class
Class clsFormazione
   Private aNum
   Private mRitardo
   Sub SetNumeri(sNum)
      Dim av,k,e
      ReDim aNum(90)
      av = Split(sNum,";")
      For k = 0 To UBound(av)
         If isNumeroValidoLotto(Int(av(k))) Then
            e = e + 1
            aNum(e) = Int(av(k))
         End If
      Next
      ReDim Preserve aNum(e)
   End Sub
   Sub CalcRitardi(Ruota,idEstr,nSorte)
      ReDim aR(1)
      aR(1) = Ruota
      mRitardo = RitardoCombinazioneTurbo(aR,aNum,nSorte,idEstr)
   End Sub
   Sub PrendiNumeriPiuRecenti(nQuantita,aRetNum,idPrimoElem,idEstr,Ruota,bDettagli)
      Dim k
      ReDim aE(10,2)
      For k = 1 To 10
         aE(k,1) = aNum(k)
         aE(k,2) = RitardoEstrattoTurbo(aNum(k),idEstr,Ruota)
      Next
      Call OrdinaMatrice(aE,1,2)
      If bDettagli Then
         For k = 1 To 10
            If k <= nQuantita Then
               Scrivi Format2(aE(k,1)) & " Rit : " & aE(k,2),True
            Else
               Scrivi Format2(aE(k,1)) & " Rit : " & aE(k,2),False
            End If
         Next
      End If
      For k = 1 To nQuantita
         aRetNum((idPrimoElem - 1) + k) = aE(k,1)
      Next
   End Sub
   Sub ScriviNumeri
      Call Scrivi(StringaNumeri(aNum) & " Rit : " & mRitardo)
   End Sub
   Public Property Get Ritardo
      Ritardo = mRitardo
   End Property
End Class
Sub Main
   Dim CollRuote , CollForm
   Dim CollSistema
   Dim idEstr,RitMin,RitMax
   Dim cFrz1,cFrz2
   Dim nSorte
   Dim RuotaDiGioco
   Dim aRegistro
   Dim nTotCasi,nTotVincenti
   Dim nUltima
   Dim bDettagli
   Dim nColpiUsati
   Dim aPosteProg
   Dim aLunghetta
   Dim bGioca
   Dim nColpiAttesa
   Dim cCoppiaFrz
 
   ReDim aQPerEsito(5)
 
 
   If MsgBox("MOSTRARE I DETTAGLI DELLE LUNGHETTE GIOCATE CON LE FORMAZONI SCELTE E GLI ESITI ?",vbQuestion + vbYesNo) = vbYes Then
      bDettagli = True
   End If
   If MsgBox("SIMULARE LE GIOCATE CON LA PROGRESSIONE ?",vbQuestion + vbYesNo) = vbYes Then
      bGioca = True
   End If
 
   nColpiAttesa = Int(InputBox("Gioca le combinazioni che hanno superato il ritardo specificato di","Colpi attsa",32))
   nSorte = 2
   RitMin = 27
   RitMax = 36
 
   ReDim aProgressioni(15)
   ' la progressione prevede di vincere minimo 10 euro entro 15 colpi giocati per ambo
 
    aProgressioni(1) = 3.00
   aProgressioni(2) = 5.00
   aProgressioni(3) = 7.50
   aProgressioni(4) = 12.00
   aProgressioni(5) = 18.50
   aProgressioni(6) = 28.50
   aProgressioni(7) = 44.00
   aProgressioni(8) = 68.50
   aProgressioni(9) = 106.00
   aProgressioni(10) = 164.50
   aProgressioni(11) = 255.00
   aProgressioni(12) = 395.50
   aProgressioni(13) = 613.50
   aProgressioni(14) = 951.00
   aProgressioni(15) = 1475.00


 
 
 
   Call AlimentaCollRuote(CollRuote)
   Call AlimentaRegistro(aRegistro)
   Call AlimentaColonneSistema(CollSistema)
   For idEstr = EstrazioneIni To EstrazioneFin
      Call CalcolaRitardi(CollRuote,idEstr,nSorte)
     
      If TrovaFormazioniDaGiocare(CollRuote, CollForm ,RitMin,RitMax ) Then
         For Each cCoppiaFrz In CollForm
            Call VerificaLunghetta(cCoppiaFrz.cFrz1,cCoppiaFrz.cFrz2, idEstr,cCoppiaFrz.Ruota,nSorte,aRegistro,nTotCasi,nTotVincenti,aQPerEsito,bDettagli,nColpiUsati,aLunghetta)
            If nColpiUsati > nColpiAttesa Then
       
               If bGioca Then Call GiocaLunghetta(CollSistema,aLunghetta,nColpiUsati,cCoppiaFrz.Ruota,nSorte,aProgressioni,idEstr,nColpiAttesa)
            End If
         Next
      End If
      Call AvanzamentoElab(EstrazioneIni,EstrazioneFin,idEstr)
      nUltima = idEstr
      If ScriptInterrotto Then Exit For
   Next
   Call ScriviRegistro(aQPerEsito,aRegistro,nTotCasi,nTotVincenti,EstrazioneIni,nUltima)
   ScriviResoconto
End Sub
Sub AlimentaRegistro(aRegistro)
   ReDim aRegistro(6,3)
   aRegistro(1,1) = 1 :aRegistro(1,2) = 3
   aRegistro(2,1) = 4 :aRegistro(2,2) = 5
   aRegistro(3,1) = 6 :aRegistro(3,2) = 7
   aRegistro(4,1) = 8 :aRegistro(4,2) = 10
   aRegistro(5,1) = 11 :aRegistro(5,2) = 13
   aRegistro(6,1) = 14 :aRegistro(6,2) = 10000000
 
End Sub
Sub AlimentaCollRuote(CollRuote)
   Dim r
   Dim cFrz,cRuota
   Set CollRuote = GetNewCollection
   For r = 1 To 12
      If r <> 11 Then
         Set cRuota = New clsRuota
         cRuota.Ruota = r
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("1;2;3;4;5;6;7;8;9;10")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("11;12;13;14;15;16;17;18;19;20")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("21;22;23;24;25;26;27;28;29;30")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("31;32;33;34;35;36;37;38;39;40")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("41;42;43;44;45;46;47;48;49;50")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("51;52;53;54;55;56;57;58;59;60")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("61;62;63;64;65;66;67;68;69;70")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("71;72;73;74;75;76;77;78;79;80")
         Call cRuota.AddFormazione(cFrz)
         Set cFrz = New clsFormazione
         cFrz.SetNumeri("81;82;83;84;85;86;87;88;89;90")
         Call cRuota.AddFormazione(cFrz)
         CollRuote.Add cRuota
      End If
   Next
End Sub
Sub CalcolaRitardi(collRuote,idEstr,nSorte)
   Dim cRuota,cFrz
   For Each cRuota In collRuote
      For Each cFrz In cRuota.CollFormazioni
         Call cFrz.CalcRitardi(cRuota.Ruota,idEstr,nSorte)
      Next
   Next
End Sub
Function TrovaFormazioniDaGiocare(CollRuote, CollForm ,RitMin,RitMax )
   Dim cRuota,cFrz
   Dim nTrovate
   Dim cCoppiaFrz
 
   Set CollForm = GetNewCollection
 
 
   For Each cRuota In CollRuote
      nTrovate = 0
      Set cCoppiaFrz = New clsCoppiaFormazioni
      cCoppiaFrz.ruota = cRuota.Ruota
       
      For Each cFrz In cRuota.CollFormazioni
         If cFrz.Ritardo >= RitMin And cFrz.Ritardo <= RitMax Then
            nTrovate = nTrovate + 1
            Select Case nTrovate
            Case 1
                Set cCoppiaFrz.cFrz1 = cFrz
            Case 2
                Set cCoppiaFrz.cFrz2 = cFrz
            Case Else
               Exit For
            End Select
         End If
      Next
      If nTrovate = 2 Then
         CollForm.Add cCoppiaFrz
         'RuotaDiGioco = cRuota.ruota
         'TrovaFormazioniDaGiocare = True
         'Exit Function
      End If
   Next
   TrovaFormazioniDaGiocare = CollForm.count
 
End Function
Sub VerificaLunghetta(cFrz1,cFrz2,idEstr,Ruota,nSorte,aRegistro,nTotCasi,nTotVincenti,aQPerEsito,bDettagli,nRetColpiDiGioco,aNumLunghetta)
   Dim sEsito,nRetColpi,sRetEstratti
   ReDim aNumLunghetta(13)
   nTotCasi = nTotCasi + 1
   If bDettagli Then
      Call Scrivi("Numeri ricavati all'estrazione " & GetInfoEstrazione(idEstr) & " per " & NomeRuota(Ruota),True,,vbYellow,,4)
      Scrivi
   End If
   If cFrz1.ritardo >= cFrz2.ritardo Then
      If bDettagli Then cFrz1.ScriviNumeri
      Call cFrz1.PrendiNumeriPiuRecenti(7,aNumLunghetta,1,idEstr,Ruota,bDettagli)
      If bDettagli Then cFrz2.ScriviNumeri
      Call cFrz2.PrendiNumeriPiuRecenti(6,aNumLunghetta,8,idEstr,Ruota,bDettagli)
   Else
      If bDettagli Then cFrz2.ScriviNumeri
      Call cFrz2.PrendiNumeriPiuRecenti(7,aNumLunghetta,1,idEstr,Ruota,bDettagli)
      If bDettagli Then cFrz1.ScriviNumeri
      Call cFrz1.PrendiNumeriPiuRecenti(6,aNumLunghetta,8,idEstr,Ruota,bDettagli)
   End If
   If bDettagli Then Call Scrivi("Lunghetta : " & StringaNumeri(aNumLunghetta))
   ReDim aRuoteG(1)
   aRuoteG(1) = Ruota
   If VerificaEsito(aNumLunghetta,aRuoteG,idEstr + 1,nSorte,,,sEsito,nRetColpi,sRetEstratti) Then
      Call RegistraVincita(aRegistro,nRetColpi,sEsito,aQPerEsito)
      If bDettagli Then Scrivi sEsito & " colpi : " & nRetColpi & " Numeri  : " & sRetEstratti
      nTotVincenti = nTotVincenti + 1
   Else
      If bDettagli Then Scrivi "Senza esito" & " colpi : " & nRetColpi
   End If
   nRetColpiDiGioco = nRetColpi
   If bDettagli Then
      Scrivi
      Scrivi
   End If
End Sub
Sub RegistraVincita(aRegistro,nColpi,sEsito,aQPerEsito)
   Dim k
   Select Case sEsito
   Case "Estratto"
      aQPerEsito(1) = aQPerEsito(1) + 1
   Case "Ambo"
      aQPerEsito(2) = aQPerEsito(2) + 1
   Case "Terno"
      aQPerEsito(3) = aQPerEsito(3) + 1
   Case "Quaterna"
      aQPerEsito(4) = aQPerEsito(4) + 1
   Case "Cinquina"
      aQPerEsito(5) = aQPerEsito(5) + 1
   End Select
   For k = 1 To UBound(aRegistro)
      If nColpi >= aRegistro(k,1) And nColpi <= aRegistro(k,2) Then
         aRegistro(k,3) = aRegistro(k,3) + 1
      End If
   Next
End Sub
Sub ScriviRegistro(aQPerEsito,aRegistro,nTotCasi,nTotVincenti,Inizio,fine)
   Dim k
   Scrivi
   Scrivi "Resoconto del metodo"
   Scrivi "Estrazione inizio : " & GetInfoEstrazione(Inizio)
   Scrivi "Estrazione fine   : " & GetInfoEstrazione(fine)
   Scrivi "Casi totali       : " & nTotCasi
   Scrivi "Casi vincenti     : " & nTotVincenti & " (" & Round(ProporzioneX(nTotVincenti,nTotCasi,100),3) & "%" & ")"
   Scrivi
   Dim aD
   aD = Array("","Colpi Min","Colpi Max","Vincenti","Perc")
   Call InitTabella(aD,vbBlue,,,vbWhite)
   For k = 1 To UBound(aRegistro)
      aD(1) = aRegistro(k,1)
      aD(2) = aRegistro(k,2)
      aD(3) = aRegistro(k,3)
      aD(4) = Round(ProporzioneX(aRegistro(k,3),nTotVincenti,100),3)
      Call AddRigaTabella(aD)
   Next
   Call CreaTabella
   Scrivi
   aD = Array("","Sorte","Quantita","Perc")
   Call InitTabella(aD,vbBlue,,,vbWhite)
   For k = 1 To 5
      aD(1) = NomeSorte(k)
      aD(2) = aQPerEsito(k)
      aD(3) = Round(ProporzioneX(aD(2),nTotVincenti,100),3)
      Call AddRigaTabella(aD)
   Next
   Call CreaTabella
End Sub
Sub AlimentaColonneSistema(coll)
   Set coll = GetNewCollection
   Call AddColonna(coll,"2;3;5;11")
   Call AddColonna(coll,"3;4;6;12")
   Call AddColonna(coll,"4;5;7;13")
   Call AddColonna(coll,"1;5;6;8")
   Call AddColonna(coll,"2;6;7;9")
   Call AddColonna(coll,"3;7;8;10")
   Call AddColonna(coll,"4;8;9;11")
   Call AddColonna(coll,"5;9;10;12")
   Call AddColonna(coll,"6;10;11;13")
   Call AddColonna(coll,"1;7;11;12")
   Call AddColonna(coll,"2;8;12;13")
   Call AddColonna(coll,"1;3;9;13")
   Call AddColonna(coll,"1;2;4;10")
End Sub
Sub AddColonna(coll,sNumeri)
   Dim clsCol
   Set clsCol = New clsColonna
   clsCol.SetNumeri(sNumeri)
   coll.Add clsCol
End Sub
Sub GiocaLunghetta(CollSistema,aLunghetta,nColpiUsati,RuotaDiGioco,nSorte,aPosteProg,idEstr,nColpiAttesa)
   Dim idG,k
   Dim cCol
   Dim aN
   ReDim aP(10)
   ReDim aRt(1)
   aRt(1) = RuotaDiGioco
   For k = 1 To UBound(aPosteProg)
      idG = 0
      If k <= nColpiUsati - nColpiAttesa Then
         Scrivi "Colpo : " & k,True,,,,4
         aP(nSorte) = aPosteProg(k)
         For Each cCol In CollSistema
            idG = idG + 1
            Call cCol.ConvertiColonna(aLunghetta,aN)
            Call ImpostaGiocata(idG,aN,aRt,aP,1,nSorte)
         Next
         Gioca(idEstr - 1) + k + nColpiAttesa
      End If
   Next
End Sub
 

genios

Advanced Member >GOLD<
Giggio potresti fare lo script per il superenalotto vediamo come si comporta

lo script procede cosi :

Scelta se fare la statistica su 6 o 7 posizioni

se su 6 posizioni

-per ogni estrazione individua dove ci sono 2 e soltanto 2 tra le formazioni delle decine naturali che siano entro i limiti del ritardo previsto in questo caso 18 e 24

se su 7 posizioni

-per ogni estrazione individua dove ci sono 2 e soltanto 2 tra le formazioni delle decine naturali che siano entro i limiti del ritardo previsto in questo caso 13 e 18


- verificare i risultati di gioco dalla lunghetta composta dalle 2 decine integrali solo su 6 posizioni

- dalla lungetta piu ritardata prende i prim 8 numeri piu recenti
-dalla lunghetta meno ritardata prende i primi 7 numeri piu recenti
- li unisce a farli diventare una lunghetta da 15
- verifica i risultati di gioco della lunghetta di 15 numeri solo su 6 posizioni .
- passa alla prossima estrazione.

ciao Eugenio
 
Ultima modifica:

genios

Advanced Member >GOLD<
Per quanto riguarda la progressione prova raddoppiare i parametri ogni 3 estrazioni di gioco . Anche se io non andrei oltre le 9 estrazioni di gioco.

01 giocata 1 ogni quartina = 13 giocata totale
02 giocata 1 ogni quartina = 13 giocata totale
03 giocata 1 ogni quartina = 13 giocata totale
04 giocata 2 ogni quartina = 26 giocata totale
05 giocata 2 ogni quartina = 26 giocata totale
06 giocata 2 ogni quartina = 26 giocata totale
07 giocata 4 ogni quartina = 52 giocata totale
08 giocata 4 ogni quartina = 52 giocata totale
09 giocata 4 ogni quartina = 52 giocata totale
10 giocata 8 ogni quartina = 104 giocata totale
11 giocata 8 ogni quartina = 104 giocata totale
12 giocata 8 ogni quartina = 104 giocata totale
13 giocata 16 ogni quartina = 208 giocata totale
14 giocata 16 ogni quartina = 208giocata totale
15 giocata16 ogni quartina = 208 giocata totale

ciao Eugenio
 

Alien.

Advanced Premium Member
Toc....Toc......permesso ....
Vado fuori "tema" per il superenalotto non si potrebbe provare con i numeri spia ?
Cioè per ogni numero spia indicare i primi 5/10 numeri usciti più frequenti. ecc..
....
cosa dite G&G ?
 

Giggio

Super Member >PLATINUM<
ahahha mi sembri il mio capo .. .vediamo come si comprta ... intanto uno lavora poi se quello che fa non serve a un tubo a me che mi frega mica ho lavorato io .....io ho le idee.... eheheh ....se vuoi sapere come si comporta con il superenalotto te lo dico subito .. nopn serve a un cazzo .... ahahahahh
 

Ultima estrazione Lotto

  • Estrazione del lotto
    martedì 26 gennaio 2021
    Bari
    21
    55
    01
    42
    88
    Cagliari
    75
    28
    81
    06
    88
    Firenze
    53
    63
    35
    90
    83
    Genova
    03
    64
    78
    66
    60
    Milano
    31
    48
    47
    08
    37
    Napoli
    87
    65
    76
    42
    54
    Palermo
    85
    64
    66
    20
    78
    Roma
    61
    31
    45
    60
    20
    Torino
    35
    83
    53
    81
    11
    Venezia
    17
    26
    45
    77
    61
    Nazionale
    13
    49
    82
    80
    47
    Estrazione Simbolotto
    Bari
    39
    07
    26
    25
    19
Alto