x LuigiB

[Beppignello]

ciao LuigiB

vorrei realizzare uno script che accorpa in decine, una serie numerica di 30 nr diversi.

non tutti hanno le condizioni che richiedo, quindi solo una parte di essi
e vorrei accorparli in una serie di 10 nr.giocabili

hai qualche idea da suggerirmi?
esiste forse qualcosa già ( o forse simile ) che può tornarmi utile per accorpare i numeri in classe da me richiesta?

da non fraintendere con le matrici ridotte, ciò che vorrei realizzare è qualcosa di diverso.

grazie

 

[LuigiB]

ciao se non vuoi ottenere dei ridotti l'algoritmo che adopererai devierà certamente da una rigida regola che imponga la rappresentazione di tutte l combinazioni della sorte voluta , gia se volessi fare questo sarebbe molto difficile scrivere la routine e varrebbe la pena di usare le matrici gia previste ,per la tua necessita invece dovrai scrivere un algoritmo che in base a tuoi criteri scelga dei numeri piuttosto che altri per formare le decine da giocare , ad esempio potresti dare dei pesi ai 30 numeri e decrementarli ogni volta che uno dei numeri è stato preso per inserirlo in una decina da giocare , poi l'algoritmo scegliera per ogni passaggio i numeri col peso piu alto e formera la decina da giocare , il tutto per il numero di decine volute in questo modo l'algoritmo tirera fuori sempre decine con peso progressivamente inferiore ..ripeto è solo un esempio si tratta di fantasia e di realizzazione pratica della propria idea..di gia fatto non c'è nulla...

 

[salvo50]

Ciao a Tutti!

Se dovessi giocarli io userei il sistema dei cassetti, 6 gruppi di 5 numeri ciascuno, accoppiate a due a due in tutte le combinazioni sono 15 giocate da 10 numeri,

A - B - C - D - E - F

(A - B) (A - C) (A - D) (A - E) (A - F)

(B - C) (B - D) (B - E) (B - F) (C - D)

(C - E) (C - F) (D - E) (D - F) (E - F)

 

[LuigiB]

Ciao , l'idea di Salvo è buona ecco lo script che la implementa ...(salvo errori miei ... fatemi sapere..)

Option Explicit
Sub Main

    Dim aGruppi
    Dim nQGruppi
    Dim aNumUsati
    Dim nQNumeri
    Dim sSistema
    Dim nNumPerGruppo
    Dim nClasseSvil
    Dim k , kk , i
    Dim aComb
    Dim sColonna


    nQNumeri = ScegliNumeri (  aNumUsati )


    sSistema  = ScegliSistemaCassetti ( nQNumeri)
    If sSistema <> "" Then
        Call Scrivi ("Numeri selezionati : " & nQNumeri )
        Call Scrivi ("Numeri             : " & StringaNumeri ( aNumUsati ) )
        Call Scrivi ("Sistema            : " & sSistema )
        Call Scrivi ()
        Call Scrivi (" - SVILUPPO - " )
        Call Scrivi ()



        ReDim av(0)
        Call SplitByChar(  sSistema , " " , av )

        nNumPerGruppo = CInt(av(0))
        nClasseSvil  = CInt(av(5))
        nQGruppi = nQNumeri / nNumPerGruppo

        ReDim aGruppi (nQGruppi ,nNumPerGruppo )
        ReDim aIdGruppi  (nQGruppi)
        i =0
        For k  = 1 To nQGruppi
            For kk = 1 To nNumPerGruppo
                i = i +1
                aGruppi (k ,kk) = aNumUsati(i)
            Next
            aIdGruppi (k) = k
        Next


        aComb =  SviluppoIntegrale ( aIdGruppi ,nClasseSvil )

        For k = 1 To UBound(aComb)
            sColonna = ""
            For kk = 1 To nClasseSvil
                sColonna = sColonna & GetCombFromGruppo (aGruppi , aComb (k,kk) ,nNumPerGruppo  )
            Next

            Call Scrivi ( FormattaStringa  ( k ,"0000" ) & ") " & RimuoviLastChr (sColonna , "." ))
        Next
    Else
        Scrivi "Nessun sistema selezionato"
    End If


End Sub
Function GetCombFromGruppo (aGruppi , idGruppo  , qNumPerGruppo )

    Dim s , k
    s = ""
    For k = 1 To qNumPerGruppo
        s = s & Format2(aGruppi (idGruppo , k)) & "."
    Next

    GetCombFromGruppo  = s
End Function

Function  ScegliSistemaCassetti ( nQNumeri )
    Dim nNumPerGruppo , nGruppi , nDisp , nClasse , sVoce , id
    Dim aVoci

    ReDim aVoci (0)

    For nNumPerGruppo = 2 To 5
        If nQNumeri  Mod nNumPerGruppo =0 Then
            For nGruppi = 2 To 10


                    nClasse = nGruppi * nNumPerGruppo
                    If nClasse <= 10 Then
                        nDisp  = nDisp +1
                        sVoce =  nNumPerGruppo & " num per gruppo, gruppi "
                        sVoce = sVoce  & nGruppi & " (classe " &  nClasse
                        sVoce = sVoce & ") comb " & Combinazioni ( (nQNumeri/nNumPerGruppo) , nGruppi )

                        ReDim Preserve aVoci (nDisp )
                        aVoci ( nDisp ) = sVoce

                    End If


            Next
        End If

    Next

    If nDisp   >0 Then
        id = ScegliOpzioneMenu( aVoci )
        If id >=0 Then
            ScegliSistemaCassetti  = aVoci (id)
        Else
            ScegliSistemaCassetti  = ""    
        End If
    Else
        MsgBox "La quantita di numeri selezionata non è adatta per la creazione del sistema a cassetti , la quantita dei numeri selezionati deve essere divisibile per almeno uno dei numeri 2,3,4,5"
    End If
End Function

 

[salvo50]

Ciao!

Eccellente, provato anche con più di 30 numeri.

Grazie!

 

[LuigiB]

grazie ..ciao ..