Novità

Se possibile..

toon

Advanced Member
Vorrei la modifica per fare la ricerca su 3 ruote o più..
Grazie in anticipo a chi mi può aiutare..
Purtroppo non ho a disposizione tutte le opzioni per esporre meglio la discussione..

Sub Main()
Scrivi " Terni su più ruote con ritardo all'ultima estrazione ",1,,4,,3
Dim rt(12),ru(12),nu(3),N3(3)
Qes = InputBox("Quante estrazioni vuoi controllare?","Estrazioni",1000)
Fin = EstrazioneFin
Ini = Fin - Qes
For es = ini To fin
AvanzamentoElab Ini,fin,es
Messaggio "TERNO : " & a & "-" & b & "-" & c
For r1 = 1 To 10
For p1 = 1 To 3
For p2 = p1 + 1 To 4
For p3 = p2 + 1 To 5
a = Estratto(es,r1,p1): b = Estratto(es,r1,p2):c = Estratto(es,r1,p3)
nu(1) = a : nu(2) = b : nu(3) = c : terno = 0
For r2 = r1 + 1 To 12
If r2 <> 11 Then
ru(1) = r2
If r1 <> r2 Then
terno = SerieFreq(es,es,nu,ru,3)
If terno > 0 Then
ColoreTesto 0
Tot = EstrazioneFin - es
Scrivi String(72,"-"):Scrivi
Scrivi "Estrazione del " & DataEstrazione(es),1,0
Scrivi Space(4) & FormatSpace(NomeRuota(r1),10) & FormatSpace(NomeRuota(r2),10) & StringaNumeri(nu) & " Ritardo " & tot,1
N3(1) = a : N3(2) = b : N3(3) = c
rt(1) = r1 : rt(2) = r2 : ColoreTesto 2
If VerificaEsito(N3,rt,es + 1,2,Tot,,RetEsito,RetColpi,RetEstratti,RetIdEstr)Then
Call Scrivi(GetInfoEstrazione(RetIdEstr) & Space(4) & RetEsito & Space(4) & " colpo : " & " " & RetColpi & Space(4) & RetEstratti)
Else
Scrivi "Non ancora sortito - Colpo : " & Tot,1,,,1
ColoreTesto 0 : Scrivi
End If
End If
End If
End If
Next
Next
Next
Next
Next
Next
End Sub
 

i legend

Premium Member
Ciao , credo che se cerchi qui in area download questo script dovrebbe essere già stato realizzato .Non ricordo quanto tempo fa mi spiace.
 
Ultima modifica:

toon

Advanced Member
in effetti è uno script di NIKOR come ho potuto verificare da tua indicazione..
Io però volevo effettuare la ricerca statistica su più di due ruote, spero che qualche volontario mi possa
aggiungere questa possibilità..
Grazie mille..
 

i legend

Premium Member
Ciao toon
Ho fatto lo script
Dal 3950 non mi risultano terni ripetuti su 3 ruote nella stessa estrazione .
Ammesso di non aver fatto errori e aver l archivio corretto.
Mi risultano 5 quaterne su 2 ruote .
Purtroppo l ho script è andato mi si è staccata la batteria.
Se riesco lo riscrivo domani.
 

toon

Advanced Member
Grazie mille , se riesci mi fai un grandissimo favore, anche perchè così riesco a capire meglio i miei errori negli script, ci avevo provato, ma mi dava continuamente errori. Sei sempre molto disponibile e gentile..

Non capisco perchè non ho tutte le opzioni come prima per scrivere sul forum...Booo
 

i legend

Premium Member
ciao toon lo script che hai postato è valido e anche abbastanza veloce ,non ho trovato terni ripetuti su piu due ruote.
Dalla 3950 si o ad oggi ma potrei sbagliare.
Ciao :)
 

i legend

Premium Member
Ciao toon ,non si può fare una statica perché al momento non ho rilevato lo stesso terno su più di due ruote.
Lo script che hai in ogni caso funzia pervhe nella stessa data segnalerebbe le tre combinazioni r1.r2 r1.r3.r2.r3
 

salvo50

Advanced Member >PLATINUM PLUS<
Ciao a Tutti.

Ciao ILegend, Toon,

Di scegliere in quale ruote fare la verifica, mi sono incasinato pure io, però ho fatto di fare la verifica su tutte le ruote e la nazionale, vedi se può andare


Codice:
Sub Main()
   Scrivi " Terni su più ruote con ritardo all'ultima estrazione ",1,,4,,3
   Dim rt(12),ru(12),nu(3),N3(3)
   Qes = InputBox("Quante estrazioni vuoi controllare?","Estrazioni",1000)
   Fin = EstrazioneFin
   Ini = Fin - Qes
   For es = ini To fin
      AvanzamentoElab Ini,fin,es
      Messaggio "TERNO : " & a & "-" & b & "-" & c
      For r1 = 1 To 10
         For p1 = 1 To 3
            For p2 = p1 + 1 To 4
               For p3 = p2 + 1 To 5
                  a = Estratto(es,r1,p1): b = Estratto(es,r1,p2):c = Estratto(es,r1,p3)
                  nu(1) = a : nu(2) = b : nu(3) = c : terno = 0
                  For r2 = r1 + 1 To 12
                     If r2 = 11 Then R2 = 12
                     ru(1) = r2
                     terno = SerieFreq(es,es,nu,ru,3)
                     If terno > 0 Then
                        ColoreTesto 0
                        Tot = EstrazioneFin - es
                        Scrivi String(72,"-")
                        Scrivi
                        Scrivi "Estrazione del " & DataEstrazione(es),1,0
                        Scrivi Space(4) & FormatSpace(NomeRuota(r1),10) & FormatSpace(NomeRuota(r2),10) & StringaNumeri(nu) & " Ritardo " & tot,1
                        N3(1) = a : N3(2) = b : N3(3) = c
                        rt(1) = TT_ : rt(2) = NZ_ : ColoreTesto 2
                        If VerificaEsito(N3,rt,es + 1,2,Tot,,RetEsito,RetColpi,RetEstratti,RetIdEstr)Then
                           Call Scrivi(GetInfoEstrazione(RetIdEstr) & Space(5) & RetEsito & Space(5) & " colpo : " & "  " & RetColpi & Space(4) & RetEstratti)
                        Else
                           Scrivi "Non ancora sortito - Colpo : " & Tot,1,,,1
                           ColoreTesto 0 : Scrivi
                        End If
                     End If
                  Next
               Next
            Next
         Next
      Next
   Next
End Sub
 

toon

Advanced Member
Spiego il mio obbiettivo : Trovando delle terzine con lo stesso ritardo su più ruote, almeno 2 o 3(ruote) , la possibilità che su una delle due o tre ci sia un'uscita positiva, sia dell'ambo che del terno, è veramente molto alta.
Probabilmente lo script non fa proprio quel che dice il titolo, ma mi pare di essere stato più chiaro, spero.
Salvo e i legend siete sempre molto presenti in questo forum e Vi ringrazio anche da parte di chi non lo fa, ma poi usa i vostri lavori come tutti coloro che Vi apprezzano.. Grazie.
 

i legend

Premium Member
Toon tu vorresti rigiocare il terno per ambo sulle ruote di rilevamento, lo script fa quello che ti serve.
Basta sostituire questa riga.
rt(1) = TT_ : rt(2) = NZ_ :
Rt(1)=r1
Rt(2)=r2
Questa riga non serve
N3(1) = a : N3(2) = b : N3(3) = c
è identica a quella già utilizzata
nu(1)=a: nu(2)=b:nu(3)=c

ciao e grazie per le parole ma in realtà sto sul forum più per passare del tempo in compagnia che a fare script, appena starò meglio cercherò di recuperate:)
 

salvo50

Advanced Member >PLATINUM PLUS<
Spiego il mio obbiettivo : Trovando delle terzine con lo stesso ritardo su più ruote, almeno 2 o 3(ruote) , la possibilità che su una delle due o tre ci sia un'uscita positiva, sia dell'ambo che del terno, è veramente molto alta.
Probabilmente lo script non fa proprio quel che dice il titolo, ma mi pare di essere stato più chiaro, spero.
Salvo e i legend siete sempre molto presenti in questo forum e Vi ringrazio anche da parte di chi non lo fa, ma poi usa i vostri lavori come tutti coloro che Vi apprezzano.. Grazie.
Scusami se non ho capito un tubo di quello che chiedevi
 

Mike58

Advanced Member >PLATINUM PLUS<
Ciao Toon , anche secondo me e dalle mie analisi scriptiche non si trovano terni ripetuti su almeno 3 ruote )
Poi queste tipo di ricerche in terne sono molto lunghe in termini di elaborazioni e poi i vari script vanno in errore in quanto non trovano risultanze.
Tuttavia ( purtroppo ho perso parecchi miei script e modus operandi, causa crash pc e quindi devo ingegnarmi ex-novo) ho rifatto una ricerca sugli ambi uguali su 3 ruote (nei 2 ambienti vbnet e vbscript) e come vedi trova pochi ambi in tempi ragionevole.

Per la ricerca dei terni dovresti fare un altro ciclo for delle posizioni e mettere il trovato in numero vettore anche se come dicevo sopra non ci sono terni ripetuti su 3 ruote.

Ti metto gli script veloci come modus operandi.

vbscript

Codice:
Sub Main
   'Quaterna uguale super veloce
   'Dim aNumEstraz(,) As Integer
   Dim Nu(2),ru(3)
   Ini = 3950'EstrazioniArchivio  - 600
   fin = EstrazioniArchivio
   Dim es,r1,r2,r3,p1,p2,p3,p4,k
   Dim T
   ResetTimer
   T = Array(T," Caso n. "," Data Rilevamento "," Ruote "," Ambo Uguale ","Ritardo Cronologico")
   Call InitTabella(T)
   For es = fin To Ini Step - 1
      ReDim aNumEstraz(11,5)
      'Call GetArrayNumeriRuota(es,aNumEstraz)
      Call GetEstrazioneCompleta(es,aNumEstraz)
      For r1 = 1 To 9
         For r2 = r1 + 1 To 10
            For r3 = r2 + 1 To 11
               For p1 = 1 To 4
                  For p2 = p1 + 1 To 5
                     'For p3 = p2 + 1 To 4
                     'For p4 = p3 + 1 To 5
                     If Posizione(es,r2,aNumEstraz(r1,p1)) Then
                        If Posizione(es,r2,aNumEstraz(r1,p2)) Then
                           If Posizione(es,r3,aNumEstraz(r1,p1)) Then
                              If Posizione(es,r3,aNumEstraz(r1,p2)) Then
                                 k = k + 1
                                 Nu(1) = aNumEstraz(r1,p1)
                                 Nu(2) = aNumEstraz(r1,p2)
                                 ' Nu(3) = aNumEstraz(r1,p3)
                                 ' Nu(4) = aNumEstraz(r1,p4)
                                 ru(1) = r1
                                 ru(2) = r2
                                 ru(3) = r3
                                 T = Array(T, k,GetInfoEstrazione(es),StringaRuote(ru),StringaNumeri(Nu),fin - es)
                                 Call AddRigaTabella(T)
                              End If
                           End If
                        End If
                     End If
                  Next
                  'Next
               Next
            Next
         Next
      Next
   Next
   CreaTabella
   Scrivi "Tempo di Elaborazione impiegato..... " & TempoTrascorso,1
End Sub

vbnet

Codice:
Class Script
    Sub Main
        'Quaterna uguale super veloce
        Dim aNumEstraz ( ,) As Integer
        Dim Nu(2),ru(3) As Integer
        Dim Ini As Integer = 3950'EstrazioniArchivio  - 1600
        Dim fin As Integer = EstrazioniArchivio
        Dim es , r1,r2,r3,p1,p2,k As Integer
        Dim T() As String
        T = {" Caso n. "," Data Rilevamento "," Ruote "," Ambo Uguale " ,"Ritardo Cronologico"}
        Call InitTabella(T)
        For es = fin To Ini Step - 1
            ReDim aNumEstraz(11,5)
            Call GetNumeriRuote (es,aNumEstraz)
            For r1 = 1 To 9
                For r2 = r1 + 1 To 10
                    For r3 = r2 + 1 To 11
                        For p1 = 1 To 4
                            For p2 = p1 + 1 To 5
                                'For p3 = p2 + 1 To 4
                                'For p4 = p3 + 1 To 5
                                If Posizione(es,r2,aNumEstraz(r1,p1)) Then
                                    If Posizione(es,r2,aNumEstraz(r1,p2)) Then
                                        If Posizione(es,r3,aNumEstraz(r1,p1)) Then
                                            If Posizione(es,r3,aNumEstraz(r1,p2)) Then
                                                k = k + 1
                                                Nu(1) = aNumEstraz(r1,p1)
                                                Nu(2) = aNumEstraz(r1,p2)
                                                ' Nu(3) = aNumEstraz(r1,p3)
                                                ' Nu(4) = aNumEstraz(r1,p4)
                                                ru(1) = r1
                                                ru(2) = r2
                                                ru(3) = r3
                                                T = { k,GetInfoEstrazione(es),ArrayRuoteToString(ru),StringaNumeri(Nu) ,fin-es}
                                                Call AddRigaTabella(T)
                                            End If
                                        End If
                                    End If
                                End If
                            Next
                            'Next
                        Next
                    Next
                Next
            Next
        Next
        CreaTabella
        Scrivi ( "Tempo Di Elaborazione........... " &  FormattaSecondi ( SecondiTrascorsi ))
    End Sub
End Class

Caso n.
Data Rilevamento
Ruote
Ambo Uguale
Ritardo Cronologico
1​
10117 - 94 - 06/08/2022​
Ba.Mi.To​
56.69​
20​
2​
9758 - 30 - 10/03/2020​
Ca.Pa.Ve​
30.43​
379​
3​
9745 - 17 - 08/02/2020​
Mi.Rm.Ve​
63.78​
392​
4​
9719 - 148 - 10/12/2019​
Pa.To.Ve​
41.31​
418​
5​
9534 - 119 - 04/10/2018​
Ge.Rm.Ve​
34.1​
603​
6​
9522 - 107 - 06/09/2018​
Ba.Mi.Rm​
74.22​
615​
 

toon

Advanced Member
Salvo, sono io che probabilmente non mi sono espresso bene, siete un Monumento alla cortesia e geniali scripter...
Grandissimo.. Grazie, penso che molti, se utilizzeranno questi script con la giusta considerazione
avranno delle soddisfazioni...
;-) Io uso anche il software in vbnet e devo dire che è velocissimo ad elaborare..
 
Ultima modifica:

i legend

Premium Member
ciao ho fatto gli script con un altra routine, vedete se sono esatti e abbastanza veloci, non ho modo di testarli per vedere se sono esatti, ho cercato di raccogliere piu dati possibili.
sulla loro effettiva validita di guadagno non saprei cosa dire.
allora il primo script trova su due ruote dall ambo alla cinquina
il secondo su tre ruote dall ambo alla cinquina

ecco gli script
se i dati sono sbagliati cerco di sistemarli se sono in grado ;)
dall ambo alla cinquina su due ruote
Codice:
Option Explicit
Sub Main
   
    Dim idEstr,R1,R2,R3,aConv12,M
    Dim Esi,nclp,Estr,idE,nPos,col11F,col11S,bold,col7F,col7S
    Dim sCharSep,sTit,nLenTit
    Dim Ini:Ini = 3950
    Dim Fin:Fin = EstrazioneFin
    Dim nSorte:nSorte = 2
    Dim nPuntiMin:nPuntiMin = 2
    Dim aR(2),aTT(2):aTT(1) = 11:aTT(2) = 12
    Dim aClp(5),aPremi(5)
    sTit = " IdCs | CONC  | R1 |   Estrazione   | R2 |   Estrazione   |   FORMAZIONE   |_|  ESITO   |_|COLPO|_|CONC |_|   ESITO 1       |_|   ESITO 2       |_|"
    nLenTit = Len(sTit)
    Call ResetTimer
    Scrivi FormatSpace("    Non si garantisce l esattezza dei dati riportati ed estrabolati dallo script ,l utilizzatore è l unico responsabile del suo utilizzo",nLenTit),1,,vbRed,vbWhite
    Scrivi FormatSpace("    Lo script è donato gratuitamente ne è vietata la vendita",nLenTit),1,,vbRed,vbWhite
    Scrivi
    Scrivi " ",,0
    Scrivi " Ciclo teorico di un ambo  su 2 ruote ",1,0,RGB(0,128,128),vbWhite
    Scrivi "|",,0,,,3
    Scrivi "   Premio su 2   Ruote   ",1,,RGB(0,128,128),vbWhite
    For Esi = 2 To 5
        aClp(Esi) = Round(CicloTeorico(Esi,2,2),2)
        aPremi(Esi) = Round(GetPremioLotto(Esi,2,2),2)
        Scrivi " ",,0
        Scrivi FormatSpace("  " & Esi & " Estratti:" & Space(14) & aClp(Esi),38),1,0,RGB(0,185,185),vbWhite
        Scrivi "|",,0,,,3
        Scrivi FormatSpace(aPremi(Esi) & "  ",25,1),1,,RGB(0,191,191),vbWhite
    Next
    Scrivi
    Scrivi FormatSpace(" Range|" & GetInfoEstrazione(Ini) & " - " & GetInfoEstrazione(Fin),nLenTit),,,RGB(3,131,195),vbWhite
    Scrivi sTit,,,RGB(0,128,192),RGB(255,255,255)
    Dim aTit:aTit = Array(0,"IdCs","CONC","R1","ESTRATTI","R2","ESTRATTI","FORMAZIONE","nCOLPI","RSTO(R1_R2","RC(TT_NZ)","RSTO(TT_NZ)")
    Call InitTabella(aTit)
    M = 0
    For idEstr = Ini To Fin
        Call AvanzamentoElab(Ini,Fin,idEstr)
        For R1 = 1 To 9
            ReDim aE1(0):Call GetArrayNumeriRuota(idEstr,R1,aE1)
            For R2 = R1 + 1 To 10
                ' ReDim aE1(0):Call GetArrayNumeriRuota(idEstr,R1,aE1)
                ReDim aE2(0):Call GetArrayNumeriRuota(idEstr,R2,aE2)
                If GetPunti(aE1,aE2,aConv12) >= nPuntiMin Then
                    Call OrdinaMatriceTurbo(aConv12,1)
                    aR(1) = R1:aR(2) = R2
                    Call VerificaEsitoTurbo(aConv12,aR,idEstr + 1,nSorte,,,Esi,nclp,Estr,idE)
                    sCharSep = "|_|"
                    If Esi = "" Then
                        sCharSep = "|X|"
                        Esi = "In Corso"
                        Dim z: z = z + 1
                        Dim aTab:aTab = Array(0,z,idEstr,SiglaRuota(R1),StringaNumeri(aE1,,True),SiglaRuota(R2),StringaNumeri(aE2,,True),StringaNumeri(aConv12,,True),nclp,SerieStoricoTurbo(Ini,Fin,aConv12,aR,2),SerieRitardoTurbo(idEstr + 1,Fin,aConv12,aTT,nSorte),SerieStoricoTurbo(Ini,Fin,aConv12,aTT,2))
                        Call AddRigaTabella(aTab)
                    End If
                    col11F = RGB(128,255,128)
                    col11S = RGB(0,113,225)
                    col7F = vbWhite
                    col7S = vbBlack
                    bold = 0
                    Dim clpPrem:clpPrem = aPremi(UBound(aConv12))
                    If(clpPrem - nclp*2 >= 0) And(clpPrem - nclp*2 <= 9) And Esi<>"Ambo" Then col11F = vbRed: col11S = vbWhite:bold = 1:col7F = vbRed: col7S = vbWhite
                    If nclp*2 > clpPrem Then col11F = RGB(247,207,72)
                    M = M + 1 ' casi trovati
                    Scrivi FormatSpace(M,5,1) & " | " & FormatSpace(idEstr,5) & " | " & SiglaRuota(R1) & " | " & _
                    StringaNumeri(aE1,,True) & " | " & SiglaRuota(R2) & " | " & StringaNumeri(aE2,,True) & " | ",,0
                    Scrivi FormatSpace(StringaNumeri(aConv12,,True),15,1),bold,0,col7F,col7S
                    Scrivi sCharSep & FormatSpace(Esi,10,1) & sCharSep,,0
                    Scrivi FormatSpace(nclp,5,1),bold,0,col11F,col11S
                    Scrivi sCharSep & FormatSpace(idE,5,1) & sCharSep & Estr
                End If
            Next
        Next
    Next
    Scrivi
    Scrivi "Casi totali:   " & M
    Scrivi " casi In corso   su ruote di rilevamento     " & z,1,,vbRed,vbWhite
    Call CreaTabellaOrdinabile()
    Scrivi TempoTrascorso
End Sub
Function GetPunti(a1,a2,aC)
    ' a1 non deve avere ripetuti
    ' a2 non deve avere ripetuti
    Dim i,j,k
    ReDim aC(0)
    k = 0
    For i = 1 To UBound(a1)
        For j = 1 To UBound(a2)
            If a1(i) = a2(j) Then
                k = k + 1
                ReDim Preserve aC(k)
                aC(k) = a1(i)
            End If
        Next
    Next
    GetPunti = UBound(aC)
End Function

dall ambo alla cinquina su tre ruote
al momento non ho rilevato nessuna formazione superiore all ambo
Codice:
Option Explicit
' inserire le piccole modifiche
'la modifica dello script potrebbe causarne il mal funzionamento
Sub Main
    Dim idEstr,R1,R2,R3,aConv12,aConv23,M
    Dim Esi,nclp,Estr,idE,nPos
    Dim sCharSep,sTit,nLenTit
    Dim Ini:Ini = 3950
    Dim Fin:Fin = EstrazioneFin
    Dim nSorte:nSorte = 2
    Dim nPuntiMin:nPuntiMin=2
    Dim aR(3),aClp(5),aPremi(5)
  
       Call ResetTimer
    sTit = "IdCs| CONC  | R1 |   Estrazione   | R2 |   Estrazione   | R2 |   Estrazione   |   FORMAZIONE   |_|  ESITO   |_|COLPO|_|CONC |_|   ESITO 1       |_|   ESITO 2       |_|   ESITO 3       "
    nLenTit = Len(sTit)
    Scrivi FormatSpace("    Non si garantisce l esattezza dei dati riportati ed estrabolati dallo script ,l utilizzatore è l unico responsabile del suo utilizzo",nLenTit),1,,vbRed,vbWhite
    Scrivi FormatSpace("    Lo script è donato gratuitamente ne è vietata la vendita",nLenTit),1,,vbRed,vbWhite
    Scrivi
 
  Scrivi " ",,0
    Scrivi " Ciclo teorico di un ambo  su 3 ruote ",1,0,RGB(0,128,128),vbWhite
    Scrivi "|",,0,,,3
    Scrivi "   Premio su 3   Ruote   ",1,,RGB(34,151,40),vbWhite

    For Esi = 2 To 5
        aClp(Esi) = Round(CicloTeorico(Esi,2,3),2)
        aPremi(Esi) = Round(GetPremioLotto(Esi,2,3),2)
        Scrivi " ",,0
        Scrivi FormatSpace("  " & Esi & " Estratti:" & Space(14) & aClp(Esi),38),1,0,RGB(0,185,185),vbWhite
        Scrivi "|",,0,,,3
        Scrivi FormatSpace(aPremi(Esi) & "      ",25,1),1,,RGB(34,151,40),vbWhite
    Next
    Scrivi
    Scrivi
    Scrivi FormatSpace(" Range|" & GetInfoEstrazione(Ini) & " - " & GetInfoEstrazione(Fin),nLenTit),,,RGB(3,131,195),vbWhite
    Scrivi sTit,,,RGB(0,128,192),RGB(255,255,255)
 
    M = 0
    For idEstr = Ini To Fin
        Call AvanzamentoElab(Ini,Fin,idEstr)
        For R1 = 1 To 9
            ReDim aE1(0):Call GetArrayNumeriRuota(idEstr,R1,aE1)
            For R2 = R1 + 1 To 10
                ' ReDim aE1(0):Call GetArrayNumeriRuota(idEstr,R1,aE1)
                ReDim aE2(0):Call GetArrayNumeriRuota(idEstr,R2,aE2)
                If GetPunti(aE1,aE2,aConv12) >= nPuntiMin Then
                    For R3 = R2 + 1 To 11
                        If R3 = 11 Then R3 = 12
                        ReDim aE3(0): Call GetArrayNumeriRuota(idEstr,R3,aE3)
                        If GetPunti(aE3,aConv12,aConv23) >= nPuntiMin Then
                            Call OrdinaMatriceTurbo(aConv23,1)
                            aR(1) = R1:aR(2) = R2:aR(3) = R3
                            Call VerificaEsitoTurbo(aConv23 ,aR ,idEstr + 1 ,nSorte,,,Esi,nclp,Estr,idE)
                            If Esi = "" Then
                                sCharSep = "|X|"
                            Else
                                sCharSep = "|_|"
                            End If
                            M = M + 1 ' casi trovati
                            Scrivi FormatSpace(M,3) & " | " & FormatSpace(idEstr,5) & " | " & SiglaRuota(R1) & " | " & _
                            StringaNumeri(aE1,,True) & " | " & SiglaRuota(R2) & " | " & StringaNumeri(aE2,,True) & " | " & _
                            SiglaRuota(R3) & " | " & StringaNumeri(aE3,,True) & " | " & FormatSpace(StringaNumeri(aConv23,,True),15,1) & _
                            sCharSep & FormatSpace(Esi,10,1) & sCharSep,,0
                            Dim col
                            If nclp*3 > aPremi(UBound(aConv23)) Then
                                col = RGB(247,207,72)
                            Else
                                col = RGB(128,255,128)
                            End If
                            Scrivi FormatSpace(nclp,5,1),0,0,col
                            Scrivi sCharSep & FormatSpace(idE,5,1) & sCharSep & Estr
                        End If
                    Next
                End If
            Next
        Next
    Next
    Scrivi
    Scrivi "Casi totali:   " & M
    Scrivi TempoTrascorso
End Sub
Function GetPunti(a1,a2,aC)
' a1 non deve avere ripetuti
' a2 non deve avere ripetuti

    Dim i,j,k
    ReDim aC(0)
    k = 0
    For i = 1 To UBound(a1)
        For j = 1 To UBound(a2)
            If a1(i) = a2(j) Then
                k = k + 1
                ReDim Preserve aC(k)
                aC(k) = a1(i)
            End If
        Next
    Next
    GetPunti = UBound(aC)
End Function
ciao Fatemi sapere cosa ne pensate :)
buona domenica a tutti :)
 
Ultima modifica:

Xeroxs

Advanced Member >GOLD<
Buongiorno,
Ho avuto solo ora il modo di Visionare quanto scritto sia Da Mike58, Salvo50 e I-Legend Direi Tutti ben fatti nelle esposizione sia delle ricerche che esposizione dei risultati, cosi da farsi un idea sugli esiti e le scelte da fare, cercando a ritroso direi che i dati riportati sono corretti, dal mio punto di vista un terno è raro a ripetersi e sicuramente un analisi attenta può essere spunto per le scelte dell'utente, sull'ambo visto le ripetizioni sicuramente occorre una scelta più mirata anche se i risultati non mancano, ma occorre sempre quella buona dose di fortuna a di là delle nostre ricerche.
Per Quanto mi riguarda faccio i miei complimenti a tutti e tre che come sempre proponete ottimi lavori, diversi ma che aiutano nella comprensione e per chi vuole anche imparare, per quanto mi riguarda ho imparato tante cose rileggendo i vostri script più che sulla teoria esposta, e poi rileggendo la teoria ovvero quanto scritto da Voi e dai vari codici di spaziometria sperando di migliorare con il tempo.

Grazie.
 

Ultima estrazione Lotto

  • Estrazione del lotto
    martedì 26 marzo 2024
    Bari
    30
    51
    17
    01
    53
    Cagliari
    13
    70
    25
    68
    47
    Firenze
    28
    30
    54
    70
    88
    Genova
    67
    87
    22
    03
    62
    Milano
    22
    34
    13
    47
    24
    Napoli
    20
    72
    59
    01
    52
    Palermo
    05
    72
    65
    52
    32
    Roma
    28
    43
    75
    54
    87
    Torino
    16
    08
    17
    24
    38
    Venezia
    67
    28
    55
    60
    29
    Nazionale
    15
    69
    22
    63
    39
    Estrazione Simbolotto
    Firenze
    44
    09
    31
    22
    16
Alto