Novità

correggere script

Marcorun

Advanced Member >GOLD<
ciao!
qualcuno gentilmente potrebbe correggere questo semplice script?
vorrei mettere in gioco il numero più frequente su tot estrazioni........a me viene fuori sempre il 4!

GRAZIE!

Sub Main()
Dim ruote(10)
Dim numeri1(10)
Dim posta(5)
posta(2) = 0
posta(3) = 0
posta(4) = 0
posta(1) = 1
r = InputBox("Su quale ruota, ",,1)
ruote(1) = r

For n = EstrazioneFin - 50 To EstrazioneFin

numeri1(1) = f
For x = 1 To 90

f = EstrattoFrequenza(r,x,EstrazioneFin - 50,EstrazioneFin)
Next
ImpostaGiocata 1,numeri1,ruote,posta,19,1


Gioca n

Next
ScriviResoconto
End Sub
 

salvo50

Advanced Member >PLATINUM PLUS<
Ciao a Tutti.

Ad occhio vedo che hai messo

numeri1(1) = f

prima di

f = EstrattoFrequenza(r,x,EstrazioneFin - 50,EstrazioneFin)

lo devi mettere dopo questa riga
 

Marcorun

Advanced Member >GOLD<
meglio.....ma c'è qualcosa che non va....escono solo numeri 1,2,3,4,5,8....e controllando non sono i più frequenti x quel range..:-\
 

salvo50

Advanced Member >PLATINUM PLUS<
Non conosco EstrattoFrequenza e sono andato a spulciare nell'aiuto e secondo me è sbagliato usarlo con ImpostaGiocata, perche da come risposta quante volte è uscito un dato numero, quindi con ImpostaGiocata non stai giocando i numeri, ma quante volte è uscito un numero

tolgo lo script
 
Ultima modifica:

Mike58

Advanced Member >PLATINUM PLUS<
Gli errori sono di concetto.
F = alle frequenze del numero x, se poi al vettore gli assegniamo il valore F e chiaro che in 50 estrazioni escono solo numeri < a 10 in quanto non si hanno presenze o frequenze superiori.

Se vuoi vedere i numeri al Vettore Numeri1 bisogna assegnare il valore x dei numeri.

Poi per il resto non si capisce cosa bisogna ottenere sembra rigiocare tutti i numeri trovati in frequenza il che è assurdo.

Ciao
 

Marcorun

Advanced Member >GOLD<
(Untitled)

Grazie x l'interessamento.... purtroppo non sono nato già imparato... è x questo che ho chiesto aiuto....ma come già accaduto ne so quanto prima...continuo con prove e richieste di aiuto.......... GRAZIE..ciao a tutti.
 

salvo50

Advanced Member >PLATINUM PLUS<
Marcorun;n2153029 ha scritto:
Grazie x l'interessamento.... purtroppo non sono nato giÃ* imparato... è x questo che ho chiesto aiuto....ma come giÃ* accaduto ne so quanto prima...continuo con prove e richieste di aiuto.......... GRAZIE..ciao a tutti.

Ciao a Tutti.

Nessuno è nato imparato, chiedi pure per quel poco che ne sò io, sarò sempre disponibile, sbagliando si impara.
 

Marcorun

Advanced Member >GOLD<
(Untitled)

Lo farò grazie mille....anche perché lo studio del lotto ,script compresi è il mio hobby principale e ho una grande ammirazione per voi che riuscite a creare listati che x me sono cose dell'altro mondo... d'altronde penso che anche x voi più esperti di me ,non si finisce mai di imparare.....ciao!!!!

PS: se proprio qualcuno si vuole impegnare.....sto cercando di scrivere uno script che mi metta in gioco l'estratto più frequente su tot estrazioni con relativo rendiconto economico...saluti!!
 

Mike58

Advanced Member >PLATINUM PLUS<
Ciao marcorun,un estratto frequente su tot estrazione non è complicato trovarlo, ma purtroppo questo cambierà con il prosiego delle estrazioni e quindi la statistica sarà sempre falsata.

Quello che ti propongo quindi è cercare su un range di estrazioni totali di determinare dei cicli di estrazioni e cercarci i superFrequenti con degli abbinamenti x ambo.

Eccoti un esempio discript magari più complesso.

Codice:
Sub Main
   Dim ini,fin,ini1,es,ciclo,colpi,i,y,ii
   Dim bEsito
   Dim kCG,kAbb,kGiocate,kCasi,kCasiPos,kAmbi,ktutto 'contatori capigioco, abbinamenti, giocate,casi tot, casi pos, ambirealizz
   Dim aRuota(1),aPosta(2),aNum(1),aAmbo(2),tutto(1)
   Dim RetEsito,RetColpi,RetEstratti,retId
   ReDim aCapoG(0),aAbbin(0),Atutto(0) 'array per i CG (freq>2), gli abbin(freq=2)
   aRuota(1) = CInt(InputBox(" Scegli la ruota di ricerca ",,"1"))
   ini = CInt(InputBox(" Scegli l'estrazione di inizio ricerca ",,8000))
   sfc = CInt(InputBox("Quanti superfrequenti capogioco",,3))
   sfa = CInt(InputBox("Quanti superfrequenti Abbinamenti",,2))
   clc = CInt(InputBox("Quanti cicli di gioco ",,12))
   clp = CInt(InputBox("Quanti colpi di gioco ",,12))
   fin = EstrazioneFin
   ciclo = clc : ciclo = ciclo - 1 ' durata del ciclo di ricerca ripetuti. Non togliere il -1!
   colpi = clp 'colpi di gioco
   aPosta(2) = 1
   For es = ini To fin Step colpi ' analizzo l'archivo a blocchi di 9 estrazioni
      Messaggio es
      Call AvanzamentoElab(ini,fin,es)
      ini1 = es - ciclo ' calcolo l'inizio di ogni nuovo ciclo rispetto ad ogni es analizzata
      kCG = 0 : kAbb = 0 : ktutto = 0' ad ogni nuovo ciclo azzero i contatori
      ReDim aCapoG(0),aAbbin(0),Atutto(0) ' e riazzero gli array prima di ogni ciclo
      For i = 1 To 90 ' verifico la frequenza dei 90 numeri su ogni ciclo
         aNum(1) = i
         If SerieFreqTurbo(ini1,es,aNum,aRuota,1) = sfa Then
            kAbb = kAbb + 1
            ReDim Preserve aAbbin(kAbb)
            aAbbin(kAbb) = i
         Else If SerieFreqTurbo(ini1,es,aNum,aRuota,1) >= sfc Then
            kCG = kCG + 1
            ReDim Preserve aCapoG(kCG)
            aCapoG(kCG) = i
         End If
      End If
   Next
   For ii = 1 To 90
      tutto(1) = ii
      If SerieFreqTurbo(ini1,es,tutto,aRuota,1) >= sfa Then
         ktutto = ktutto + 1
         ReDim Preserve Atutto(ktutto)
         Atutto(ktutto) = ii
      End If
   Next
   If kCG > 0 Then ' se trova almeno un capogioco ovvero un numero con freq>2
      kCasi = kCasi + 1
      Call ColoreTesto(1)
      Call Scrivi
      Call Scrivi(String(80,"-"))
      Call Scrivi("Ricerca su " & SiglaRuota(aRuota(1)) & " ciclo di " & ciclo + 1 & " estrazioni (" & ini1 & "-" & es & ")" & " gioco fino..." & GetInfoEstrazione(es + colpi),1)
      Call Scrivi("Capigioco: " & StringaNumeri(aCapoG) & "    [ " & kCG & " ]",1)
      Call Scrivi("Abbinamenti: " & StringaNumeri(aAbbin) & "   [ " & kAbb & " ] ",1)
      Call Scrivi("Tutti i Numeri: " & StringaNumeri(Atutto) & "   [ " & ktutto & " ] ",1)
      Call Scrivi
      Call ColoreTesto(0)
      kGiocate = 0 ' ad ogni nuova estrazione azzero il contatore delle giocate
      bEsito = False
      For i = 1 To kCG 'imposto le giocate
         aAmbo(1) = aCapoG(i)
         For y = 1 To kAbb
            aAmbo(2) = aAbbin(y)
            'kGiocate = kGiocate + 1
            'Call ImpostaGiocata(kGiocate,aAmbo,aRuota,aPosta,colpi,2)
            Call VerificaEsitoTurbo(aAmbo,aRuota,es + 1,2,colpi,,RetEsito,RetColpi,RetEstratti,retId)
            If RetEsito <> "" Then
               kAmbi = kAmbi + 1
               bEsito = True
               Call Scrivi(Format2(RetColpi) & "°   - " & RetEstratti & " - " & RetEsito & " - " & GetInfoEstrazione(retId),1)
            End If
         Next
      Next
      If bEsito = False Then
         Call Scrivi("Esito negativo")
      Else
         kCasiPos = kCasiPos + 1
      End If
      Scrivi String(80,"-")
      kk = 0
      estra = 0
      ambo = 0
      terno = 0
      For idestr = es + 1 To es + colpi
         kk = kk + 1
         Call VerificaEsitoTurbo(Atutto,aRuota,idestr,1,1,,RetEsito,RetColpi,RetEstratti,retId)
         If RetEsito <> "" Then
            ColoreTesto 0
            If RetEsito = "Estratto" Then estra = estra + 1
            If RetEsito = "Ambo" Then ColoreTesto 2
            If RetEsito = "Ambo" Then ambo = ambo + 1
            If RetEsito = "Terno" Then ColoreTesto 1
            If RetEsito = "Terno" Then terno = terno + 1
            'kk = kk + 1
            Call Scrivi(idestr & " - " & Format2(kk) & "°  - " & RetEstratti & " - " & RetEsito & " - " & GetInfoEstrazione(retId),1)
            'Call Scrivi(idestr & " - " & kk &  "°" & RetEstratti & " - " & RetEsito & " - " & GetInfoEstrazione(retId),1)
            ColoreTesto 0
            'kk = 0
         End If
         'End If
         'kk = 0
      Next
      Scrivi
      Scrivi" Totali Estratto..." & estra & "  ",True,False,0,5,2
      Scrivi" Totali Ambi......." & ambo & "  ",True,False,2,4,2
      Scrivi" Totali Terni......" & terno & "  ",True,True,4,2,2
      'For i = 1 To kGiocate
      '   For y = i + 1 To kGiocate
      '      Call ImpostaInterruzioni(i,y,2)
      '      Call ImpostaInterruzioni(y,i,2)
      '   Next
      'Next
      'Call Gioca(es,True)
   Else
      Call ColoreTesto(2)
      Call Scrivi
      Call Scrivi(String(60,"-"))
      Call Scrivi("Ricerca su " & SiglaRuota(aRuota(1)) & " ciclo di " & ciclo + 1 & " estrazioni (" & ini1 & "-" & es & ")",1)
      Call Scrivi("Nessun superfrequente come CG - Caso non giocabile")
      Call ColoreTesto(0)
   End If
   If ScriptInterrotto Then Exit For
Next
Call Scrivi
Call Scrivi(String(60,"="))
Call Scrivi("Casi giocabili " & kCasi & " di cui positivi " & kCasiPos & " (ambi:" & kAmbi & ")",1)
'Call ScriviResoconto
End Sub


mentre per la ricerca fine a se stessa di cui sopra menzionata la peculiarità, prova anche così-

Codice:
Sub Main
   Dim T,V,Nu(1),Ru(1)
   estr = InputBox("Quante estrazioni Analizzo",,17)
   r = InputBox("Quale Ruota analizzo",,1)
   Ini = EstrazioneFin - estr
   fin = EstrazioneFin
   Tot = fin - Ini + 1
   Scrivi "Presenze Lotto " & nomeruota(r),1,1,,1,3,,1
   Scrivi "Range Inizio  : " & DataEstrazione(Ini)
   Scrivi "Range Fine    : " & DataEstrazione(fin)
   Scrivi "Totali Estraz.: " & Tot
   Scrivi
   T = Array(T,"N.Presenze","Numeri","Q.tà","Ritardo Serie","Verifica","esito")
   Call InitTabella(T)
   For x = 0 To estr
      For n = 1 To 90
         Nu(1) = n
         Ru(1) = r
         If SerieFreq(Ini,fin,Nu,Ru,1) = x Then
            k = k + 1
            ReDim Preserve riga(k)
            riga(k) = n
            sr = SerieRitardo(ini,fin,riga,Ru,1)
            Call VerificaEsito(riga,Ru,EstrazioneFin,1,,,esito,,es1)
         End If
      Next
      If k > 0 Then
         V = Array(V,x,StringaNumeri(riga),k,sr,es1,esito)
         Call AddRigaTabella(V)
      End If
      k = 0
   Next
   Call CreaTabella()
   Scrivi
   Scrivi
   Scrivi "Script By Mike58",1,,,1,2,,1
End Sub
 
Ultima modifica:

Marcorun

Advanced Member >GOLD<
Sono davvero belli.....mi ci divertirò parecchio a studiarli....GRAZIE...VI farò sapere.....Spero un giorno di poter contraccabbiare tutte queste attenzioni...(sarà dura..visto l'alto livello che avete voialtri)....CIAO!!
 

Mike58

Advanced Member >PLATINUM PLUS<
Mentre questi sono i Superfrequenti per ruota su range e frequenza stabilita.

Codice:
Sub Main
   Dim ru(1)
   est = InputBox("Quante estrazioni analizzo",,17)
   freq = CInt(InputBox("Quanti frequenti => a",,3))
   Ini = EstrazioneFin - est
   fin = EstrazioneFin - 1
   fine = EstrazioneFin
   SetColorSezione(6)
   Scrivi "S U P E R . . . .  F R E Q U E N T I ",1,,,1,4,,1
   EndColorSezione
   'Scrivi "S U P E R . . . .  F R E Q U E N T I ",1,,,1,4,,1
   t = Array(t,"Ruota","Numeri","Q.tà","Verifica","Esito")
   Call InitTabella(t)
   For r = 1 To 12
      If r = 11 Then r = 12
      ru(1) = r
      For n = 1 To 90
         'For p = 1 To 5
         'a = Estratto(es,r,p)
         b = EstrattoFrequenzaTurbo(r,n,Ini,fin)
         c = EstrattoRitardoTurbo(r,n,Ini,fin)
         If b >= freq And c > 0 Then
            k = k + 1
            ReDim Preserve aNum(k)
            aNum(k) = n
            ReDim Preserve fre(k)
            fre(k) = b
            ReDim Preserve rit(k)
            rit(k) = c
         End If
         'Next
      Next
      Call VerificaEsito(aNum,ru,fine,1,1,,esito,,es1)
      v = Array(v,SiglaRuota(r),StringaNumeri(aNum,,1),k,es1,esito)
      vv = Array(vv,"Freq",StringaNumeri(fre,,1),"-","--","--")
      vvv = Array(vvv,"Rit",StringaNumeri(rit,,1),"-","--","--")
      vuoto = Array(vuoto,"","","","","","")
      Call AddRigaTabella(v)
      Call AddRigaTabella(vv,,,,1)
      Call AddRigaTabella(vvv,,,,2)
      Call AddRigaTabella(vuoto,3,,1)
      'Scrivi SiglaRuota(r) & vbTab & StringaNumeri(aNum,,1) & vbTab & k
      k = 0
   Next
   CreaTabella
End Sub

buon studio.

Ciao
 

Mike58

Advanced Member >PLATINUM PLUS<
Ciao Carissimo Marco nessun alto livello, solo applicazione, curiosità e voglia di fare e di imparare.
Il tutto è anche una buona palestra per la mente.
 

Marcorun

Advanced Member >GOLD<
Quanta roba!!!...piatto ricco mi ci ficco!!....io è una vita che studio ...ma da quando sono in questo forum,credo di essere salito di un piccolo livello...grazie soprattutto alla vostra collaborazione..........ringrazio anche SALVO.
 

Ultima estrazione Lotto

  • Estrazione del lotto
    martedì 26 marzo 2024
    Bari
    30
    51
    17
    01
    53
    Cagliari
    13
    70
    25
    68
    47
    Firenze
    28
    30
    54
    70
    88
    Genova
    67
    87
    22
    03
    62
    Milano
    22
    34
    13
    47
    24
    Napoli
    20
    72
    59
    01
    52
    Palermo
    05
    72
    65
    52
    32
    Roma
    28
    43
    75
    54
    87
    Torino
    16
    08
    17
    24
    38
    Venezia
    67
    28
    55
    60
    29
    Nazionale
    15
    69
    22
    63
    39
    Estrazione Simbolotto
    Firenze
    44
    09
    31
    22
    16
Alto