Novità

metodo delle triple di cadenza di Ron Colman

purtroppo il "segreto" su come giocare proficuamente al gioco del lotto non è custodito in nessun libro , con le attuali regole impostare il gioco come fosse un lavoro porterebbe di sicuro alla rovina , ci si potrebbe salvare solo azzeccando per fortuna una bella quaterna o cinquina secca , in tutti gli altri casi si perde con certezza matematica e questo grazie proprio alle regole fissate dal gioco.
Ad ogni modo se il punto non era trovare i numeri da giocare bensi si doveva focalizzare sul metodo di gioco e sulla gestione delle puntate si poteva evitare di mettere 7 pagine sul metodo e spiegare meglio il resto ...
ciao
 
Ultima modifica di un moderatore:
E' dal primo post che dico che secondo me la bontà di questo metodo sta nel recupero delle puntate perse.
Lo sviluppo del metodo richiede una grande quantità di giocate . le triple di figura e di cadenza ci danno questa garanzia.
Sergio
 
Volevo chiedere a LuigiB, bontà sua, se poteva aggiungere nel listato la possibilità di scegliere da quando fare partire la ricerca ed eventualmente inserire la possibilità di stampare le giocate da fare con le rispettive puntate.
Lo so che hai scritto "STOP RICHIESTE" ma ci provo lo stesso.

Grazie

Sergio
 
Volevo chiedere se un volenteroso poteva aggiungere nell'ultimo listato postato da LuigiB, la possibilità di scegliere da quando fare partire la ricerca ed eventualmente inserire la possibilità di stampare le giocate da fare con le rispettive puntate.
Grazie

Sergio
 
aiuto per uno script

aiuto per uno script

sergio1954 ha scritto:
Volevo chiedere se un volenteroso poteva aggiungere nell'ultimo listato postato da LuigiB, la possibilità di scegliere da quando fare partire la ricerca ed eventualmente inserire la possibilità di stampare le giocate da fare con le rispettive puntate.
Grazie

Sergio
Clicca per espandere...

Proprio nessuno mi vuole dare un'aiuto ?
 
ciao , ho riguardato brevemente lo script
Codice: 
Inizio = EstrazioneIni
Fine = EstrazioneFin

le due righe sopra dimostrano che il range di analisi si imposta con la barra rosa in basso .. cioè usa il range principale del programma.
Scusami se non te lo faccio io ma il mio compito per usare una metafora non è pescare ma insegnare a farlo ...
se ogni tanto faccio uno script oltre che per mio passatempo è anche per far vedere come si fa

un saluto
 
modifica script

modifica script

LuigiB ha scritto:
ciao , ho riguardato brevemente lo script
Codice: 
Inizio = EstrazioneIni
Fine = EstrazioneFin

le due righe sopra dimostrano che il range di analisi si imposta con la barra rosa in basso .. cioè usa il range principale del programma.
Scusami se non te lo faccio io ma il mio compito per usare una metafora non è pescare ma insegnare a farlo ...
se ogni tanto faccio uno script oltre che per mio passatempo è anche per far vedere come si fa

un saluto
Clicca per espandere...

Grazie LuigiB pe l'indicazione, magari si potesse fare con un "box".
Poi il discorso della stampa dei numeri da giocare con i rispettivi importi ?
Per me è una cosa complicata . Te sicuramente ci metti 5 minuti.

Ciao.

Sergio
 
disaronno ha scritto:
Buongiorno,
Rinnovando il consiglio di LuigiB, che saluto ed auguro a lui e a tutti gli Auguri, di utilizzare la barra rosa per decidere l' intervallo di scelta delle estrazioni.
Riquardo a stampa schedine , apra Spaziometria in alto Utility , menù a tendina Stampa Schedine
Allego il listato modificato.
Codice: 
    Option Explicit
Class clsGruppoCombInGioco
    Private m_EstrazioneInizio
    Private m_EstrazioneInizioGioco
    Private collCombinazioni
    Sub Class_Initialize
        ' codice
        Set collCombinazioni = GetNewCollection
        m_EstrazioneInizio = 0
        m_EstrazioneInizioGioco = 0
    End Sub
    Sub Class_Terminate
        ' codice
        ' codice
    End Sub
    Public Property Get EstrazioneInizio
        EstrazioneInizio = m_EstrazioneInizio
    End Property
    Public Property Let EstrazioneInizio(NewValue)
        m_EstrazioneInizio = NewValue
    End Property
    Public Property Get EstrazioneInizioGioco
        EstrazioneInizioGioco = m_EstrazioneInizioGioco
    End Property
    Public Property Let EstrazioneInizioGioco(NewValue)
        m_EstrazioneInizioGioco = NewValue
    End Property
    Public Property Get Combinazioni
        Set Combinazioni = collCombinazioni
    End Property
    Sub AddTripla(classeTripla)
        collCombinazioni.Add classeTripla
    End Sub
End Class
Class clsTripla
    Dim cEstrazioniRitroso
    Private aNumeri()
    Private abNumInGioco()
    Private m_Ruota
    Private m_NumeroBase
    Private m_PrimoNumeroTrovatoIndietro
    Private m_IdEstrPrimoNumeroTrovatoIndietro
    Private m_IdEstrEsito
    Private m_NumUsciti
    Private m_Scartata
    Sub Class_Initialize
        ' codice
        ReDim abNumInGioco(90)
        m_IdEstrEsito = 0
        m_NumUsciti = ""
        m_PrimoNumeroTrovatoIndietro = ""
        m_IdEstrPrimoNumeroTrovatoIndietro = 0
        m_Scartata = False
        cEstrazioniRitroso = 20
    End Sub
    Sub Class_Terminate
        ' codice
    End Sub
    Public Property Get Ruota
        Ruota = m_Ruota
    End Property
    Public Property Let Ruota(NewValue)
        m_Ruota = NewValue
    End Property
    Public Property Get NumeroBase
        NumeroBase = m_NumeroBase
    End Property
    Public Property Let NumeroBase(NewValue)
        m_NumeroBase = NewValue
    End Property
    Public Property Get Scartata
        Scartata = m_Scartata
    End Property
    Public Property Let Scartata(NewValue)
        m_Scartata = NewValue
    End Property
    Public Property Get IdEstrEsito
        IdEstrEsito = m_IdEstrEsito
    End Property
    Public Property Get PrimoNumeroTrovatoIndietro
        PrimoNumeroTrovatoIndietro = m_PrimoNumeroTrovatoIndietro
    End Property
    Public Property Get IdEstrPrimoNumeroTrovatoIndietro
        IdEstrPrimoNumeroTrovatoIndietro = m_IdEstrPrimoNumeroTrovatoIndietro
    End Property
    Public Property Get NumUsciti
        NumUsciti = m_NumUsciti
    End Property
    Public Property Get NumeriInGioco
        NumeriInGioco = ArrayBToString(abNumInGioco)
    End Property
    Sub SetNumeri(aNum)
        Dim k
        ReDim aNumeri(UBound(aNum))
        For k = 1 To UBound(aNum)
            aNumeri(k) = aNum(k)
        Next
    End Sub
    Sub IndividuaCoppiaDaGiocare(idEstrInizio)
        Dim k,e,nLottrone,nTrovati
        ReDim abNum(90)
        nTrovati = 0
        m_PrimoNumeroTrovatoIndietro = ""
        Call ArrayNumToArrayBNum(aNumeri,abNum)
        For k = idEstrInizio - 1 To idEstrInizio - cEstrazioniRitroso Step - 1
            For e = 1 To 5
                nLottrone = Estratto(k,m_Ruota,e)
                If nLottrone <> m_NumeroBase Then
                    If abNum(nLottrone) Then
                        abNum(nLottrone) = False
                        m_PrimoNumeroTrovatoIndietro = m_PrimoNumeroTrovatoIndietro & nLottrone & " "
                        m_IdEstrPrimoNumeroTrovatoIndietro = k
                        nTrovati = nTrovati + 1
                    End If
                End If
            Next
            If nTrovati > 0 Then
                Exit For
            End If
        Next
        If nTrovati = 0 Then
            ' non ha trovato nessuno dei due
            abNum(m_NumeroBase) = False
        ElseIf nTrovati = 2 Then
            ' li ha trovati tutti e due nella stessa estr
            ReDim abNum(90)
            For k = 1 To UBound(aNumeri)
                If aNumeri(k) <> m_NumeroBase Then
                    abNum(aNumeri(k)) = True
                End If
            Next
        End If
        Call CopiaArray(abNum,abNumInGioco)
    End Sub
    Sub Verifica(idEstr)
        Dim e,nLottrone
        m_NumUsciti = ""
        For e = 1 To 5
            nLottrone = Estratto(idEstr,m_Ruota,e)
            If abNumInGioco(nLottrone) Then
                m_NumUsciti = m_NumUsciti & nLottrone & " "
                m_IdEstrEsito = idEstr
            End If
        Next
    End Sub
    Function GetNumeriInGioco(aRetNum)
        Dim k,nTrov
        ReDim aRetNum(0)
        nTrov = 0
        For k = 1 To 90
            If abNumInGioco(k) Then
                nTrov = nTrov + 1
                ReDim Preserve aRetNum(nTrov)
                aRetNum(nTrov) = k
            End If
        Next
    End Function
End Class
Sub Main
    Dim cColpiMax
    Dim idEstr,e,k,nLottrone
    Dim EP,Inizio,Fine
    Dim GruppoCombInGioco
    Dim Tripla
    Dim nColpi
    Dim MatriceImporti
    ReDim aRuote(0)
    Dim nTipoAnalisi
    Dim nGiocateTotali
    Dim nEsitiPositivi
    Dim nQCombDaAspettare
    Dim nQRuoteDaUsare
    Dim nCombMaxPossibili
    Call LeggiMatriceProgressione(MatriceImporti)
    EP = CInt(InputBox("Quante Estrazioni Controll0",,EstrazioneFin))
    Inizio = EstrazioneFin - EP
    Fine = EstrazioneFin
    nTipoAnalisi = ScegliTipoAnalisi
    nQRuoteDaUsare = Int(InputBox("Quante ruote usare","Quantità ruote","2"))
    nCombMaxPossibili = nQRuoteDaUsare * 5 * 2
    nQCombDaAspettare = Int(InputBox("Quante cmbinazioni aspettare su " & nCombMaxPossibili & " prima di giocare ?","Quantità combinazioni da aspettare",Int(nCombMaxPossibili /2)))
    cColpiMax = 47
    cColpiMax = Int(InputBox("Inserire i colpi di gioco da 1 a 47","Colpi",cColpiMax))
    idEstr = Inizio
    If nTipoAnalisi < 0 Or nTipoAnalisi > 1 Then
        MsgBox "Tipo analisi non valido"
        Exit Sub
    End If
    If cColpiMax <= 0 Or cColpiMax > 47 Then
        MsgBox "Colpi massimi non validi"
        Exit Sub
    End If
    If nQCombDaAspettare >= nCombMaxPossibili Then
        MsgBox "Quantità di combinazioni da aspettare errata"
        Exit Sub
    End If
    If nQRuoteDaUsare <= 0 Or nQRuoteDaUsare > 11 Then
        MsgBox "Quantità di ruote errata"
        Exit Sub
    End If
    If ScegliRuote(aRuote) = nQRuoteDaUsare Then
        ReDim Preserve aRuote(nQRuoteDaUsare)
        Do
            If VerificaCadenzeDiverse(idEstr,aRuote) And VerificaFigureDiverse(idEstr,aRuote) Then
                Set GruppoCombInGioco = New clsGruppoCombInGioco
                GruppoCombInGioco.EstrazioneInizio = idEstr
                For k = 1 To UBound(aRuote)
                    For e = 1 To 5
                        nLottrone = Estratto(idEstr,aRuote(k),e)
                        Set Tripla = New clsTripla
                        ReDim aN(0)
                        Call GetTriplaCadenzaByNum(nLottrone,aN)
                        Call Tripla.SetNumeri(aN)
                        Tripla.Ruota = aRuote(k)
                        Tripla.NumeroBase = nLottrone
                        Call Tripla.IndividuaCoppiaDaGiocare(idEstr)
                        Call GruppoCombInGioco.AddTripla(Tripla)
                        Set Tripla = New clsTripla
                        ReDim aN(0)
                        Call GetTriplaFiguraByNum(nLottrone,aN)
                        Call Tripla.SetNumeri(aN)
                        Tripla.Ruota = aRuote(k)
                        Tripla.NumeroBase = nLottrone
                        Call Tripla.IndividuaCoppiaDaGiocare(idEstr)
                        Call GruppoCombInGioco.AddTripla(Tripla)
                    Next
                Next
                Do
                    idEstr = idEstr + 1
                    For Each Tripla In GruppoCombInGioco.Combinazioni
                        If Tripla.Scartata = False Then
                            Call Tripla.Verifica(idEstr)
                            If Tripla.idEstrEsito <> 0 Then
                                Tripla.Scartata = True
                            End If
                        End If
                    Next
                    If idEstr >= Fine Then Exit Do
                Loop While ContaCombSortite(GruppoCombInGioco) < nQCombDaAspettare
                nGiocateTotali = nGiocateTotali + ContaCombNonSortite(GruppoCombInGioco)
                GruppoCombInGioco.EstrazioneInizioGioco = idEstr + 1
                nColpi = 0
                Do
                    idEstr = idEstr + 1
                    For Each Tripla In GruppoCombInGioco.Combinazioni
                        If Tripla.idEstrEsito = 0 Then
                            Call Tripla.Verifica(idEstr)
                            If Tripla.idEstresito <> 0 Then
                                nEsitiPositivi = nEsitiPositivi + 1
                            End If
                        End If
                    Next
                    nColpi = nColpi + 1
                    If nColpi = cColpiMax Then
                        Exit Do
                    End If
                    If idEstr >= Fine Then Exit Do
                Loop While ContaCombSortite(GruppoCombInGioco) < nCombMaxPossibili
                If GruppoCombInGioco.EstrazioneInizioGioco > 0 Then Call ScriviProspetto(GruppoCombInGioco)
                If nTipoAnalisi = 1 Then
                    If GruppoCombInGioco.EstrazioneInizioGioco > 0 Then
                        If idEstr <= Fine Then Call GiocaCombinazioni(GruppoCombInGioco,cColpiMax,aRuote,MatriceImporti)
                    End If
                End If
            Else
                idEstr = idEstr + 1
            End If
            Call Messaggio("Estrazione " & idEstr)
            Call AvanzamentoElab(Inizio,Fine,idEstr)
            If ScriptInterrotto Then Exit Do
        Loop While idEstr < Fine
        Call Scrivi
        Call Scrivi(String(100,"*"))
        Call Scrivi("Giocate totali                           : " & nGiocateTotali)
        Call Scrivi("Giocate con esito entro i colpi previsti : " & nEsitiPositivi & " (" & ProporzioneX(nEsitiPositivi,nGiocateTotali,100) & "%)")
        Call Scrivi
        Call Scrivi(String(100,"*"))
        If nTipoAnalisi = 1 Then Call ScriviResoconto
    Else
        MsgBox "Il metodo prevede di selezionare " & nQRuoteDaUsare & "ruote"
    End If
End Sub
Function ScegliTipoAnalisi
    ReDim aV(2)
    aV(0) = "Ricerca combinazioni"
    aV(1) = "Ricerca combinazioni + Simulazione giocate"
    ScegliTipoAnalisi = ScegliOpzioneMenu(aV,0)
End Function
Sub GetTriplaCadenzaByNum(n,aRetNum)
    Dim k
    ReDim aRetNum(3)
    If n >= 1 And n <= 30 Then
        aRetNum(1) = n
        aRetNum(2) = n + 30
        aRetNum(3) = n + 60
    ElseIf n >= 31 And n <= 60 Then
        aRetNum(1) = n - 30
        aRetNum(2) = n
        aRetNum(3) = n + 30
    ElseIf n >= 61 And n <= 90 Then
        aRetNum(1) = n - 60
        aRetNum(2) = n - 30
        aRetNum(3) = n
    End If
End Sub
Sub GetTriplaFiguraByNum(n,aRetNum)
    Dim k
    ReDim aRetNum(3)
    If n >= 1 And n <= 24 Then
        aRetNum(1) = n
        aRetNum(2) = n + 33
        aRetNum(3) = n + 66
    ElseIf n >= 25 And n <= 27 Then
        aRetNum(1) = n
        aRetNum(2) = n + 3
        aRetNum(3) = n + 6
    ElseIf n >= 28 And n <= 30 Then
        aRetNum(1) = n - 3
        aRetNum(2) = n
        aRetNum(3) = n + 3
    ElseIf n >= 31 And n <= 33 Then
        aRetNum(1) = n - 6
        aRetNum(2) = n - 3
        aRetNum(3) = n
    ElseIf n >= 34 And n <= 57 Then
        aRetNum(1) = n - 33
        aRetNum(2) = n
        aRetNum(3) = n + 33
    ElseIf n >= 58 And n <= 60 Then
        aRetNum(1) = n
        aRetNum(2) = n + 3
        aRetNum(3) = n + 6
    ElseIf n >= 61 And n <= 63 Then
        aRetNum(1) = n - 3
        aRetNum(2) = n
        aRetNum(3) = n + 3
    ElseIf n >= 64 And n <= 66 Then
        aRetNum(1) = n - 6
        aRetNum(2) = n - 3
        aRetNum(3) = n
    ElseIf n >= 67 And n <= 90 Then
        aRetNum(1) = n - 66
        aRetNum(2) = n - 33
        aRetNum(3) = n
    End If
End Sub
Function VerificaCadenzeDiverse(idEstr,aRuote)
    Dim e,k,n,bRet,nLottrone
    bRet = True
    For k = 1 To UBound(aRuote)
        ReDim ab(30)
        For e = 1 To 5
            nLottrone = Estratto(idEstr,aRuote(k),e)
            ReDim aNum(0)
            Call GetTriplaCadenzaByNum(nLottrone,aNum)
            ab(aNum(1)) = True
        Next
        If ContaNumeriInArrayB(ab) <> 5 Then
            bRet = False
            Exit For
        End If
    Next
    VerificaCadenzeDiverse = bRet
End Function
Function VerificaFigureDiverse(idEstr,aRuote)
    Dim e,k,n,bRet,nLottrone
    bRet = True
    For k = 1 To UBound(aRuote)
        ReDim ab(90)
        For e = 1 To 5
            nLottrone = Estratto(idEstr,aRuote(k),e)
            ReDim aNum(0)
            Call GetTriplaFiguraByNum(nLottrone,aNum)
            ab(aNum(1)) = True
        Next
        If ContaNumeriInArrayB(ab) <> 5 Then
            bRet = False
            Exit For
        End If
    Next
    VerificaFigureDiverse = bRet
End Function
Function ContaNumeriInArrayB(aB)
    Dim k,n
    n = 0
    For k = LBound(aB) To UBound(aB)
        If aB(k) Then n = n + 1
    Next
    ContaNumeriInArrayB = n
End Function
Function ContaCombSortite(GruppoCombInGioco)
    Dim tripla,n
    n = 0
    For Each tripla In GruppoCombInGioco.Combinazioni
        If Tripla.IdEstrEsito <> 0 Then
            n = n + 1
        End If
    Next
    ContaCombSortite = n
End Function
Function ContaCombNonSortite(GruppoCombInGioco)
    Dim tripla,n
    n = 0
    For Each tripla In GruppoCombInGioco.Combinazioni
        If Tripla.IdEstrEsito = 0 Then
            n = n + 1
        End If
    Next
    ContaCombNonSortite = n
End Function
Sub ScriviProspetto(GruppoCombInGioco)
    Dim Tripla
    ReDim aV(12)
    aV(1) = "Anno"
    aV(2) = "N°Estr"
    aV(3) = "Ruota"
    aV(4) = "Numero Base"
    aV(5) = "Uscite Prec"
    aV(6) = "Coppia in gioco"
    aV(7) = "Sortiti"
    aV(8) = "N°Estr"
    aV(9) = "Colpi"
    aV(10) = "Inizio gioco"
    aV(11) = "N°Estr"
    aV(12) = "Colpi"
    Call InitTabella(aV)
    For Each Tripla In GruppoCombInGioco.Combinazioni
        ReDim aV(12)
        aV(1) = Anno(GruppoCombInGioco.EstrazioneInizio)
        aV(2) = IndiceAnnuale(GruppoCombInGioco.EstrazioneInizio)
        aV(3) = SiglaRuota(Tripla.Ruota)
        aV(4) = Tripla.NumeroBase
        aV(5) = Tripla.PrimoNumeroTrovatoIndietro
        aV(6) = Tripla.NumeriInGioco
        aV(7) = Tripla.NumUsciti
        If Tripla.Scartata Then
            aV(8) = IndiceAnnuale(Tripla.IdEstrEsito)
            aV(9) =(Tripla.IdEstrEsito) - GruppoCombInGioco.EstrazioneInizio
        Else
            aV(10) = IndiceAnnuale(GruppoCombInGioco.EstrazioneInizioGioco)
            If Tripla.IdEstrEsito > 0 Then
                aV(11) = IndiceAnnuale(Tripla.IdEstrEsito)
                aV(12) =(Tripla.IdEstrEsito + 1) - GruppoCombInGioco.EstrazioneInizioGioco
            Else
                aV(11) = "-"
                aV(12) = "-"
            End If
        End If
        Call AddRigaTabella(aV)
    Next
    Call CreaTabella
End Sub
Sub GiocaCombinazioni(GruppoCombInGioco,cColpiMax,aRuote,MatriceImporti)
    Dim Tripla,k
    ReDim aNumInGioco(1)
    ReDim aRuota(1)
    ReDim aPoste(1)
    Dim idGiocata
    ReDim aGiocateDaInterr(1)
    For Each Tripla In GruppoCombInGioco.Combinazioni
        If Tripla.Scartata = False Then
            aRuota(1) = Tripla.Ruota
            ReDim aNumInGiocoTmp(0)
            Call Tripla.GetNumeriInGioco(aNumInGiocoTmp)
            For k = 1 To UBound(aNumInGiocoTmp)
                aNumInGioco(1) = aNumInGiocoTmp(k)
                idGiocata = idGiocata + 1
                If k = 1 Then
                    aGiocateDaInterr(1) = idGiocata + 1
                ElseIf k = 2 Then
                    aGiocateDaInterr(1) = idGiocata - 1
                End If
                Call ImpostaGiocata(idGiocata,aNumInGioco,aRuota,aPoste,cColpiMax,1,,aGiocateDaInterr)
                Call ImpostaProgressione(idGiocata,MatriceImporti)
            Next
            'Call Gioca(GruppoCombInGioco.EstrazioneInizioGioco)
        End If
    Next
    Call Gioca(GruppoCombInGioco.EstrazioneInizioGioco)
End Sub
Sub LeggiMatriceProgressione(aProgressioni)
    ReDim aProgressioni(10,255) ' preparo la matrice per leggere gli Importi di gioco
    aProgressioni(1,1) = 1.00
    aProgressioni(1,2) = 1.00
    aProgressioni(1,3) = 1.00
    aProgressioni(1,4) = 1.00
    aProgressioni(1,5) = 1.50
    aProgressioni(1,6) = 1.50
    aProgressioni(1,7) = 2.00
    aProgressioni(1,8) = 2.50
    aProgressioni(1,9) = 3.00
    aProgressioni(1,10) = 4.00
    aProgressioni(1,11) = 5.00
    aProgressioni(1,12) = 6.50
    aProgressioni(1,13) = 8.00
    aProgressioni(1,14) = 10.00
    aProgressioni(1,15) = 12.50
    aProgressioni(1,16) = 16.00
    aProgressioni(1,17) = 20.00
    aProgressioni(1,18) = 25.00
    aProgressioni(1,19) = 31.50
    aProgressioni(1,20) = 39.50
    aProgressioni(1,21) = 50.00
    aProgressioni(1,22) = 62.50
    aProgressioni(1,23) = 78.50
    aProgressioni(1,24) = 99.00
    aProgressioni(1,25) = 124.50
    aProgressioni(1,26) = 156.50
    aProgressioni(1,27) = 196.50
    aProgressioni(1,28) = 247.00
    aProgressioni(1,29) = 310.50
    aProgressioni(1,30) = 390.50
    aProgressioni(1,31) = 491.00
    aProgressioni(1,32) = 617.50
    aProgressioni(1,33) = 776.00
    aProgressioni(1,34) = 975.50
    aProgressioni(1,35) = 1226.50
    aProgressioni(1,36) = 1542.00
    aProgressioni(1,37) = 1938.50
    aProgressioni(1,38) = 2437.00
    aProgressioni(1,39) = 3064.00
    aProgressioni(1,40) = 3852.00
    aProgressioni(1,41) = 4843.00
    aProgressioni(1,42) = 6088.50
    aProgressioni(1,43) = 7654.50
    aProgressioni(1,44) = 9623.00
    aProgressioni(1,45) = 12098.00
    aProgressioni(1,46) = 15210.00
    aProgressioni(1,47) = 19122.00
End Sub
Clicca per espandere...

Buonasera a tutti

Grazie disaronno e Grazie luigiB per la pillola di saggezza.
Colgo l'occasione per fare gli Auguri a Voi e a tutti i frequentatori di questo simpatico sito.
Che la forza sia con Voi.

Sergio
 
sergio1954 ha scritto:
Buonasera a tutti

Grazie disaronno e Grazie luigiB per la pillola di saggezza.
Colgo l'occasione per fare gli Auguri a Voi e a tutti i frequentatori di questo simpatico sito.
Che la forza sia con Voi.

Sergio
Clicca per espandere...

Buonasera a tutti,

Vorrei che qualche volenteroso implementasse il listato con la seguente variante:

-La giocata che non ha vinto entro il colpo impostato, ritorna a puntare la quota del 1° colpo.
-La perdita causata dalla non vincita viene recuperata da un numero di giocate in corso( esempio 10)
-Le dieci giocate individuate oltre a puntare le rispettive quote si suddividono la perdita*

*La perdita viene divisa per 10 e la puntata sarrà aumentata in modo tale che in caso di vincita si recuperi anche la decima parte della perdita.

Spero di essere stato abbastanza chiaro.

Grazie
Sergio
 
sergio1954 ha scritto:
Buonasera a tutti,

Vorrei che qualche volenteroso implementasse il listato con la seguente variante:

-La giocata che non ha vinto entro il colpo impostato, ritorna a puntare la quota del 1° colpo.
-La perdita causata dalla non vincita viene recuperata da un numero di giocate in corso( esempio 10)
-Le dieci giocate individuate oltre a puntare le rispettive quote si suddividono la perdita*

*La perdita viene divisa per 10 e la puntata sarrà aumentata in modo tale che in caso di vincita si recuperi anche la decima parte della perdita.

Spero di essere stato abbastanza chiaro.

Grazie
Sergio
Clicca per espandere...


oè oè oè nonc'è nessuno

Sergio
 
guarda non te ne avere a male se non viene nessuno ad aiutarti la cosa che chiedi è complessa ,io non sono interessato ne ai giochi ne agli studi ma se volessi implementarla dovrei applicarmi parecchio pure io e probabilemte dovrei chiederti altre cose .. temo che rimarrai cosi
un saluto
 
LuigiB ha scritto:
guarda non te ne avere a male se non viene nessuno ad aiutarti la cosa che chiedi è complessa ,io non sono interessato ne ai giochi ne agli studi ma se volessi implementarla dovrei applicarmi parecchio pure io e probabilemte dovrei chiederti altre cose .. temo che rimarrai cosi
un saluto
Clicca per espandere...

Buongiorno ,

Stai "sereno" non sono permaloso.
Sinceramente mi rimane difficile pensare che la variante richiesta sia cosi complicata.
In modo particolare per persone come te che hanno una certa dimestichezza con il programma.
Comumque ho capito.

un saluto.

Sergio
 
chi ha mai parlato di permalosità d'altra parte non capisco come fai a valutare la complessità di una cosa se non sei capace di farla ....ciao
 
LuigiB ha scritto:
chi ha mai parlato di permalosità d'altra parte non capisco come fai a valutare la complessità di una cosa se non sei capace di farla ....ciao
Clicca per espandere...

Salve,

Dalle mie parti "chi se la prende" è permaloso.
Relativamente alla "complessità" io mi confronto appunto con quello che fai tu che io non saprei fare ma che tu fai con disinvoltura o no?.

Colgo l'occasione per fare a te e tutti i frequentatori del forum ,i più sinceri Auguri di un Felice Anno Nuovo.

Ciao

Sergio
 
un meccanico ad esempio puo stringere con disinvoltura una vite ma se deve montare un pistone deve impegnarsi ... giusto per fare una metafora ..
 
LuigiB ha scritto:
un meccanico ad esempio puo stringere con disinvoltura una vite ma se deve montare un pistone deve impegnarsi ... giusto per fare una metafora ..[/QUOT

Buongiorno ,

Volevo chiedere (sempre a chiudere questo !!!) se sull'ultimo listato di LuigiB si poteva inserire alcune linee di programma.
Il risultato dovrebbe essere una tabella riassuntiva con le seguenti indicazioni:
- numeri da giocare
- colpo di gioco
- puntata
- ruota
- numeri non usciti con relativa perdita.

PS: LuigiB tu non sei un semplice meccanico ma un meccanico specializzato

Grazie

Sergio
Clicca per espandere...
 
sergio1954 ha scritto:
LuigiB ha scritto:
un meccanico ad esempio puo stringere con disinvoltura una vite ma se deve montare un pistone deve impegnarsi ... giusto per fare una metafora ..[/QUOT

Buongiorno ,

Volevo chiedere (sempre a chiudere questo !!!) se sull'ultimo listato di LuigiB si poteva inserire alcune linee di programma.
Il risultato dovrebbe essere una tabella riassuntiva con le seguenti indicazioni:
- numeri da giocare
- colpo di gioco
- puntata
- ruota
- numeri non usciti con relativa perdita.

PS: LuigiB tu non sei un semplice meccanico ma un meccanico specializzato

Grazie

Buonasera ,

Qualcuno mi pui aiutare ad inserire nel listato questa riga di comando:
"AddRecordAgendaGiocate"

Grazie

Sergio

Sergio
Clicca per espandere...
Clicca per espandere...
 
Devi accedere o registrarti per poter rispondere.

Ultima estrazione Lotto

  • Estrazione del lotto
    martedì 21 gennaio 2025
    Bari
    78
    09
    70
    03
    23
    Cagliari
    32
    88
    30
    13
    45
    Firenze
    87
    23
    15
    39
    86
    Genova
    71
    48
    67
    59
    23
    Milano
    58
    50
    80
    85
    29
    Napoli
    90
    81
    79
    82
    62
    Palermo
    70
    33
    90
    05
    10
    Roma
    15
    71
    55
    85
    76
    Torino
    89
    09
    18
    33
    69
    Venezia
    44
    80
    82
    73
    58
    Nazionale
    80
    25
    13
    63
    17
    Estrazione Simbolotto
    Bari
    39
    36
    34
    14
    31
    Archivio estrazioni lotto Ritardi top 15 Frequenze top 15

Ultimi Messaggi

Indietro
Alto